Référence Excel feuille de travail par nom?

J'ai le nom d'une feuille de calcul stockée comme une chaîne de caractères dans une variable. Comment puis-je effectuer une opération sur cette feuille de calcul?

J'ai pensé que je ferais quelque chose comme ceci:

nameOfWorkSheet = "test"
ActiveWorkbook.Worksheets(nameOfWorkSheet).someOperation()

Comment puis-je obtenir ce fait?

source d'informationauteur Jonson Bylvaklov

  1. 10

    Il y a plusieurs options, y compris à l'aide de la méthode de vous démontrer, À l'aide, et l'aide d'une variable.

    Ma préférence est l'option 4 ci-dessous: Dim une variable de type Worksheet et de stocker la feuille de calcul et d'appeler les méthodes de la variable ou de la transmettre à des fonctions, cependant l'une des options de travail.

    Sub Test()
Dim SheetName As String
Dim SearchText As String
Dim FoundRange As Range
SheetName = "test"      
SearchText = "abc"
' 0. If you know the sheet is the ActiveSheet, you can use if directly.
Set FoundRange = ActiveSheet.UsedRange.Find(What:=SearchText)
' Since I usually have a lot of Subs/Functions, I don't use this method often.
' If I do, I store it in a variable to make it easy to change in the future or
' to pass to functions, e.g.: Set MySheet = ActiveSheet
' If your methods need to work with multiple worksheets at the same time, using
' ActiveSheet probably isn't a good idea and you should just specify the sheets.
' 1. Using Sheets or Worksheets (Least efficient if repeating or calling multiple times)
Set FoundRange = Sheets(SheetName).UsedRange.Find(What:=SearchText)
Set FoundRange = Worksheets(SheetName).UsedRange.Find(What:=SearchText)
' 2. Using Named Sheet, i.e. Sheet1 (if Worksheet is named "Sheet1"). The
' sheet names use the title/name of the worksheet, however the name must
' be a valid VBA identifier (no spaces or special characters. Use the Object
' Browser to find the sheet names if it isn't obvious. (More efficient than #1)
Set FoundRange = Sheet1.UsedRange.Find(What:=SearchText)
' 3. Using "With" (more efficient than #1)
With Sheets(SheetName)
Set FoundRange = .UsedRange.Find(What:=SearchText)
End With
' or possibly...
With Sheets(SheetName).UsedRange
Set FoundRange = .Find(What:=SearchText)
End With
' 4. Using Worksheet variable (more efficient than 1)
Dim MySheet As Worksheet
Set MySheet = Worksheets(SheetName)
Set FoundRange = MySheet.UsedRange.Find(What:=SearchText)
' Calling a Function/Sub
Test2 Sheets(SheetName) ' Option 1
Test2 Sheet1 ' Option 2
Test2 MySheet ' Option 4
End Sub
Sub Test2(TestSheet As Worksheet)
Dim RowIndex As Long
For RowIndex = 1 To TestSheet.UsedRange.Rows.Count
If TestSheet.Cells(RowIndex, 1).Value = "SomeValue" Then
' Do something
End If
Next RowIndex
End Sub
  2. 5

    Le meilleur moyen est de créer une variable de type Worksheetaffecter la feuille de calcul et l'utiliser chaque fois que le VBA serait implicitement utiliser le ActiveSheet.

    Cela vous aidera à éviter des bugs qui finira par apparaître lorsque votre programme prend de l'ampleur.

    Par exemple quelque chose comme Range("A1:C10").Sort Key1:=Range("A2") est bon lorsque la macro ne fonctionne que sur une seule feuille. Mais vous finirez par développez votre macro pour travailler avec plusieurs feuilles, de savoir que cela ne fonctionne pas, l'ajuster à ShTest1.Range("A1:C10").Sort Key1:=Range("A2")... et de savoir que cela ne fonctionne toujours pas.

    Ici est la bonne manière:

    Dim ShTest1 As Worksheet
Set ShTest1 = Sheets("Test1")
ShTest1.Range("A1:C10").Sort Key1:=ShTest1.Range("A2")
  3. 1

    De se développer sur de Ryan réponse, lorsque vous déclarez des variables (à l'aide de Dim), vous pouvez tricher un peu en utilisant la saisie de texte prédictive fonctionnalité dans le VBE, comme dans l'image ci-dessous. Référence Excel feuille de travail par nom?

    Si elle figure dans cette liste, vous pouvez affecter un objet de ce type à une variable. Donc pas juste une Feuille de calcul, comme Ryan l'a souligné, mais aussi un Graphique, la Plage, le Classeur, la Série et sur et sur.

    Vous définissez cette variable est égale à l'objet que vous souhaitez manipuler et ensuite, vous pouvez appeler les méthodes, les faire passer à des fonctions, etc, tout comme Ryan a souligné pour cet exemple. Vous pourriez avoir quelques accrocs quand il s'agit de collections vs objets (Graphique ou de Tableaux, la Plage ou les Plages, etc) mais avec essais et erreurs, vous pourrez l'obtenir pour vous.