Régulière fichier texte au format XML à l'aide de XSLT

Texte (non XML) les fichiers peuvent être lus avec le standard XSLT 2.0 fonction unparsed-text().

Alors on peut utiliser la norme XPath 2.0 fonction marquer() et deux autres standard XPath 2.0 fonctions qui acceptent une expression régulière comme l'un de leurs arguments -- correspond à() et replace().

XSLT 2.0 dispose de sa propre puissance instructions pour la poignée de traitement de texte à l'aide d'expressions régulières:: le <xsl:analyser-string>, le <xsl:correspondance-sous-chaîne> et la <xsl:non-correspondance-sous-chaîne> instruction.

Voir certains des plus puissantes capacités de XSLT traitement de texte avec ces fonctions et des instructions dans ce monde réel, exemple: une transformation XSLT solution au problème WideFinder.

Enfin, voici un XSLT 1.0 solution:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 xmlns:my="my:my" exclude-result-prefixes="ext my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <my:fieldNames>
  <name>FirstName</name>
  <name>LastName</name>
  <name>City</name>
  <name>State</name>
  <name>Zip</name>
 </my:fieldNames>

 <xsl:variable name="vfieldNames" select=
  "document('')/*/my:fieldNames"/>

 <xsl:template match="/">
  <xsl:variable name="vrtfTokens">
   <xsl:apply-templates/>
  </xsl:variable>

  <xsl:variable name="vTokens" select=
       "ext:node-set($vrtfTokens)"/>

  <results>
   <xsl:apply-templates select="$vTokens/*"/>
  </results>
 </xsl:template>

 <xsl:template match="text()" name="tokenize">
  <xsl:param name="pText" select="."/>

     <xsl:if test="string-length($pText)">
       <xsl:variable name="vWord" select=
       "substring-before(concat($pText, '^'),'^')"/>

       <word>
        <xsl:value-of select="$vWord"/>
       </word>

       <xsl:call-template name="tokenize">
        <xsl:with-param name="pText" select=
         "substring-after($pText,'^')"/>
       </xsl:call-template>
     </xsl:if>
 </xsl:template>

 <xsl:template match="word">
  <xsl:variable name="vPos" select="position()"/>

  <field>
      <xsl:element name="{$vfieldNames/*[position()=$vPos]}">
      </xsl:element>
      <value><xsl:value-of select="."/></value>
  </field>
 </xsl:template>
</xsl:stylesheet>

Lorsque cette transformation est appliquée sur le document XML suivant:

<t>John^Smith^Bellevue^WA^98004</t>

le voulait, résultat correct est produit:

<results>
   <field>
      <FirstName/>
      <value>John</value>
   </field>
   <field>
      <LastName/>
      <value>Smith</value>
   </field>
   <field>
      <City/>
      <value>Bellevue</value>
   </field>
   <field>
      <State/>
      <value>WA</value>
   </field>
   <field>
      <Zip/>
      <value>98004</value>
   </field>
</results>

OriginalL'auteur Dimitre Novatchev