Réinitialiser le formulaire en VBA

J'ai un formulaire VBA avec une variété d'options de sélection, y compris les menus déroulants, les champs de texte, des cases à cocher et les radios.

Je voulais juste savoir à propos de la meilleure façon d'effacer tous ces domaines, avec un bouton de la presse. Un de mes amis a essayé d'aider en m'envoyant un email le code ci-dessous mais malheureusement ça ne fonctionne pas, j'ai vérifié les noms de variable.

Des conseils sur comment je peux l'améliorer?

Merci d'avance.

Private Sub btnReset_Click()

Unload Me
UserForm.Show

End Sub

Voici le code pour l'objet userform.

Dim DeptCode 'Holds department code

Private Sub UserForm_Initialize()

    Dim c_deptCode As Range
    Dim c_deptName As Range
    Dim deptCodes As Variant
    Dim deptNames As Variant

    Dim ws_dept As Worksheet
    Set ws_dept = Worksheets("lookupDept")

    ' Assign each range to an array containing the values
    deptCodes = Choose(1, ws_dept.Range("deptCode"))
    deptNames = Choose(1, ws_dept.Range("deptName"))

    For i = 1 To ws_dept.Range("deptCode").Rows.Count
        ' Create the combined name (code + space + name)
        CombinedName = deptCodes(i, 1) & " - " & deptNames(i, 1)
        cbo_deptCode.AddItem CombinedName
    Next i

End Sub
InformationsquelleAutor methuselah | 2012-10-10
  1. 17

    Je pense que quand il frappe les Décharger M'ligne, l'exécution de code s'arrête et c'est pourquoi il ne fonctionne pas pour vous. Voici un générique événement procédure pour réinitialiser tous (la plupart) des contrôles sur le formulaire.

    Private Sub cmdReset_Click()

    Dim ctl As MSForms.Control

    For Each ctl In Me.Controls
        Select Case TypeName(ctl)
            Case "TextBox"
                ctl.Text = ""
            Case "CheckBox", "OptionButton", "ToggleButton"
                ctl.Value = False
            Case "ComboBox", "ListBox"
                ctl.ListIndex = -1
        End Select
    Next ctl

End Sub

    Il n'a pas de repeupler les zones de liste modifiables et zones de liste, juste effacer la sélection, qui est ce que je suppose que vous voulez.

    • Merci il fonctionne à merveille
    InformationsquelleAutor Dick Kusleika
  2. 5

    Je sais que cette question est presque 2 ans, MAIS je cherchais une réponse de ce genre. Cependant, je suis aide d'Access 2010 et a découvert que la fonction ne fonctionne pas entièrement comme prévu:

    • ctl peut être Dim-ed simplement que le Contrôle
    • Pour une zone de texte, le ctl.Texte de propriété ne peut être attribué que si le contrôle a le focus (utiliser ctl.Valeur au lieu de cela)
    • Si un contrôle OptionButton fait partie d'un groupe d'options, il ne peut pas être attribué une valeur

    Donc avec ces questions à l'esprit, voici mon réécrit la fonction:

    Private Sub resetForm()

    Dim ctl As Control ' Removed MSForms.

    For Each ctl In Me.Controls
        Select Case TypeName(ctl)
            Case "TextBox"
                ctl.value = ""
            Case "CheckBox", "ToggleButton" ' Removed OptionButton
                ctl.value = False
            Case "OptionGroup" ' Add OptionGroup
                ctl = Null
            Case "OptionButton" ' Add OptionButton
                ' Do not reset an optionbutton if it is part of an OptionGroup
                If TypeName(ctl.Parent) <> "OptionGroup" Then ctl.value = False
            Case "ComboBox", "ListBox"
                ctl.ListIndex = -1
        End Select
    Next ctl

End Sub
    • Pour le ctl.ListIndex affectation, j'obtiens le message d'erreur que je suis en utilisant la propriété ListIndex de manière incorrecte. J'ai eu à utiliser ctl = Null
    InformationsquelleAutor Johan Godfried
  3. 2

    L'ajout le plus récent réponse - si certains de vos contrôles ont des valeurs par défaut, vous pouvez utiliser

    ctl.Value = ctl.DefaultValue

    Qui fonctionne pour moi, au moins pour les cases à cocher et les listes déroulantes.

    • C'est bon, mais si vous voulez une réponse, vous devez fournir le code complet. "le plus récent réponse" change tous les jours. Si vous souhaitez simplement ajouter un commentaire à une réponse, vous pouvez le faire aussi.
    InformationsquelleAutor Erik I
  4. 1

    Vous pouvez essayer ceci:

    Private Sub btnReset_Click()

    Call UserForm_Initialize

End Sub
    • Votre contribution serait ajouter plus de valeur pour le site si vous voulez expliquer pourquoi votre approche a des avantages sur les suggestions qui ont été faites, il y a des années...
    • S'il vous plaît ajouter plus d'explication. Il en a été examinée pour la longueur et le contenu. Il peut être supprimé à un certain point si la réponse n'est pas améliorée.
    • Eh bien, c'est beaucoup moins de code pour un. Aussi, les solutions ci-dessus ne tiennent pas compte de l'état des contrôles lorsque le formulaire est chargé pour la première fois (ce qui peut être nécessaire si l'on est de "remettre à zéro" d'une forme). Cela devrait être évident... si la solution a fonctionné. Malheureusement, il n'a pas. Accès me dit que la méthode n'est pas définie.
    • Pour que cela fonctionne, vous devez d'abord créer l'événement initialize. Cet événement devra alors faire quelque chose, comme l'ensemble de l'état, comme l'a suggéré dans d'autres réponses. Il est anti-modèle à l'appel d'un événement directement comme ça. Au lieu de cela, vous devez définir l'état dans un sous et l'appeler par l'initialiser et le bouton.
    InformationsquelleAutor S. Stoyanov
  5. 1

    Microsoft a cette documenté assez bien maintenant pour la dernière version d'Accès. Il ressemble à certaines des réponses ci-dessus se réfèrent à des versions plus anciennes. Le code ci-dessous fonctionne dans mon application parfaitement. J'ai seulement compris les types de contrôle j'ai besoin, mais vous pouvez trouver de la documentation pour tous les autres dans le Microsoft liens ci-dessous.

    Ref: https://msdn.microsoft.com/en-us/vba/access-vba/articles/textbox-controltype-property-access?f=255&MSPPError=-2147217396

    Dim ctl As Control

For Each ctl In Me.Controls
    With ctl
        Select Case .ControlType
            Case acTextBox
                .Value = ""
            Case acCheckBox
                .Value = False
            Case acComboBox
                .SetFocus
                .SelText = ""
            Case acListBox
                .Value = Null
        End Select
    End With
Next ctl

    Noter que pour la zone de liste modifiable, vous avez à mettre l'accent là avant le réglage de la valeur.
    Ref: https://msdn.microsoft.com/en-us/vba/access-vba/articles/combobox-seltext-property-access

    InformationsquelleAutor dRay