SAS - Comment obtenir le dernier 'n' observations à partir d'un dataset?

Comment pouvez-vous créer un SAS ensemble de données à partir d'un autre jeu de données en utilisant uniquement le dernier n des observations à partir d'ensembles de données d'origine. C'est facile quand vous savez que la valeur de n. Si je ne sais pas " n " comment cela peut-il être fait?

  • Que voulez-vous dire que vous ne savez pas 'n'? Comment allez-vous trouver la valeur de 'n' - est-il un jeu de données variable, une macro variable, un paramètre?
InformationsquelleAutor Riyaz Iqbal | 2013-04-23
  1. 8

    Cela suppose que vous avez une macro variable qui indique combien d'observations que vous voulez. NOBS vous indique le nombre d'observations dans le jeu de données actuellement sans lire la totalité de la chose.

    %let obswant=5;
data want;
set sashelp.class nobs=obscount;
if _n_ gt (obscount-&obswant.);
run;
    InformationsquelleAutor Joe
  2. 4

    À l'aide de Joe exemple d'une macro variable pour spécifier le nombre d'observations que vous souhaitez, voici une autre réponse:

    %let obswant = 10;
data want;
   do _i_=nobs-(&obswant-1) to nobs;
      set have point=_i_ nobs=nobs;
      output;
      end;
   stop;  /* Needed to stop data step */
run;

    Cela devrait mieux fonctionner car il ne lit que des observations particulières que vous voulez.

    • Je suis curieux de connaître les conditions pour "cela devrait mieux fonctionner". Je soupçonne que c'est un peu de chaque; accès aléatoire n'est pas aussi rapide que l'accès séquentiel, il y a donc une perte. Peut tester si j'ai le temps. Je suppose que si vous utilisez la plupart des observations qu'il sera plus rapide de le faire de façon séquentielle, mais si c'est un grand jeu de données et que vous voulez un petit nombre d'observations, il est plus rapide de le faire random=accès. J'aimerais bien que SAS avait un moyen d'ouvrir un jeu de données dans l'ordre inverse sans avoir à les trier en premier.
    • Imaginez un jeu de données avec 1 million d'obs et vous souhaitez le "dernier" 10. En utilisant cette technique, à seulement 10 "entrée" les opérations sont effectuées. En utilisant simplement le NOBS valeur exige 1 million de "l'entrée" des opérations. En fonction de comment "" à l'échelle de l'ensemble de données est, cette différence peut être très importante.
    • Bon, je vois bien la possibilité de ce qui est plus rapide. Je suis curieux de savoir à quel point il est vite/ - vite (c'est à dire, quelle est la taille de la donnée, quel est le pourcentage de données tirée de 10 à partir de 1 MM de cours serait plus rapide, mais qu'500k de 1MM?)
    InformationsquelleAutor BellevueBob
  3. 2

    Si le jeu de données est grande, vous pourriez ne pas vouloir lire l'ensemble du jeu de données. Au lieu de cela, vous pourriez essayer une construction qui lit le nombre total d'Observations dans le jeu de données en premier. Donc, si vous voulez avoir le dernier des observations:

    data t;
  input x;
datalines;
1
2
3
4
;

%let dsid=%sysfunc(open(t));
%let num=%sysfunc(attrn(&dsid,nlobs));
%let rc=%sysfunc(close(&dsid));
%let number = 2;

data tt;
set t (firstobs =  %eval(&num.-&number.+1));
run;
    InformationsquelleAutor user1965813
  4. 1

    Par souci de variété, voici une autre approche (pas nécessairement un meilleur)

    %let obswant=5;

proc sql noprint;
select nlobs-&obswant.+1 into :obscalc
from dictionary.tables
where libname='SASHELP' and upcase(memname)='CLASS';
quit;

data want;
set sashelp.class (firstobs=&obscalc.);
run;
    • Note: vous souhaitez spécifier le format lors de l'utilisation de select..en, sinon, la valeur est formaté comme BEST8., ce qui conduit à bizarre bugs lorsque vous sélectionnez une valeur >= 100 000 000 d' (en forme de notation exponentielle, leader de l'arrondissement).
    InformationsquelleAutor Longfish