Savoir si le fichier est âgé de plus de 4 heures dans un fichier de commandes

Sur la comparaison des temps de fichiers avec code de lot suivants doivent être pris en compte:

1. Format de Date et heure paramètres
2. Système de fichiers des supports de stockage
3. Fuseau horaire, heure d'été
4. Réglage automatique de l'heure d'été
5. Version de Windows

---

1. Format de Date et heure paramètres

Il y a les variables d'environnement DATE et TEMPS qui sur l'accès (et non pas sur le début de l'exécution du lot) retour actuel de la date et de l'heure dans un format selon Région Windows et les paramètres de Langue. Le pays définit le format de date et heure.

Il est même possible de définir par exemple pour l'allemand format de date courte avec DD.MM.YYYY (jour et mois avec zéro) et format de l'heure avec HH:mm:ss (format 24 heures avec zéro pour l'heure, minute et seconde). Mais cela ne signifie pas que la valeur de DATE et TEMPS sont vraiment à l'aide de ce format. Par exemple TEMPS est en format H:mm:ss,ms quand après avoir sélectionné un allemand, même avec HH:mm:ss définies, ce qui signifie pas de zéro sur l'heure, mais sur la minute et la seconde, et, en outre millisecondes après une virgule dans le temps de chaîne. La chaîne de date peut être aussi avec ou sans jour de la semaine selon les paramètres de région.

Et il est le modèle %~t pour obtenir la dernière date de modification et le temps d'un répertoire ou d'un fichier. Exécuter dans une fenêtre d'invite de commande call /? et for /? et de lire toutes les pages d'aide affiché pour ces deux commandes pour plus de détails. Le format de la date et de l'heure chaîne de caractères retournée par %~t ainsi affiché sur la sortie de commande DIR dépend aussi de Windows, les paramètres de région, mais n'est généralement pas égale le format des variables DATE et TEMPS. L'heure de la dernière modification d'un fichier ou d'un répertoire est généralement retournée sans deuxième valeur dans la chaîne de date/heure.

Mieux est de trouver avec fichier de commandes suivant les meilleures exécutée avant 10:00 AM quels sont les formats actuels de la machine pour l'utilisateur courant.

@echo off
echo Current date/time: %DATE% %TIME%
for %%I in ("%~f0") do echo Batch file time:   %%~tI
pause

---

2. Système de fichiers des supports de stockage

Sur les systèmes de fichiers Windows deux formats de stockage sont utilisés pour les fichier fois:

• Sur un support de stockage à l'aide de NTFS la NTFS précision le temps est utilisé qui est un 64-bit nombre d'intervalles de 100 nanosecondes qui se sont écoulées depuis le 12:00 A. M. le 1er janvier 1601 Temps Universel Coordonné (UTC).

• Sur un support de stockage à l'aide de FAT, FAT16, FAT32 ou exFAT le temps de fichiers sont stockés à l'aide de DOS de Date de Temps format avec deux valeurs de 16 bits avec une résolution de 2 secondes et à l'aide de l'heure locale actuelle.

Cela signifie une drôle de seconde n'est pas possible pour un fichier sur le GRAS des médias, mais sur le média NTFS. Copie d'un fichier sur un lecteur NTFS avec un étrange deuxième à la date de dernière modification d'un lecteur FAT32 résultats en avoir les fichiers identiques avec 1 seconde de différence dans la date de dernière modification.

Le temps de fichiers NTFS médias sont stockés au format UTC. Donc, ce qui est retourné par %~t ou commande DIR ainsi que ce qui est affiché par exemple dans l'Explorateur Windows dépend

• fuseau horaire actuel,
• l'heure d'été pour ce fuseau horaire,
• si l'heure actuelle est à l'intérieur de l'heure d'été période,
• et si l'ajustement automatique de l'heure d'été est activée actuellement.

Changer un de ces 4 paramètres en résulte un changement immédiat de TOUTES les heures de fichier de fichiers et de répertoires sur le système NTFS de stockage de médias.

Fichier fois sur la GRAISSE médias sont plus ou moins constant que l'utilisation de l'heure locale sur la création, la modification ou de dernier accès, mais lisez la suite pour plus de détails.

---

3. Fuseau horaire, heure d'été

Comme temps de fichiers NTFS médias sont stockés au format UTC, mais à l'heure locale, le fuseau horaire et l'heure d'été pour cette zone sont importants pour le fichier de comparaisons temps, surtout quand fait pour les fichiers NTFS et FAT32 lecteurs.

Mais aussi pour les fichiers sur un GRAS des médias, le fuseau horaire et l'heure avancée paramètres pourrait être important en fonction de la version de Windows. Lire ci-dessous pour plus de détails.

---

4. Réglage automatique de l'heure d'été

Il y a le paramètre de réglage automatique de l'heure d'été qui devient important lors de l'activation par défaut et actuellement fuseau horaire définit l'heure d'été réglage.

Par exemple l'heure d'été est active actuellement en Europe. La désactivation de cette option dans les réglages de l'horloge de Windows en résulte un changement immédiat de l'affichage des temps de fichiers NTFS médias par -1 heure, et aussi beaucoup de fichiers sur le GRAS des médias en fonction de la version de Windows.

Cette 1 heure de différence résultant de l'heure le réglage doit être pris en compte sur la comparaison des temps de fichiers NTFS et FAT médias.

---

5. La Version de Windows

NTFS sont pris en charge par toutes les versions de Windows NT. Fichier fois le comportement est le même pour les fichiers et les répertoires sur toutes les versions de Windows de soutien NTFS.

Mais comment fichier fois sur le GRAS des médias sont interprétés en fonction de la version de Windows. Avant Windows Vista, le fichier fois sur le GRAS des médias sont indépendants sur le changement de fuseau horaire, heure d'été réglage et d'ajustement automatique de l'heure d'été. Dernière modification date/heure d'un fichier est constante sur Windows 2000 et Windows XP.

Mais sur Windows Vista et les versions ultérieures le fichier affichée fois sur le GRAS des médias dépendent de l'heure d'été et réglage automatique de l'heure d'été. Le fuseau horaire n'est pas directement en question. La sélection d'un autre fuseau horaire que celui actuellement utilisé ne permet pas de modifier le fichier affichée fois des fichiers sur le GRAS des médias comme il le fait pour les fichiers de NTFS médias. Mais si l'heure actuelle est à l'intérieur de l'heure d'été période de l'actif de fuseau horaire et le réglage automatique de l'heure d'été est activée et que l'heure locale du fichier ou le répertoire est à l'intérieur de l'heure d'été période, +1 heure, on ajoute par Windows Vista et les versions ultérieures. Les fichiers de la dernière modification sur les lecteurs FAT dans le temps standard sont constants au cours de l'année; seulement les fichiers de la dernière modification au sein de période d'heure d'été sont affichés avec ou sans +1 heure en fonction de l'heure est activé automatique de l'heure d'été réglage.

Que les différents fichiers FAT la gestion du temps peut être extrêmement déroutant lorsque, ayant par exemple un partage public d'un dossier sur un lecteur FAT32 sur une machine Windows 7 et étant connecté à ce dossier public avec une machine Windows XP. Un fichier de la dernière modification sur 2015-09-19 17:39:08 stockées sur le lecteur FAT32 sur PC Windows 7 est affichée aujourd'hui par Windows 7 avec l'allemand fuseau horaire avec l'heure du fichier 19.09.2015 17:39:08, mais dans 2 mois, mais pas modifié avec 19.09.2015 16:39:08, et Windows XP affiche même fichier connecté sur PC Windows 7 aujourd'hui et à l'avenir constante de temps du fichier 19.09.2015 17:39:08.

Comparant les temps de fichiers de fichiers stockés dans les archives (ZIP, RAR, ...) avec des fichiers NTFS ou FAT médias peut être vraiment un cauchemar.

---

6. En comparant l'heure du fichier avec l'heure actuelle

Pour cette tâche en comparant la date de dernière modification d'un fichier à l'heure actuelle, il devrait être suffisant de prendre date et de l'heure format de paramètres en compte.

Le lot code ci-dessous utilise le code est expliqué en détail dans ma réponse sur Lot de fichiers pour supprimer les fichiers de plus de N jours. Cette explication doit être lu avant d'utiliser le code ci-dessous.

En fonction de la date/heure format de l'variables DATE et TEMPS et la date/heure de chaîne de caractères retournée par %~tI pour les fichiers locaux de PC sous Windows, il pourrait être nécessaire d'apporter de petites modifications au code. Approprié conseils sont donnés dans le commentaire des lignes de code de lot.

@echo off
setlocal EnableExtensions

rem Get seconds since 1970-01-01 for current date and time.
rem From date string only the last 10 characters are passed to GetSeconds
rem which results in passing dd/mm/yyyy or dd.mm.yyyy in expected format
rem to this subroutine independent on date string of environment variable
rem DATE is with or without abbreviated weekday at beginning.
call :GetSeconds "%DATE:~-10% %TIME%"

rem Subtract seconds for 4 hours (4 * 3600 seconds) from seconds value.
set /A "CompareTime=Seconds-4*3600"

rem Define batch file itself as the file to compare time by default.
set "FileToCompareTime=%~f0"

rem If batch file is started with a parameter and the parameter
rem specifies an existing file (or directory), compare with last
rem modification date of this file.
if not "%~1" == "" (
    if exist "%~1" set "FileToCompareTime=%~1"
)

rem Get seconds value for the specified file.
for %%F in ("%FileToCompareTime%") do call :GetSeconds "%%~tF:0"

rem Compare the two seconds values.
if %Seconds% LSS %CompareTime% (
    echo File %FileToCompareTime% was last modified for more than 4 hours.
) else (
    echo File %FileToCompareTime% was last modified within the last 4 hours.
)
endlocal
goto :EOF


rem No validation is made for best performance. So make sure that date
rem and hour in string is in a format supported by the code below like
rem MM/DD/YYYY hh:mm:ss or M/D/YYYY h:m:s for English US date/time.

:GetSeconds

rem If there is " AM" or " PM" in time string because of using 12 hour
rem time format, remove those 2 strings and in case of " PM" remember
rem that 12 hours must be added to the hour depending on hour value.
set "DateTime=%~1"
set "Add12Hours=0"
if "%DateTime: AM=%" NEQ "%DateTime%" (
    set "DateTime=%DateTime: AM=%"
) else if "%DateTime: PM=%" NEQ "%DateTime%" (
    set "DateTime=%DateTime: PM=%"
    set "Add12Hours=1"
)

rem Get year, month, day, hour, minute and second from first parameter.
for /F "tokens=1-6 delims=,-./: " %%A in ("%DateTime%") do (
    rem For English US date MM/DD/YYYY or M/D/YYYY
    set "Day=%%B" & set "Month=%%A" & set "Year=%%C"
    rem For German date DD.MM.YYYY or English UK date DD/MM/YYYY
    rem set "Day=%%A" & set "Month=%%B" & set "Year=%%C"
    set "Hour=%%D" & set "Minute=%%E" & set "Second=%%F"
)

rem Remove leading zeros from the date/time values or calculation could be wrong.
if "%Month:~0,1%"  EQU "0" ( if "%Month:~1%"  NEQ "" set "Month=%Month:~1%"   )
if "%Day:~0,1%"    EQU "0" ( if "%Day:~1%"    NEQ "" set "Day=%Day:~1%"       )
if "%Hour:~0,1%"   EQU "0" ( if "%Hour:~1%"   NEQ "" set "Hour=%Hour:~1%"     )
if "%Minute:~0,1%" EQU "0" ( if "%Minute:~1%" NEQ "" set "Minute=%Minute:~1%" )
if "%Second:~0,1%" EQU "0" ( if "%Second:~1%" NEQ "" set "Second=%Second:~1%" )

rem Add 12 hours for time range 01:00:00 PM to 11:59:59 PM,
rem but keep the hour as is for 12:00:00 PM to 12:59:59 PM.
if "%Add12Hours%" == "1" (
    if %Hour% LSS 12 set /A Hour+=12
)
set "DateTime="
set "Add12Hours="

rem Must use 2 arrays as more than 31 tokens are not supported
rem by command line interpreter cmd.exe respectively command FOR.
set /A "Index1=Year-1979"
set /A "Index2=Index1-30"

if %Index1% LEQ 30 (
    rem Get number of days to year for the years 1980 to 2009.
    for /F "tokens=%Index1% delims= " %%Y in ("3652 4018 4383 4748 5113 5479 5844 6209 6574 6940 7305 7670 8035 8401 8766 9131 9496 9862 10227 10592 10957 11323 11688 12053 12418 12784 13149 13514 13879 14245") do set "Days=%%Y"
    for /F "tokens=%Index1% delims= " %%L in ("Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N") do set "LeapYear=%%L"
) else (
    rem Get number of days to year for the years 2010 to 2038.
    for /F "tokens=%Index2% delims= " %%Y in ("14610 14975 15340 15706 16071 16436 16801 17167 17532 17897 18262 18628 18993 19358 19723 20089 20454 20819 21184 21550 21915 22280 22645 23011 23376 23741 24106 24472 24837") do set "Days=%%Y"
    for /F "tokens=%Index2% delims= " %%L in ("N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N") do set "LeapYear=%%L"
)

rem Add the days to month in year.
if "%LeapYear%" == "N" (
    for /F "tokens=%Month% delims= " %%M in ("0 31 59 90 120 151 181 212 243 273 304 334") do set /A "Days+=%%M"
) else (
    for /F "tokens=%Month% delims= " %%M in ("0 31 60 91 121 152 182 213 244 274 305 335") do set /A "Days+=%%M"
)

rem Add the complete days in month of year.
set /A "Days+=Day-1"

rem Calculate the seconds which is easy now.
set /A "Seconds=Days*86400+Hour*3600+Minute*60+Second"

rem Exit this subroutine
goto :EOF

rojo ajout d'informations sur la date et l'heure de paramètres du format, fichiers système et la version de Windows peut être ignoré par l'aide de wmic - Windows Management Instrumentation utilitaire de ligne de commande.

À l'aide de wmic a l'avantage de format fixe la date et l'heure des chaînes et donc le lot code fonctionne sur tous les ordinateurs Windows sans adaptations locales format de date/heure.

Aussi la version de Windows n'a pas d'importance sur l'utilisation de wmic en raison de l'usage interne de GetFileTime fonction (le plus probable).

Le système de fichiers est seulement important sur l'évaluation de la également à quelques minutes de décalage de l'heure locale /heure du fichier à UTC. Commande wmic retourne sur les lecteurs FAT juste +*** pour les minutes de décalage UTC alors que les minutes de décalage est correct pour la dernière modification du fichier d'un fichier sur un lecteur NTFS.

Exemple pour le même fichier sur une partition NTFS ou FAT32 disque:

NTFS:  20071011192622.000000+120
FAT32: 20071011192622.000000+***

+120 est la somme de +60 minutes pour CET (Heure d'europe Centrale) et +de 60 minutes pour les actifs de l'heure d'été, ou en d'autres mots +120 minutes pour CEST (Central European Summer Time).

Par conséquent, le code du lot ci-dessous n'est pas d'évaluer les minutes de décalage à l'UTC qui n'est pas nécessaire sur la comparaison de dernière modification du fichier d'un fichier avec l'heure locale actuelle.

Plus le nom de fichier doit être spécifié toujours avec chemin d'accès complet dans wmic ligne de commande. Juste en spécifiant le nom de fichier pour un fichier dans le répertoire courant ou un nom de fichier avec un chemin relatif ne fonctionne pas. Et chaque barre oblique inverse doit être échappés avec une barre oblique inverse dans le nom du fichier avec le chemin d'accès.

Le principal inconvénient sur l'utilisation de wmic est la vitesse. Le code de lot besoins ci-dessus sur mon ordinateur environ 50 ms à terminer selon Le Moniteur De Processus log (moyenne de plusieurs essais). Le code du lot ci-dessous l'appel de wmic deux fois les besoins pour la même tâche sur 1500 ms à la fin (aussi une valeur moyenne). Par conséquent l'utilisation de wmic sur un grand nombre de fichiers est certainement pas une bonne idée si elle peut être évitée en raison local format de date/heure est connu.

@echo off
setlocal EnableExtensions

rem Get seconds since 1970-01-01 for current date and time.
for /F "tokens=2 delims==." %%T in ('%SystemRoot%\System32\wbem\wmic.exe OS GET LocalDateTime /VALUE') do call :GetSeconds %%T

rem Subtract seconds for 4 hours (4 * 3600 seconds) from seconds value.
set /A "CompareTime=Seconds-4*3600"

rem Define batch file itself as the file to compare time by default.
set "FileToCompareTime=%~f0"

rem If batch file is started with a parameter and the parameter
rem specifies an existing file (or directory), compare with last
rem modification date of this file.
if not "%~1" == "" (
    if exist "%~f1" set "FileToCompareTime=%~f1"
)

rem Get seconds value for the specified file.
set "DataFile=%FileToCompareTime:\=\\%"
for /F "usebackq tokens=2 delims==." %%T in (`%SystemRoot%\System32\wbem\wmic.exe DATAFILE where "name='%DataFile%'" GET LastModified /VALUE`) do echo call :GetSeconds %%T

rem Compare the two seconds values.
if %Seconds% LSS %CompareTime% (
    echo File %FileToCompareTime% was last modified for more than 4 hours.
) else (
    echo File %FileToCompareTime% was last modified within the last 4 hours.
)
endlocal
goto :EOF


rem Date/time format used by the command line utility of Windows
rem Management Instrumentation is always YYYYMMDDHHmmss with a
rem dot and a 6 digit microsecond value and plus/minus 3 digit
rem time offset to UTC in minutes independent on region and
rem language settings. Microsecond is always 000000 for a file
rem time. The minutes offset including time zone offset and
rem current daylight saving time offset is returned for a file
rem time only for a file on an NTFS drive. Minutes offset is
rem +*** for a file on a FAT drive (at least on Windows XP).

:GetSeconds
rem Get year, month, day, hour, minute and second from first parameter.
set "DateTime=%~1"
set "Year=%DateTime:~0,4%"
set "Month=%DateTime:~4,2%"
set "Day=%DateTime:~6,2%"
set "Hour=%DateTime:~8,2%"
set "Minute=%DateTime:~10,2%"
set "Second=%DateTime:~12,2%"
rem echo Date/time is: %Year%-%Month%-%Day% %Hour%:%Minute%:%Second%

rem Remove leading zeros from the date/time values or calculation could be wrong.
if "%Month:~0,1%"  EQU "0" ( if "%Month:~1%"  NEQ "" set "Month=%Month:~1%"   )
if "%Day:~0,1%"    EQU "0" ( if "%Day:~1%"    NEQ "" set "Day=%Day:~1%"       )
if "%Hour:~0,1%"   EQU "0" ( if "%Hour:~1%"   NEQ "" set "Hour=%Hour:~1%"     )
if "%Minute:~0,1%" EQU "0" ( if "%Minute:~1%" NEQ "" set "Minute=%Minute:~1%" )
if "%Second:~0,1%" EQU "0" ( if "%Second:~1%" NEQ "" set "Second=%Second:~1%" )

rem Must use 2 arrays as more than 31 tokens are not supported
rem by command line interpreter cmd.exe respectively command FOR.
set /A "Index1=Year-1979"
set /A "Index2=Index1-30"

if %Index1% LEQ 30 (
    rem Get number of days to year for the years 1980 to 2009.
    for /F "tokens=%Index1% delims= " %%Y in ("3652 4018 4383 4748 5113 5479 5844 6209 6574 6940 7305 7670 8035 8401 8766 9131 9496 9862 10227 10592 10957 11323 11688 12053 12418 12784 13149 13514 13879 14245") do set "Days=%%Y"
    for /F "tokens=%Index1% delims= " %%L in ("Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N") do set "LeapYear=%%L"
) else (
    rem Get number of days to year for the years 2010 to 2038.
    for /F "tokens=%Index2% delims= " %%Y in ("14610 14975 15340 15706 16071 16436 16801 17167 17532 17897 18262 18628 18993 19358 19723 20089 20454 20819 21184 21550 21915 22280 22645 23011 23376 23741 24106 24472 24837") do set "Days=%%Y"
    for /F "tokens=%Index2% delims= " %%L in ("N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N") do set "LeapYear=%%L"
)

rem Add the days to month in year.
if "%LeapYear%" == "N" (
    for /F "tokens=%Month% delims= " %%M in ("0 31 59 90 120 151 181 212 243 273 304 334") do set /A "Days+=%%M"
) else (
    for /F "tokens=%Month% delims= " %%M in ("0 31 60 91 121 152 182 213 244 274 305 335") do set /A "Days+=%%M"
)

rem Add the complete days in month of year.
set /A "Days+=Day-1"

rem Calculate the seconds which is easy now.
set /A "Seconds=Days*86400+Hour*3600+Minute*60+Second"

rem Exit this subroutine
goto :EOF

OriginalL'auteur Mofi

La solution à cela dépendra beaucoup sur le temps prévu-gamme, car autant que je sache, vous n'obtenez pas le temps que l'un d'entier dans un fichier de commandes sans programmes externes. Cela signifie que vous devez analyser la valeur de temps dans votre script, et la quantité de l'analyse et le nombre de calculs nécessaires, dépendent de la gamme vous avez besoin pour ce travail.
Voici une solution simple. Il suppose que le fichier ne peut PAS être âgés de plus de 24 heures.

set "filename=myfile.txt"
rem extract current date and time
for /f "tokens=1-5 delims=.:, " %%a in ("%date% %time%") do (
  set day=%%a&set mon=%%b&set yr=%%c&set hr=%%d&set min=%%e
)
rem extract file date and time
for /f "tokens=1-5 delims=.:, " %%a in ('"dir %filename%|find "%filename%""') do (
  set fday=%%a&set fmon=%%b&set fyr=%%c&set fhr=%%d&set fmin=%%e
)
rem calculate age of file (in minutes)
set /a "age=((hr*60+min)-(fhr*60+fmin)+(24*60))%%(24*60)"
set /a "max=4*60"
if %age% geq %max% echo.file is older than 4 hours

OriginalL'auteur Superole