script pour corriger dynamiquement ophaned les utilisateurs après la db de restauration

Après avoir effectué une restauration de base de données, je veux lancer un script dynamique de fixer ophaned utilisateurs. Mon script ci-dessous une boucle par tous les utilisateurs qui sont affichés après l'exécution de sp_change_users_login "rapport" et applys un "alter user [nom d'utilisateur] avec login = [nom d'utilisateur]" déclaration de fixer SID conflits. Je suis un "incorrect erreur de syntaxe sur la ligne 15" et ne peut pas comprendre pourquoi...aider..

DECLARE @Username varchar(100), @cmd varchar(100)
DECLARE userLogin_cursor CURSOR FAST_FORWARD
FOR
SELECT UserName = name FROM sysusers
WHERE issqluser = 1 and (sid IS NOT NULL AND sid <> 0×0)
    AND suser_sname(sid) IS NULL
ORDER BY name
FOR READ ONLY
OPEN userLogin_cursor

FETCH NEXT FROM userLogin_cursor INTO @Username
WHILE @@fetch_status = 0
  BEGIN
    SET @cmd = ‘ALTER USER ‘+@username+‘ WITH LOGIN ‘+@username
    EXECUTE(@cmd)
    FETCH NEXT FROM userLogin_cursor INTO @Username
  END
CLOSE userLogin_cursor
DEALLOCATE userLogin_cursor
InformationsquelleAutor gates | 2010-05-20
  1. 1
    DECLARE @Username VARCHAR(100),
        @cmd      VARCHAR(100)

DECLARE userlogin_cursor CURSOR FAST_FORWARD FOR
  SELECT username = name
  FROM   sysusers
  WHERE  issqluser = 1
     AND (sid IS NOT NULL
          AND sid <> 0x01)
     AND Suser_sname(sid) IS NULL
  ORDER  BY name
  FOR READ ONLY

OPEN userlogin_cursor
FETCH NEXT FROM userlogin_cursor INTO @Username

WHILE @@FETCH_STATUS = 0
  BEGIN
      SET @cmd = 'ALTER USER [' + @username + '] WITH LOGIN = [' + @username + ']'
      EXECUTE(@cmd)
      FETCH NEXT FROM userlogin_cursor INTO @Username
  END

CLOSE userlogin_cursor
DEALLOCATE userlogin_cursor
    • J'oublie toujours de les crochets []. Merci!
    • Avez-vous vérifié que l'utilisateur n'en fait-il exister?
    InformationsquelleAutor Kenneth
  2. 3

    Utilisateurs orphelins peuvent être fixés à l'aide de la [dbo].[sp_change_users_login] procédure stockée.

    Boucle par tous vos utilisateurs et exécuter la procédure

    Bonne Chance

    DECLARE @UserCount INT
DECLARE @UserCurr INT
DECLARE @userName VARCHAR(100)
DECLARE @vsql NVARCHAR(4000)
DECLARE @Users TABLE(
id INT IDENTITY(1,1) PRIMARY KEY NOT NULL,
userName VARCHAR(100))
INSERT INTO @Users(UserName) 
SELECT [name] FROM 
--
master.[dbo].sysUsers -- SQL 2008 & SQL 2005
--master.dbo.sysxlogins -- SQL 2000


SELECT @UserCount = max([id]) FROM @Users
SET @UserCurr = 1

WHILE (@UserCurr <= @UserCount)
BEGIN
 SELECT @userName=userName FROM @Users WHERE [id] =@UserCurr
 SET @vsql = '[dbo].[sp_change_users_login] ''AUTO_FIX'',''' + @userName + ''''
 -- EXEC(@vsql)
 PRINT @vsql
 SET @UserCurr = @UserCurr + 1
END
    InformationsquelleAutor John DaCosta
  3. 1

    J'ai utilisé une approche similaire, l'emballage le code dans une procédure stockée:

    USE [master]
GO

CREATE PROCEDURE [sp_AutoFixAllUsers]
AS
BEGIN

    DECLARE @AutoFixCommand NVARCHAR(MAX)
    SET @AutoFixCommand = ''

    SELECT --dp.[name], dp.[sid] AS [DatabaseSID], sp.[sid] AS [ServerSID],
        @AutoFixCommand = @AutoFixCommand + ' '
         + 'EXEC sp_change_users_login ''Auto_Fix'', ''' + dp.[name] + ''';'-- AS [AutoFixCommand]
    FROM sys.database_principals dp
    INNER JOIN sys.server_principals sp
        ON dp.[name] = sp.[name] COLLATE DATABASE_DEFAULT
    WHERE dp.[type_desc] IN ('SQL_USER', 'WINDOWS_USER', 'WINDOWS_GROUP')
    AND sp.[type_desc] IN ('SQL_LOGIN', 'WINDOWS_LOGIN', 'WINDOWS_GROUP')
    AND dp.[sid] <> sp.[sid]

    IF (@AutoFixCommand <> '')
    BEGIN
        PRINT 'Fixing users in database: ' + DB_NAME()
        PRINT @AutoFixCommand
        EXEC(@AutoFixCommand)
        PRINT ''
    END
END
GO

    J'ai ensuite utilisé le sys.sp_MS_marksystemobject procédure stockée pour faire ma procédure stockée disponible dans toutes les bases de données utilisateur (lui permettant d'opérer sur les objets locaux)

    EXEC sys.sp_MS_marksystemobject 'sp_AutoFixAllUsers'

    Vous pouvez ensuite l'exécuter comme suit:

    EXEC [MyDB].[dbo].[sp_AutoFixAllUsers]

    Ou pour chaque base de données à l'aide de sp_msforeachdb:

    EXEC sp_msforeachdb '[?].[dbo].[sp_AutoFixAllUsers]'
    InformationsquelleAutor Tom Hunter