Se référant à un curseur dans un bloc anonyme

Comment pouvez-vous vous référer à un curseur spécifique de valeur s'il existe plusieurs valeurs de retour?

DECLARE
  X INTEGER;
  CURSOR c1 IS SELECT col1, col2, col3.....;
BEGIN
  OPEN c1;
  LOOP
    EXIT WHEN c1%NOTFOUND;
    FETCH (col2 from c1) INTO X;
  END LOOP;
END;

OriginalL'auteur brendan | 2012-02-24

  1. 13

    Pourquoi voudriez-vous? Sans doute, si vous êtes à la sélection de trois colonnes dans votre déclaration de curseur, vous avez besoin tous les trois colonnes dans votre code, de sorte que vous devez récupérer toutes les trois colonnes en trois variables locales, c'est à dire

    DECLARE
  x      integer;
  y      integer;
  z      integer;
  CURSOR c1
      IS SELECT column1, column2, column3
           FROM some_table;
BEGIN
  OPEN c1;
  LOOP
    FETCH c1 
     INTO x, y, z;
    EXIT WHEN c1%NOTFOUND;
  END LOOP;
  CLOSE c1;
END;

    Alternativement, vous pouvez déclarer un type d'enregistrement basé sur la déclaration de curseur et de chercher dans cette

    DECLARE
  CURSOR c1
      IS SELECT column1, column2, column3
           FROM some_table;
  c1_rec c1%ROWTYPE;
BEGIN
  OPEN c1;
  LOOP
    FETCH c1 
     INTO c1_rec;
    dbms_output.put_line( c1_rec.column2 );
    EXIT WHEN c1%NOTFOUND;
  END LOOP;
  CLOSE c1;
END;

    Vous pouvez également vous débarrasser de l'explicite boucle entièrement qui est généralement l'approche privilégiée puisque vous n'avez pas à vous soucier de curseur fuites et (dans les versions modernes) Oracle peut automatiquement faire en vrac recueille pour vous

    DECLARE
  CURSOR c1
      IS SELECT column1, column2, column3
           FROM some_table;
BEGIN
  FOR c1_rec IN c1
  LOOP
    dbms_output.put_line( c1_rec.column2 );
  END LOOP;
END;

    OriginalL'auteur Justin Cave