Sélectionnez la première cellule vide dans la colonne F à partir de la ligne 1. (sans l'aide de décalage )

C'est une requête que je suis vraiment confus. Coz j'ai cherché tant de fois mais j'ai toujours trouver les codes lié à la découverte de la dernière ou la première cellule non vide.
Essayé au-dessous de codes. diff codes ont été séparés par le mot "même"

iRow = Worksheets("Sheet1").Cells(Rows.Count,1).End(XlUp).Row

même

Sub LastCellBeforeBlankInColumn()

Range("A1").End(xldown).Select

End Sub

même

Trouver le dernier a utilisé des cellules dans une Colonne:

Sub LastCellInColumn()

Range("A65536").End(xlup).Select

End Sub

même

Trouver la dernière cellule, avant un passage à vide dans une Rangée:

Sub LastCellBeforeBlankInRow()

Range("A1").End(xlToRight).Select

End Sub

même

Trouver le très utilisée la dernière cellule d'une Ligne:

Sub LastCellInRow()

Range("IV1").End(xlToLeft).Select

End Sub

même

Worksheets("Sheet1").Range("A1").End(xlDown).Row + 1

même

LastRow = Range("A" & Rows.Count).End(xlUp).Row + 1
Sheets("SheetName").Range("A" & LastRow).Paste

même

Dim FirstBlankCell as Range
Set FirstBlankCell=Range("A" & rows.Count).end(xlup).offset(1,0)
FirstBlankCell.Activate

'Find the last used row in a Column: column A in this example
Dim LastRow As Long
Dim NextRow As Long
With ActiveSheet
    LastRow = .Cells(.Rows.Count, "F").End(xlUp).Row
End With
NextRow = LastRow + 1

Avez-vous vu cela? stackoverflow.com/questions/11169445/...
N'est-il pas la même chose. Je veux sélectionner ou activer la première cellule vide. exemple: Si Il y a des valeurs jusqu'à la cellule F5 puis je veux activer la Cellule F6 et ne pas utiliser de Compenser en faisant de la sorte
Si vous connaissez la dernière ligne, puis il suffit d'utiliser Range("F" & LastRow).Activate Si je ne suis pas trop en faveur de .Activate
Siddharth je sais que... mais encore une fois le LastRow est utilisé des cellules avec une certaine valeur. Je veux la cellule du dessous
LastRow = .Range("E" & .Rows.Count).End(xlUp).Row + 1 vous donnera la ligne 😉

OriginalL'auteur Nishant | 2013-02-19

12

Si tout ce que vous essayez de faire est de sélectionnez la première cellule vide dans une colonne donnée, vous pouvez donner à ceci un essai:

Code:
```
Public Sub SelectFirstBlankCell()
    Dim sourceCol As Integer, rowCount As Integer, currentRow As Integer
    Dim currentRowValue As String

    sourceCol = 6   'column F has a value of 6
    rowCount = Cells(Rows.Count, sourceCol).End(xlUp).Row

    'for every row, find the first blank cell and select it
    For currentRow = 1 To rowCount
        currentRowValue = Cells(currentRow, sourceCol).Value
        If IsEmpty(currentRowValue) Or currentRowValue = "" Then
            Cells(currentRow, sourceCol).Select
        End If
    Next
End Sub
```
Avant la Sélection de la première cellule vide pour sélectionner:

Après La Sélection:

Hey Merci Sam c'est Ce que j'essayais de faire. Si j'ai regardé à Siddharth de la suggestion et qui en fait trop et l'ont déjà utilisé. Mais votre sna serait utile à l'avenir pour moi. merci beaucoup
Est-il un moyen de faire cela comme une formule plutôt qu'en VBA?
Ne pouvez pas obtenir que cela fonctionne quand il n'y a qu'une seule cellule au-dessus d'elle. E. g. F1 a une valeur, mais F2 ne fonctionne pas.

OriginalL'auteur Sam
11

Dans le cas où l'on tombe sur ce que je viens d'avoir...

Trouver la Première cellule vide dans une colonne(je suis en utilisant la colonne D, mais ne veulent pas inclure D1)
```
NextFree = Range("D2:D" & Rows.Count).Cells.SpecialCells(xlCellTypeBlanks).Row
Range("D" & NextFree).Select
```
NextFree est juste un nom, vous pouvez utiliser des saucisses si vous le souhaitez.

les deux premières solutions ne fonctionne pas, il n'
Ne fonctionne pas si la ligne est vide au départ.

OriginalL'auteur Cameronface

Code de Sam est bonne, mais je pense qu'il faut un peu de correction,

Public Sub SelectFirstBlankCell()
    Dim sourceCol As Integer, rowCount As Integer, currentRow As Integer
    Dim currentRowValue As String

    sourceCol = 6   'column F has a value of 6
    rowCount = Cells(Rows.Count, sourceCol).End(xlUp).Row

    'for every row, find the first blank cell and select it
    For currentRow = 1 To rowCount
        currentRowValue = Cells(currentRow, sourceCol).Value
        If IsEmpty(currentRowValue) Or currentRowValue = "" Then
            Cells(currentRow, sourceCol).Select
            Exit For 'This is missing...
        End If
    Next
End Sub

Grâce

et vous pouvez utiliser de Long au lieu d'un Entier, parce que les lignes peuvent aller très loin en bas (ou en haut ?)

OriginalL'auteur RedLeo

7

Si tout ce que vous essayez de faire est de sélectionner la première cellule vide dans une colonne donnée, vous pouvez donner à ceci un essai:
```
Range("A1").End(xlDown).Offset(1, 0).Select
```
Si vous l'utilisez, par rapport à une colonne que vous avez choisi, cela fonctionne:
```
Selection.End(xlDown).Offset(1, 0).Select
```
De loin la réponse la plus simple.
Pas grand si la colonne est vide, il suffit de sélectionner l'absolu de la dernière cellule.

OriginalL'auteur Chandan B

Si vous êtes à la recherche pour un liner (non compris les désignations et les commentaires d'essayer de

Dim iRow As Long
Dim ws As Worksheet
Set ws = Worksheets("Name")

    'find first empty cell in column F (coming up from the bottom) and return row number
iRow = ws.Range("F:F").Find(What:="*", SearchOrder:=xlRows, SearchDirection:=xlPrevious, LookIn:=xlValues).Row + 1

OriginalL'auteur CammoL

J'ai adapté un peu le code de tout le monde, fait dans une Fonction, l'a rendu plus rapide (tableau), et les paramètres ajoutés :

Public Function FirstBlankCell(Optional Sh As Worksheet, Optional SourceCol As Long = 1, Optional ByVal StartRow& = 1, Optional ByVal SelectCell As Boolean = False) As Long
Dim RowCount As Long, CurrentRow As Long
Dim CurrentRowValue As String
Dim Data()
If Sh Is Nothing Then Set Sh = ActiveSheet

With Sh

    rowCount = .Cells(.Rows.Count, SourceCol).End(xlUp).Row
    Data = .Range(.Cells(1, SourceCol), .Cells(rowCount, SourceCol)).Value2

    For currentRow = StartRow To RowCount
        If Data(currentRow, SourceCol) = vbNullString Then
            If SelectCell Then .Cells(currentRow, SourceCol).Select
            'if selection is out of screen, intead of .select , use : application.goto reference:=.cells(...), scroll:= true
            FirstBlankCell = currentRow
            Exit For
        End If
    Next

End With ' Sh

Erase Data
Set Sh = Nothing
End Function

C'est vraiment exagéré, et ne fonctionne pas pour les colonnes vides.

OriginalL'auteur Patrick Lepelletier

Public Sub SelectFirstBlankCell()
    Dim sourceCol As Integer, rowCount As Integer, currentRow As Integer
    Dim currentRowValue As String

    sourceCol = 6   'column F has a value of 6
    rowCount = Cells(Rows.Count, sourceCol).End(xlUp).Row

    'for every row, find the first blank cell and select it
    For currentRow = 1 To rowCount
        currentRowValue = Cells(currentRow, sourceCol).Value
        If IsEmpty(currentRowValue) Or currentRowValue = "" Then
            Cells(currentRow, sourceCol).Select
        End If
    Next
End Sub

Si une colonne contient plus d'une cellule vide en permanence ensuite, ce code ne fonctionnera pas correctement

OriginalL'auteur Goka raju

C'est très rapide et propre façon de faire. Il prend également en charge les colonnes vides où, comme aucune des réponses ci-dessus a travaillé pour des colonnes vides.

Utilisation: SelectFirstBlankCell("F")

Public Sub SelectFirstBlankCell(col As String)

    Dim i As Integer
    Dim NextCell As Integer

    For i = 1 To 10000
        If Range(col & CStr(i)).Value = "" Then
            NextCell = i
            Exit For
        End If
    Next i

    Range(col & CStr(i)).Select
End Sub

OriginalL'auteur user2924019

Je pense que Do Untilboucle est plus propre, plus court et plus approprié ici:

Public Sub SelectFirstBlankCell(col As String)
    Dim Column_Index as Integer
    Dim Row_Counter as 

    Column_Index = Range(col & 1).Column
    Row_Counter = 1

    Do Until IsEmpty(Cells(Row_Counter, 1))
        Row_Counter = Row_Counter + 1
    Loop

    Cells(Row_Counter, Column_Index).Select

OriginalL'auteur Matthias Baetens

Vous devez vous connecter pour publier un commentaire.