sélectionnez une plage de texte à partir d'un document Word et de les copier dans un autre document Word

Je suis en train d'utiliser VBA pour extraire des phrases dans un document Word et le mettre dans un autre document Word.
Ainsi, par exemple, si nous avons besoin de trouver le titre de l'organisation, nous suivons l'algorithme:

De la recherche pour "Titre"
Ne (Prendre) chaque personnage après "Titre" et (arrêt) jusqu'à ce que "l'Adresse"

OriginalL'auteur Lisa Qing | 2013-06-07

ms-word word-vba

Les ouvrages suivants, mais il y a peut être un moyen plus efficace de le faire:

Sub FindIt()
    Dim blnFound As Boolean
    Dim rng1 As Range
    Dim rng2 As Range
    Dim rngFound As Range
    Dim strTheText As String

    Application.ScreenUpdating = False
    Selection.HomeKey wdStory
    Selection.Find.Text = "Title"
    blnFound = Selection.Find.Execute
    If blnFound Then
        Selection.MoveRight wdWord
        Set rng1 = Selection.Range
        Selection.Find.Text = "Address"
        blnFound = Selection.Find.Execute
        If blnFound Then
            Set rng2 = Selection.Range
            Set rngFound = ActiveDocument.Range(rng1.Start, rng2.Start)
            strTheText = rngFound.Text
            MsgBox strTheText
        End If
    End If
    'move back to beginning
    Selection.HomeKey wdStory
    Application.ScreenUpdating = True
End Sub

Vous pouvez basculer entre les documents à l'aide d'Activer, de préférence à l'aide de variables d'objet.

Microsoft MVP Jay Freedman aimablement mis à jour ce pour moi de travailler sans la Sélection de l'objet, ce qui rend beaucoup plus lisible.

Sub RevisedFindIt()
' Purpose: display the text between (but not including)
' the words "Title" and "Address" if they both appear.
    Dim rng1 As Range
    Dim rng2 As Range
    Dim strTheText As String

    Set rng1 = ActiveDocument.Range
    If rng1.Find.Execute(FindText:="Title") Then
        Set rng2 = ActiveDocument.Range(rng1.End, ActiveDocument.Range.End)
        If rng2.Find.Execute(FindText:="Address") Then
            strTheText = ActiveDocument.Range(rng1.End, rng2.Start).Text
            MsgBox strTheText
        End If
    End If
End Sub

La seule condition nécessaire est d'obtenir ce texte dans l'autre document. Quelque chose comme:

Documents(2).Range.Text = strTheText

Souhaitez-vous ajouter quelques notes?
Désolé, non, je pense que c'est trop demander. (Peut-être que quelqu'un d'autre bénévole.) Je pense que le code est assez clair, si vous l'avez lu, ou pas, au travers de. D'ailleurs, je ne suis pas sûr de ce que les notes, je voudrais ajouter! Cliquez sur un mot et appuyez sur la touche de fonction F1 à voir la page d'aide pour cela.
Merci!!!! Ouais. Je l'ai eu! Mais, comment obtenir ce texte dans un autre document? J'ai essayé la manière dont vous l'avez mentionné, mais je ne suis pas sûr de savoir comment cela fonctionne. Je ne suis pas familier avec VB. Merci beaucoup pour votre aide!

OriginalL'auteur Andy G

Ce code va écrire dans un fichier externe:

Sub RevisedFindIt_savetofile2 () 
' Purpose: display the text between (but not including)
' the words "Title" and "Address" if they both appear.
'This file will search current document only, the data in open word document.
Dim rng1 As Range
Dim rng2 As Range
Dim strTheText As String
Dim DestFileNum As Long
Dim sDestFile As String

sDestFile = "C:\test-folder\f12.txt" 'Location of external file
DestFileNum = FreeFile()
'A valid file number in the range 1 to 511,
'inclusive. Use the FreeFile function to obtain the next available file number.

Open sDestFile For Output As DestFileNum 'This opens new file with name DestFileNum
Set rng1 = ActiveDocument.Range
If rng1.Find.Execute(FindText:="Title") Then
    Set rng2 = ActiveDocument.Range(rng1.End, ActiveDocument.Range.End)
    If rng2.Find.Execute(FindText:="Address") Then
        strTheText = ActiveDocument.Range(rng1.End, rng2.Start).Text
        MsgBox strTheText 'writes string to a message box
        Print #DestFileNum, strTheText 'Print # will write to external file with the text strTheText
    End If
End If
Close #DestFileNum 'Close the destination file
End Sub

OriginalL'auteur equalizer

0

Vous pourriez (de préférence) d'utiliser le nom de l'autre document, plutôt que l'indice de référence (2):
```
Documents("OtherName").Range.Text = strTheText
```
Cependant, cela va changer le texte pour l'ensemble du document, alors vous avez besoin pour naviguer à l'endroit où vous souhaitez insérer le texte.

Il est de loin préférable, si possible, qu'il y a des pré-existantes des Signets dans le document (ou le modèle) que vous pouvez consulter:
```
Documents("OtherName").Bookmarks("bkSome").Range.Text = strTheText
```
Bonne chance.

OriginalL'auteur Andy G
0

Excel et Word ont un Range objet. Parce que vous êtes dans Excel VBA mais essayez de référence le Mot Range objet dont vous avez besoin pour qualifier la déclaration de la variable, de sorte que Excel sait que vous êtes à l'aide d'un Mot à l'objet Range.
```
Dim rng1 As Word.Range
Dim rng2 As Word.Range
```
De crédit à ChipsLetten pour repérer ce

OriginalL'auteur Swifty

Vous devez vous connecter pour publier un commentaire.