SendEmail avec des composants Indy

Le code de votre question qui est écrit pour Indy 9 et à partir de votre erreur du compilateur semble que vous êtes en utilisant Indy 10. Pour vos erreurs du compilateur:

• Undeclared identifier: Self - le Self est le pointeur vers l'instance de la classe elle-même et, puisque vous n'avez pas écrit le SendSimpleMail comme une méthode de classe, mais comme une procédure autonome, vous n'avez pas de Self juste parce que vous n'avez pas de n'importe quelle classe. La méthode de classe, vous pouvez écrire par exemple pour votre classe de formulaire, comme par exemple TForm1.SendSimpleMail, où à l'intérieur de la méthode la Self aurait sens de la TForm1 exemple, la forme elle-même.

• Et le reste des erreurs que vous avez obtenu parce que vous aviez accès à la TIdSMTP de la classe, pas l'objet de l'instance. Couramment utilisé en pratique est de déclarer une variable locale, de créer une instance d'objet de l'affecter à la variable travail avec l'objet (variable) et de libérer l'instance de l'objet.

Je voudrais essayer quelque chose comme ceci (testé avec Indy 10 livré avec Delphi 2009):

uses
  IdSMTP, IdMessage, IdEMailAddress;

procedure SendSimpleMail;
var
  IdSMTP: TIdSMTP;
  IdMessage: TIdMessage;
  IdEmailAddressItem: TIdEmailAddressItem;
begin
  IdSMTP := TIdSMTP.Create(nil);
  try
    IdSMTP.Host := 'smtp.gmail.com';
    IdSMTP.Port := 25;
    IdSMTP.AuthType := satDefault;
    IdSMTP.Username := '[email protected]';
    IdSMTP.Password := 'password';
    IdSMTP.Connect;
    if IdSMTP.Authenticate then
    begin
      IdMessage := TIdMessage.Create(nil);
      try
        IdMessage.From.Name := 'User Name';
        IdMessage.From.Address := '[email protected]';
        IdMessage.Subject := 'E-mail subject';
        IdMessage.Body.Add('E-mail body.');

        IdEmailAddressItem := IdMessage.Recipients.Add;
        IdEmailAddressItem.Address := '[email protected]';

        IdSMTP.Send(IdMessage);
      finally
        IdMessage.Free;
      end;
    end;
    IdSMTP.Disconnect;
  finally
    IdSMTP.Free;
  end;
end;

OriginalL'auteur TLama