SQL Server 2005 - fermeture de couchage connexions

Me semble que j'ai une application sur mon serveur de Dev qui a beaucoup de connexions ouvertes (ils devraient être là, mais certains mauvais couche de données a été utilisé pour les ouvrir, qui a oublié de fermer). Je veux juste leur fermée, donc je peux garder les autres applications en cours d'exécution sur le serveur. Comment puis-je la force de toutes les connexions à fermer?

OriginalL'auteur digiguru | 2008-12-15

  1. 5

    Utiliser le script suivant pour tuer les sessions inactives partir d'un hôte spécifique /login. Vous pouvez l'utiliser à partir d'un travail planifié, bien sûr, votre priorité devrait être de fixer votre application de niveau. 

    SET NOCOUNT ON;
DECLARE @host VARCHAR(50), @login NVARCHAR(128);
SET @host = 'fooHost'; --NULL to kill sessions from all hosts.
SET @login = 'fooLogin';
DECLARE @cmd NVARCHAR(255);
DECLARE @possition INT, @total INT, @selSpid SMALLINT;
DECLARE @spidInfo TABLE
(
[id] INT IDENTITY(1,1),
spid SMALLINT,
loginame NVARCHAR(128)
);
INSERT @spidInfo(spid, loginame)
SELECT session_id, login_name 
FROM sys.dm_exec_sessions
WHERE is_user_process = 1 AND [status] = 'sleeping' AND 
login_name = @login AND [host_name] = COALESCE(@host, [host_name]);
SELECT @total = @@IDENTITY, @selSpid = 0, @possition = 0;
WHILE @possition < @total
BEGIN
SELECT TOP 1 @selSpid = spid, @possition = [id]
FROM @spidInfo
WHERE [ID] > @possition
SET @cmd = N'KILL ' + CAST(@selSpid AS NVARCHAR(10));
EXEC sp_executesql @cmd;
PRINT 'SessionId = ' + CAST(@selSpid AS NVARCHAR(10)) + '[' + @login + 
'] killed by ' + system_user + ' at ' + CAST(GETDATE() AS VARCHAR(50));
END;
IF (@total = 0)
PRINT 'No sessions owned by user ' + '[' + @login + ']';

    OriginalL'auteur Thuglife

  2. 3

    Autres que de tuer vos connexions manuellement, vous pouvez

    • Disposer de connexions. C'est, de récupérer les objets de Connexion en quelque sorte et de les appeler .Fermer et .Dispose (). À l'aide de "l'aide" serait l'idéal car il demande .Dispose() automatiquement pour vous.
    • Recycler votre pool d'applications.
    Merci - j'ai une couche de données qui est jetable et tue toutes les connexions sur les éliminer, mais pour une raison quelconque, le devloper de travail sur cette application a décidé de ne pas tuer l'accès aux données. Qu'entendez-vous par recyclage de l'application de la piscine?
    Ce n'est rien à voir avec les connexions SQL Server...
    Eh bien, si c'est une application web s'exécutant sur IIS, vous pouvez recycler (=redémarrer) l'application IIS chaque maintenant et puis, qui, évidemment, tue toutes les connexions. Si ce n'est pas une application web, puis vous ne pouvez pas utiliser cette approche. Ce ne sont pas des MSSQL des solutions spécifiques, mais va tuer les connexions n'en est pas moins.
    C'est une application web, et cela a bien fonctionné.

    OriginalL'auteur Tamas Czinege

  3. 3

    Utiliser la colonne last_batch de sysprocesses travailler si c'est vraiment actif ou non.
    SPID > 50 (ou peut - >= 50?) pour éviter de tuer les Spid système.

    Comparer ce désirée pour votre temps de sommeil et de TUER spid.

    Vous aurez à boucle à travers.

    DECLARE @kill_id smallint 
DECLARE spid_cursor CURSOR FOR
select spid from sysprocesses 
where dbid = > 4 and last_batch < dateadd(hour, -24, getdate()) and spid >= 50
OPEN spid_cursor
FETCH NEXT FROM spid_cursor INTO @kill_id
WHILE (@@FETCH_STATUS = 0)
BEGIN
-- Kill the current spid here
-- KILL @kill_id <---This line will not work
-- Get the next cursor row
FETCH NEXT FROM spid_cursor INTO @kill_id
END 
CLOSE spid_cursor
DEALLOCATE spid_cursor
    De bons conseils! Merci

    OriginalL'auteur gbn

  4. 2

    De la première exécution de ce pour trouver le fautif de la base de données.....

    SELECT DB_NAME(dbid) as 'Database Name', 
COUNT(dbid) as 'Total Connections' 
FROM master.dbo.sysprocesses WITH (nolock)
WHERE dbid > 0
GROUP BY dbid
SELECT @@MAX_CONNECTIONS AS 'Max Allowed Connections'

    Puis le lancer pour tuer les connexions à l'souhaité DB

    USE master
go
DECLARE @dbname sysname
SET @dbname = 'Events'
DECLARE @spid int
SELECT @spid = min(spid) from master.dbo.sysprocesses where dbid = db_id(@dbname)
WHILE @spid IS NOT NULL
BEGIN
EXECUTE ('KILL ' + @spid)
SELECT @spid = min(spid) from master.dbo.sysprocesses where dbid = db_id(@dbname) AND spid > @spid
END

    OriginalL'auteur