SQL Server 2005 obtenir la première et la dernière date pour un mois dans une année

J'ai une procédure stockée qui doit accepter un mois que int (1-12) et une année en tant que int. Compte tenu de ces deux valeurs, je dois déterminer la date de la portée de ce mois. J'ai donc besoin d'une variable datetime représenter le premier jour de ce mois, et une autre variable datetime pour représenter le dernier jour de ce mois. Est-il assez facile d'obtenir cette info?

source d'informationauteur Ristogod

  1. 14
    DECLARE @Month int
DECLARE @Year int

set @Month = 2
set @Year = 2004

select DATEADD(month,@Month-1,DATEADD(year,@Year-1900,0)) /*First*/

select DATEADD(day,-1,DATEADD(month,@Month,DATEADD(year,@Year-1900,0))) /*Last*/

    Mais de quoi avez-vous besoin comme le temps composant pour le dernier jour du mois? Si votre datetimes avoir le temps de composants autres que le minuit, vous pouvez ainsi être mieux de faire quelque chose comme 

    WHERE COL >= DATEADD(month,@Month-1,DATEADD(year,@Year-1900,0)) 
     AND COL < DATEADD(month,@Month,DATEADD(year,@Year-1900,0))

    De cette façon, votre code sera de continuer à travailler si vous finalement migrer vers SQL Server 2008 et la plus grande précision datetime les types de données.

  2. 19

    Premier jour du mois: SELECT DATEADD(mm, DATEDIFF(mm, 0, GETDATE()), 0)

    Dernier jour du mois: SELECT DATEADD(ms, -3, DATEADD(mm, DATEDIFF(m, 0, GETDATE()) + 1, 0))

    Substituer une variable DateTime valeur pour GETDATE().

    Je l'ai eu il y a longtemps de ce très pratique page qui a tout un tas d'autres calculs de date, comme le "lundi de la semaine en cours" et "le premier lundi du mois".

  3. 1
    DECLARE @Month INTEGER
DECLARE @Year INTEGER
SET @Month = 10
SET @Year = 2010

DECLARE @FirstDayOfMonth DATETIME
DECLARE @LastDayOfMonth DATETIME

SET @FirstDayOfMonth = Str(@Year) + RIGHT('0' + Str(@Month), 2) + '01'
SET @LastDayOfMonth = DATEADD(dd, -1, DATEADD(mm, 1, @FirstDayOfMOnth))
SELECT @FirstDayOfMonth, @LastDayOfMonth
  4. 1

    Essayez ceci:

    Declare @month int, @year int;
Declare @first DateTime, @last DateTime;
Set @month=10;
Set @year=2010;
Set @first=CAST(CAST(@year AS varchar) + '-' + CAST(@month AS varchar) + '-' + '1' AS DATETIME);
Set @last=DATEADD(s,-1,DATEADD(mm, DATEDIFF(m,0,@first)+1,0));

SELECT @first,@last;
  5. 1
    DECLARE @Month int;
DECLARE @Year int;
DECLARE @FirstDayOfMonth DateTime;
DECLARE @LastDayOfMonth DateTime;

SET @Month = 3
SET @Year = 2010

SET @FirstDayOfMonth = CONVERT(datetime, CAST(@Month as varchar) + '/01/' + CAST(@Year as varchar));
SET @LastDayOfMonth = DATEADD(month, 1, CONVERT(datetime, CAST(@Month as varchar)+ '/01/' + CAST(@Year as varchar))) - 1;
  6. 1
    select [FirstDay Of The Month] as Text ,convert(varchar,dateadd(d,-(day(getdate()-1)),getdate()),106) 'Date'
union all
select [LastDay Of The Month], convert(varchar,dateadd(d,-day(getdate()),dateadd(m,1,getdate())),106)
  7. 1
    DECLARE @Month  int = 3, @Year  int = 2016
DECLARE @StartDate DATETIME
DECLARE @EndDate DATETIME

-- First date of month
SET @StartDate = DATEADD(MONTH, @Month-1, DATEADD(YEAR, @Year-1900, 0));
-- Last date of month
SET @EndDate = DATEADD(SS, -1, DATEADD(MONTH, @Month, DATEADD(YEAR, @Year-1900, 0)))

    Ce sera de retour date de la première et de la dernière date avec le temps composant.

  8. 0

    Mois en cours, Date de la dernière:

    select dateadd(dd,-day(dateadd(mm,1,getdate())),dateadd(mm,1,getdate()))

    Mois en cours 1er Jour:

    select dateadd(dd,-day(getdate())+1,getdate())