SQL Server Déclencheur de mise à Jour, Obtenir Uniquement les champs modifiés

À l'intérieur de la gâchette, vous pouvez utiliser COLUMNS_UPDATED() comme cela dans le but de obtenir la valeur mise à jour

-- Get the table id of the trigger
--
DECLARE @idTable      INT

SELECT  @idTable = T.id 
FROM    sysobjects P JOIN sysobjects T ON P.parent_obj = T.id 
WHERE   P.id = @@procid

-- Get COLUMNS_UPDATED if update
--
DECLARE @Columns_Updated VARCHAR(50)

SELECT  @Columns_Updated = ISNULL(@Columns_Updated + ', ', '') + name 
FROM    syscolumns 
WHERE   id = @idTable   
AND     CONVERT(VARBINARY,REVERSE(COLUMNS_UPDATED())) & POWER(CONVERT(BIGINT, 2), colorder - 1) > 0

Mais ce snipet de code ne fonctionne pas lorsque vous avez une table avec plus de 62 colonnes.. Arth.Débordement...

Ici est la version finale qui gère plus de 62 colonnes, mais donne seulement le nombre de colonnes mises à jour. Il est facile de lien avec "syscolumns" pour obtenir le nom

DECLARE @Columns_Updated VARCHAR(100)
SET     @Columns_Updated = ''   

DECLARE @maxByteCU INT
DECLARE @curByteCU INT
SELECT  @maxByteCU = DATALENGTH(COLUMNS_UPDATED()), 
        @curByteCU = 1

WHILE @curByteCU <= @maxByteCU BEGIN
    DECLARE @cByte INT
    SET     @cByte = SUBSTRING(COLUMNS_UPDATED(), @curByteCU, 1)

    DECLARE @curBit INT
    DECLARE @maxBit INT
    SELECT  @curBit = 1, 
            @maxBit = 8
    WHILE @curBit <= @maxBit BEGIN
        IF CONVERT(BIT, @cByte & POWER(2,@curBit - 1)) <> 0 
            SET @Columns_Updated = @Columns_Updated + '[' + CONVERT(VARCHAR, 8 * (@curByteCU - 1) + @curBit) + ']'
        SET @curBit = @curBit + 1
    END
    SET @curByteCU = @curByteCU + 1
END

OriginalL'auteur podosta

Je l'ai fait en tant que simple "one-liner". Sans aide, de pivot, de boucles, de nombreuses variables etc. qui fait de la recherche comme de la programmation procédurale. SQL doit être utilisé pour traiter des ensembles de données :-), la solution est:

DECLARE @sql as NVARCHAR(1024);
select @sql = coalesce(@sql + ',' + quotename(column_name), quotename(column_name))
from INFORMATION_SCHEMA.COLUMNS
where substring(columns_updated(), columnproperty(object_id(table_schema + '.' + table_name, 'U'), column_name, 'columnId') / 8 + 1, 1) & power(2, -1 + columnproperty(object_id(table_schema + '.' + table_name, 'U'), column_name, 'columnId') % 8 ) > 0
and table_name = 'DBCustomers'
-- and column_name in ('c1', 'c2') -- limit to specific columns
-- and column_name not in ('c3', 'c4') -- or exclude specific columns
SET @sql = 'SELECT ' + @sql + ' FROM inserted FOR XML RAW';
DECLARE @x as XML;
SET @x = CAST(EXEC(@sql) AS XML);

Il utilise COLUMNS_UPDATED, prend soin de plus de huit colonnes - il gère autant de colonnes que vous le souhaitez.

Il prend soin sur le bon ordre des colonnes qui devrait être d'obtenir l'aide de COLUMNPROPERTY.

Il est basé sur la vision Les COLONNES de sorte qu'il peut inclure ou exclure uniquement les colonnes spécifiques.

OriginalL'auteur Michał Powaga

Le code ci-dessous fonctionne pour plus de 64 colonnes et enregistre uniquement les colonnes mises à jour. Suivez les instructions sur les commentaires et tout doit être bien.

/*******************************************************************************************
*         Add the below table to your database to track data changes using the trigger    *
*         below. Remember to change the variables in the trigger to match the table that  *
*         will be firing the trigger                                                      *
*******************************************************************************************/
SET ANSI_NULLS ON;
GO
SET QUOTED_IDENTIFIER ON;
GO
CREATE TABLE [dbo].[AuditDataChanges]
(
[RecordId] [INT] IDENTITY(1, 1)
NOT NULL ,
[TableName] [VARCHAR](50) NOT NULL ,
[RecordPK] [VARCHAR](50) NOT NULL ,
[ColumnName] [VARCHAR](50) NOT NULL ,
[OldValue] [VARCHAR](50) NULL ,
[NewValue] [VARCHAR](50) NULL ,
[ChangeDate] [DATETIME2](7) NOT NULL ,
[UpdatedBy] [VARCHAR](50) NOT NULL ,
CONSTRAINT [PK_AuditDataChanges] PRIMARY KEY CLUSTERED
( [RecordId] ASC )
WITH ( PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF,
IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON,
ALLOW_PAGE_LOCKS = ON ) ON [PRIMARY]
)
ON  [PRIMARY];
GO
ALTER TABLE [dbo].[AuditDataChanges] ADD  CONSTRAINT [DF_AuditDataChanges_ChangeDate]  DEFAULT (GETDATE()) FOR [ChangeDate];
GO
/************************************************************************************************
* Add the below trigger to any table you want to audit data changes on. Changes will be saved  *
* in the AuditChangesTable.                                                                    *
************************************************************************************************/
ALTER TRIGGER trg_Survey_Identify_Updated_Columns ON Survey --Change to match your table name
FOR INSERT, UPDATE
AS
SET NOCOUNT ON;
DECLARE @sql VARCHAR(5000) ,
@sqlInserted NVARCHAR(500) ,
@sqlDeleted NVARCHAR(500) ,
@NewValue NVARCHAR(100) ,
@OldValue NVARCHAR(100) ,
@UpdatedBy VARCHAR(50) ,
@ParmDefinitionD NVARCHAR(500) ,
@ParmDefinitionI NVARCHAR(500) ,
@TABLE_NAME VARCHAR(100) ,
@COLUMN_NAME VARCHAR(100) ,
@modifiedColumnsList NVARCHAR(4000) ,
@ColumnListItem NVARCHAR(500) ,
@Pos INT ,
@RecordPk VARCHAR(50) ,
@RecordPkName VARCHAR(50);
SELECT  *
INTO    #deleted
FROM    deleted;
SELECT  *
INTO    #Inserted
FROM    inserted;
SET @TABLE_NAME = 'Survey'; ---Change to your table name
SELECT  @UpdatedBy = UpdatedBy --Change to your column name for the user update field
FROM    inserted;
SELECT  @RecordPk = SurveyId --Change to the table primary key field
FROM    inserted;   
SET @RecordPkName = 'SurveyId';
SET @modifiedColumnsList = STUFF(( SELECT   ',' + name
FROM     sys.columns
WHERE    object_id = OBJECT_ID(@TABLE_NAME)
AND SUBSTRING(COLUMNS_UPDATED(),
( ( column_id
- 1 ) / 8 + 1 ),
1) & ( POWER(2,
( ( column_id
- 1 ) % 8 + 1 )
- 1) ) = POWER(2,
( column_id - 1 )
% 8)
FOR
XML PATH('')
), 1, 1, '');
WHILE LEN(@modifiedColumnsList) > 0
BEGIN
SET @Pos = CHARINDEX(',', @modifiedColumnsList);
IF @Pos = 0
BEGIN
SET @ColumnListItem = @modifiedColumnsList;
END;
ELSE
BEGIN
SET @ColumnListItem = SUBSTRING(@modifiedColumnsList, 1,
@Pos - 1);
END;    
SET @COLUMN_NAME = @ColumnListItem;
SET @ParmDefinitionD = N'@OldValueOut NVARCHAR(100) OUTPUT';
SET @ParmDefinitionI = N'@NewValueOut NVARCHAR(100) OUTPUT';
SET @sqlDeleted = N'SELECT @OldValueOut=' + @COLUMN_NAME
+ ' FROM #deleted where ' + @RecordPkName + '='
+ CONVERT(VARCHAR(50), @RecordPk);
SET @sqlInserted = N'SELECT @NewValueOut=' + @COLUMN_NAME
+ ' FROM #Inserted where ' + @RecordPkName + '='
+ CONVERT(VARCHAR(50), @RecordPk);
EXECUTE sp_executesql @sqlDeleted, @ParmDefinitionD,
@OldValueOut = @OldValue OUTPUT;
EXECUTE sp_executesql @sqlInserted, @ParmDefinitionI,
@NewValueOut = @NewValue OUTPUT;
IF ( LTRIM(RTRIM(@NewValue)) != LTRIM(RTRIM(@OldValue)) )
BEGIN   
SET @sql = 'INSERT INTO [dbo].[AuditDataChanges]
([TableName]
,[RecordPK]
,[ColumnName]
,[OldValue]
,[NewValue]
,[UpdatedBy])
VALUES
(' + QUOTENAME(@TABLE_NAME, '''') + '
,' + QUOTENAME(@RecordPk, '''') + '
,' + QUOTENAME(@COLUMN_NAME, '''') + '
,' + QUOTENAME(@OldValue, '''') + '
,' + QUOTENAME(@NewValue, '''') + '
,' + QUOTENAME(@UpdatedBy, '''') + ')';
EXEC (@sql);
END;     
SET @COLUMN_NAME = '';
SET @NewValue = '';
SET @OldValue = '';
IF @Pos = 0
BEGIN
SET @modifiedColumnsList = '';
END;
ELSE
BEGIN
-- start substring at the character after the first comma
SET @modifiedColumnsList = SUBSTRING(@modifiedColumnsList,
@Pos + 1,
LEN(@modifiedColumnsList)
- @Pos);
END;
END;
DROP TABLE #Inserted;
DROP TABLE #deleted;
GO

OriginalL'auteur Rick