Supprimer ajouter Dynamiquement des Contrôles à partir d'un Userform

J'ai un Userform excel avec ajoutées dynamiquement des cases à cocher. J'ai ajouter les cases dès le début avec un code qui ressemble à ceci:

Set chkBox = Me.Controls.Add("Forms.Checkbox.1", "Checkbox" & i)

Plus tard, je veux enlever tous ces cases à cocher. J'essaie ce code:

    Dim j As Integer
'Remove all dynamically updated checkboxes
For Each cont In Me.Controls
    For j = 1 To NumControls
    If cont.Name = "Checkbox" & j Then
        Me.Controls.Remove ("Checkbox" & j)
    End If
    Next j
Next cont

Mais je reçois le message d'erreur suivant: Supprimer ajouter Dynamiquement des Contrôles à partir d'un Userform

toute aide serait grandement appréciée.

l'un des problèmes ici sont peut-être les paranthesese " ("Checkbox" & j)"
vérifier à qui j il échoue et vérifier si c'est une case à cocher ajouté au moment de l'exécution et PAS en mode conception
En regardant en arrière, ce qui est probablement corrigé mon code n'était pas le vérifier, mais à la sortie, pour une fois, il a trouvé la bonne. @PatrickLepelletier est probablement vrai, c'est probablement la vérification de la mauvaise case. Cela étant dit, Chris du code ci-dessous devrait corriger ce problème.
je suis revenu à ce poste, seul à me demander pourquoi je ne l'avais pas vu: je fais ce genre de choses avec un On error resume next

OriginalL'auteur ale10ander | 2015-01-06

Une meilleure approche serait de garder la trace des commandes que vous créez (par exemple dans une collection), et de l'utiliser pour les supprimer.

De cette façon, votre code n'est pas lié au format de nom, et peut être appliquée à d'autres types de contrôle.

Private cbxs As Collection

Private Sub UserForm_Initialize()
    Set cbxs = New Collection
End Sub

' Remove all dynamicly added Controls
Private Sub btnRemove_Click()
    Dim i As Long
    Do While cbxs.Count > 0
        Me.Controls.Remove cbxs.Item(1).Name
        cbxs.Remove 1
    Loop
End Sub


' Add some Controls, example for testing purposes
Private Sub btnAdd_Click()
    Dim i As Long
    Dim chkBox As Control
    For i = 1 To 10
        Set chkBox = Me.Controls.Add("Forms.CheckBox.1", "SomeRandomName" & i)
        chkBox.Top = 40 + i * 20
        chkBox.Left = 20
        cbxs.Add chkBox, chkBox.Name  ' <-- populate tracking collection
    Next

    ' Demo that it works for other control types
    For i = 1 To 10
        Set chkBox = Me.Controls.Add("Forms.ListBox.1", "SomeOtherRandomName" & i)
        chkBox.Top = 40 + i * 20
        chkBox.Left = 60
        chkBox.Add chkBox, chkBox.Name
    Next

End Sub

Peut ainsi modifier la variable chkbox nom. +1 pour les frais d'utilisation de la collecte.
Thx @L42. Oui, je voudrais utiliser je généralisée nom. Juste gardé pour le rendre plus clair pour l'OP, comment cela se rapporte à son code d'origine
J'apprécie la suggestion! Dans cette application particulière, j'ai voulu supprimer les cases qui ont été créés au moment de l'exécution (et donc à ce schéma de nommage), tout en laissant tous les autres le seul contrôle. Mais vous avez raison, c'est plus propre, et plus générique de code. +1
je ne suis pas sûr, mais ne serait pas une collection de commencer à 0 ?
en fait non, les Articles de la collection commence à 1. (Dictionnaires de l'autre main commence à 0). VBA peut être tout à fait incompatible avec l'index de départ

OriginalL'auteur chris neilsen

En supposant qu'aucun autre contrôle des noms commençant par "Case",

For Each cont In Me.Controls
    If InStr(cont.Name, "Checkbox") = 1 Then
        Me.Controls.Remove cont.Name
    End If
Next cont

Belle approche, très simple mais effective.

OriginalL'auteur Gene Skuratovsky

si vous connaissez déjà le nom des champs, le type, et combien, pourquoi la double boucle ?

noter que SEULS les contrôles créés lors de l'exécution peut être retiré.

'the following removes all controls created at runtime
Dim i As Long
On Error Resume Next
With Me.Controls
    For i = .Count - 1 to 0 step -1
        .Remove i
    Next i
End With
Err.Clear: On Error GoTo 0

et pour votre cas : "si tout de nommage sont corrects

Dim j&
For j = 1 To NumControls
    Me.Controls.Remove "Checkbox" & j
Next j

OriginalL'auteur Patrick Lepelletier

1

Ajout d'une vérification pour le contrôle semble résoudre ce problème. Pas tout à fait sûr pourquoi, mais ça fonctionne.
```
   Dim j As Integer
'Remove all dynamically updated checkboxes
For Each cont In Me.Controls
    If TypeName(cont) = "CheckBox" Then
        For j = 1 To NumControls
            If cont.Name = "Checkbox" & j Then
                Me.Controls.Remove cont.Name
                Exit For
            End If
        Next j
    End If
Next cont
```
C'est quoi cette boucle à l'intérieur de la boucle en train de faire là?
La boucle intérieure est en train de vérifier le numéro de chaque contrôle. Dans la boucle externe, j'ai appris à contrôler Un, mais je ne sais pas avec toute certitude que c'est le contrôle de 1. J'ai donc vérifier chaque numéro jusqu'à ce que je trouve le bon numéro.
Ce n'était pas la vérification de contrôle fixe, mais plutôt à la sortie, quand j'ai trouver ce que je cherche, j'ai arrêter de regarder. Il se trouve que mes cases à cocher ont été vérifiées avant toute autre chose. L'on a accepté la réponse est plus stable; il ne repose pas sur la chance 🙂

OriginalL'auteur ale10ander

J'ai réécrit le code d'origine à l'aide de boutons de commande, et ont juste ajouté "Moi.Les contrôles.Le comte" plutôt que "NumControls" et défini "Cont" comme un Contrôle. Il semble fonctionner pour moi. S'il vous plaît laissez-moi savoir si cela fonctionne pour vous:

-->

On Error Resume Next
Dim Cont As Control
Dim C As Integer
'Remove all dynamically updated checkboxes
For Each Cont In Me.Controls
    For C = 1 To Me.Controls.Count
    If Cont.Name = "CommandButton" & C Then
        Me.Controls.Remove ("CommandButton" & C)
    End If
    Next C
Next Cont

OriginalL'auteur MrPantsMan

Vous devez vous connecter pour publier un commentaire.