Supprimer les doublons d'éléments de la liste en Tcl

Comment faire pour supprimer dupliquer l'élément de liste Tcl dire:

list is like [this,that,when,what,when,how]

J'ai Googlé et trouvé lsort unique mais même ne fonctionne pas pour moi. Je veux retirer de la liste.

Qu'appelez-vous une "liste"?
vous avez posé beaucoup de Tcl questions où vous ne montrez pas que vous comprenez Tcl syntaxe. Le Tcl tutoriel va vous aider un peu: tcl.tk/man/tcl8.5/tutorial/tcltutorial.html

OriginalL'auteur user2901871 | 2013-12-04

  1. 12

    Les ouvrages suivants, pour moi

    set myList [list this that when what when how]
lsort -unique $myList

    cela renvoie

    how that this what when

    lequel vous pouvez stocker dans une nouvelle liste

    set uniqueList [lsort -unique $myList]
    Celui-ci va changer l'ordre de la liste d'origine

    OriginalL'auteur m4eme

  2. 6

    Vous pouvez également utiliser un dictionnaire, où les touches doit être unique:

    set l {this that when what when how}
foreach element $l {dict set tmp $element 1}
set unique [dict keys $tmp]
puts $unique
    this that when what how

    À préserver l'ordre des éléments.

    +1 pour la conservation de l'ordre
    Ce travail sur Tcl 8.6+. dict commande n'existe pas sur Tcl 8.4

    OriginalL'auteur glenn jackman

  3. 1

    glenn jackman réponse fonctionnent parfaitement sur Tcl 8.6 et au-dessus.

    Pour Tcl 8.4 et ci-dessous (Pas dict de commande). Vous pouvez utiliser:

    proc list_unique {list} {
    array set included_arr [list]
    set unique_list [list]
    foreach item $list {
        if { ![info exists included_arr($item)] } {
            set included_arr($item) ""
            lappend unique_list $item
        }
    }
    unset included_arr
    return $unique_list
}

set list   [list this that when what when how]
set unique [list_unique $list]

    Cela permettra également de préserver l'ordre des éléments
    et voici le résultat:

    ce qui quand quoi comment

    OriginalL'auteur Hazem

  4. 0

    Une autre façon, si ne veulent pas utiliser natif lsort fonction.C'est ce que l'intervieweur vous demande 🙂

    `set a "this that when what when how"
for {set i 0} {$i < [llength $a]} {incr i} {
    set indices [lsearch -all $a [lindex $a $i]]
    foreach index $indices {
        if {$index != $i} {
            set a [lreplace $a $index $index]
        }
    }
}

    `

    OriginalL'auteur Dcode