Sur la feuille de calcul Google comment pouvez-vous vous interroger "GoogleFinance" pour un passé, des taux de change?

Je voudrais savoir si il est possible d'interroger un passé, des taux de change sur Google feuille de calcul.

Par exemple, en utilisant la formule =GoogleFinance("CURRENCY:USDEUR") sera de retour l'USD/EUR taux à ce moment présent. Comment pouvez-vous obtenir un taux historique?

InformationsquelleAutor antr | 2013-12-16

81

Dans le but de récupérer l'historique des taux, vous devez utiliser la formule suivante:
```
=GoogleFinance("eurusd","price",today()-1,today())
```
Où aujourd'hui()-1, aujourd'hui (le) est l'intervalle désiré, qui peut être définie explicitement comme statique paire de dates, ou implicitement, comme l'dynamiquement les valeurs calculées, comme dans l'exemple ci-dessus. Cette expression renvoie à deux tableau de la colonne des dates et des valeurs proches. Il est important de prendre soin de la approprié de format de cellule (date/numéro), sinon, vos données seront brisés.

Si vous voulez obtenir le pure ligne avec la date et les taux de change, sans en-têtes de colonne, enveloppez votre formule avec les INDEX() fonction:
```
=INDEX(GoogleFinance("eurusd","price",today()-1,today()),2,)
```
Pour récupérer le taux de change de valeur, définir le numéro de la colonne paramètre:
```
=INDEX(GoogleFinance("eurusd","price",today()-1,today()),2,2)
```
D'obtenir aujourd'hui des taux de change dans Google Docs/feuille de calcul de Google Finance:
```
=GoogleFinance("eurusd","price",today())
```
P. S. il y a Quelques temps il y avait un problème avec le court chemin pour obtenir les taux du jour, mais maintenant ça fonctionne, et vous pouvez les utiliser à nouveau:
```
=GoogleFinance("currency:usdeur")
```
P. S. Comment obtenir live les taux de change, dans Microsoft Excel:
- https://superuser.com/a/687927/128312
- Vous pouvez aussi avoir une colonne de la DATE et de l'utiliser à la place d'aujourd'hui()-1,aujourd'hui() pour avoir des données historiques pour la journée.
InformationsquelleAutor Mike B.
15

Essayer,
```
=GoogleFinance("usdeur","price",date(2013,12,1),date(2013,12,16))
```
Assurez-vous que les dates sont à votre feuille de calcul des paramètres.

Modifier en tant que commentaire, date de modification pour la capture d'une seule journée de données:-

Seulement avec les en-têtes:
```
=INDEX(GoogleFinance("usdeur","price",date(2013,12,3),date(2013,12,4)),,2)
```
sans en-têtes:
```
=FILTER(INDEX(GoogleFinance("usdeur","price",date(2013,12,3),date(2013,12,4)),,2),INDEX(GoogleFinance("usdeur","price",date(2013,12,3),date(2013,12,4)),,2)<>"Close")
```
- Grâce Vasim, cette dernière formule est parfaite. Il fonctionne tout simplement. Meilleur
- ne fonctionne pas sur Google feuilles de calcul
InformationsquelleAutor Vasim
10

Les instructions pour tous liés à googlefinance sont ici: https://support.google.com/docs/answer/3093281

Souvenir de Google feuilles de calcul Formules utilisez le point-virgule (;) à la place de la virgule (,).
Une fois fait le remplacement sur quelques exemples ressemblerait à ceci:

Pour 30 jours de l'INDEX de USD vs EUR, vous devez utiliser (à noter que dans le cas de monnaies, elles vont ensemble dans la même première variable):
```
=INDEX(GoogleFinance(USDEUR;"price";today()-30;today());2;2)
```
ASTUCE: Vous pouvez obtenir le graphique sur l'ensemble de la taille de la cellule, en changeant simplement l'INDEX pour SPARKLINE, comme ceci:
```
=SPARKLINE(GoogleFinance(USDEUR;"price";today()-30;today());2;2)
```
InformationsquelleAutor DavidTaubmann
3

Vasim la réponse est excellente, toutefois, de l'avis si vous voulez la date de l'échange ce jour-là seulement, vous pouvez omettre la plage et il suffit de spécifier le jour telles que les suivantes

=FILTER(INDEX(GoogleFinance("usdeur","price",today()),,2),INDEX(GoogleFinance("usdeur","price",today()),,2)<>"Close")

InformationsquelleAutor user56236
1

Vous remarquerez peut-être que GOOGLEFINANCE sera de retour de N/A pour quelques dates, c'est parce que la date est un jour de congé (généralement un week-end), ce que vous pouvez faire est d'obtenir le dernier de travailler à partir de la date spécifiée, par exemple, Jun 21 2015 est le dimanche, de sorte que vous devez demander le tarif pour Jun 19 (vendredi), vous pouvez le faire via WORKDAY fonction comme il a été suggéré ici:
```
WORKDAY("6/21/2015"+1,-1)
```
Par conséquent, la formule va ressembler à quelque chose comme ça:
```
INDEX(GoogleFinance("CURRENCY:USDRUB", "price", WORKDAY("6/21/2015"+1,-1),1),2,2)
```
En outre, vous voulez obtenir le taux de change pour des dates futures vous pouvez aussi vérifier si la date est dans le futur et, dans l'affirmative, il suffit d'utiliser la date d'aujourd'hui:
```
WORKDAY(IF("6/21/2099">TODAY(),TODAY(),"6/21/2099")+1,-1)
```
InformationsquelleAutor chingis
0

Pour les plus grosses feuilles de calcul, des Feuilles de calcul Google limitations généralement montrera au hasard d'erreur suivant:

Erreur Fonction de l'INDICE de paramètre 2 est de 2. Les valeurs valides sont entre
0 et 1 inclus.

Même la modification de l'Index() et GoogleFinance() suivant les paramètres attendus GOOGLEFINANCE(ticker, [attribut], [date_debut], [end_date|jours], [intervalle]) l'erreur continuera.
Une solution consiste à copier les petites pièces dans de nouvelles feuilles de calcul, mais souvent, il échouera.

Comme une alternative, j'ai utilisé ImportXML web grattoir pour x-historique des taux de change les données.
```
=index(IMPORTXML("https://www.x-rates.com/historical/?from="&N2&"&amount="&K2&"&date="&YEAR(B2)&"-"&TEXT(B2,"mm")&"-"&TEXT(B2,"dd")&"","//td[@class='rtRates']"),1)
```
Je suis en supposant que la colonne B sont des dates, K est pour les montants et N pour les devises.

Au hasard, il sera également échouer pour+ de 2000 lignes de la feuille de calcul mais dans l'ensemble à mon exigence, il a travaillé trop beaucoup mieux que GoogleFinance()

ImportXML exemples

Le ImportXML Guide pour Google Docs, de débutant à avancé
- Cette erreur est parce que votre date est dans le JJ/MM/AAAA au lieu de AAAA/MM/JJ. Changer le format de la date ou de modifier la formule de DATE en conséquence
InformationsquelleAutor Damodar Das

Vous devez vous connecter pour publier un commentaire.