tcl lsearch sur la liste de la liste

Utilisation -index, il est conçu exactement pour ce cas. Comme ramanman, lorsque vous avez une liste, utilisez la liste des procédures. Avez-vous pensé à ce qui se passe si vous avez plusieurs matches?

Dans votre cas, je viens de le faire:

% lsearch -index 0 -all -inline $somelist bbb
{bbb 2}
% lsearch -index 0 -all $somelist "bbb"
1
% lsearch -index 0 -all $somelist "ccc"
2

Vous utilisez -index de 0 pour indiquer que vous êtes intéressé dans le premier index de la liste externe. -tous retourne tous les résultats. Et vous pouvez utiliser -inline si vous voulez juste la valeur de l'élément de la liste qui correspond à, de les omettre si vous voulez juste l'index de l'élément correspondant.

En Tcl 8.5, mais pas dans les Tcl 8.4:

set somelist {{aaa 1} {bbb 2} {ccc 1}}
lsearch -index 0 $somelist bbb; # Returns either the index if found, or -1 if not

L'index des drapeaux spécifie l'index de la sous-liste de la recherche: 0 les recherches pour aaa, bbb, ... Tout en 1 recherche 1, 2, 1...

En Tcl 8.4, utilisez le keylget commande à partir de la Tclx package:

package require Tclx

set somelist {{aaa 1} {bbb 2} {ccc 1}}
set searchTerm "bbb"
if {[keylget somelist $searchTerm myvar]} {
    puts "Found instance of $searchTerm, value is: $myvar"
}

La keylget commande dans cette syntaxe renvoie 1 si trouvé, 0 si non. La valeur du côté de bbb (2) est placé dans la variable mavar. Notez qu'il devrait y avoir aucun signe de dollar ($) devant somelist dans le keylget commande.

Mise à jour

En fait, l'indice du pavillon permet la recherche de profondeur arbitraire, comme illustré par le présent code:

package require Tcl 8.5 

# For each sub-list:
# - index 0 = the user's name
# - index 1 = a list of {home value}
# - index 2 = a list of {id value}
# - index 3 = a list of {shell value}
set users {
    {john {home /users/john} {id 501} {shell bash}}
    {alex {home /users/alex} {id 502} {shell csh}}
    {neil {home /users/neil} {id 503} {shell zsh}}
}   

# Search for user name == neil
set term neil
puts "Search for name=$term returns: [lsearch -index 0 $users $term]"; # 2

# Search for user with id = 502. That means we first looks at index
# 2 for {id value}, then index 1 for the value
set term 502
puts "Search for id=$term returns: [lsearch -index {2 1} $users $term]"; # 1

# Search for shell == sh (should return -1, not found)
set term sh
puts "Search for shell=$term returns: [lsearch -index {3 1} $users $term]"; # -1

Si vous voulez la recherche de la façon qui vous tentent, vous pouvez utiliser le glob option:

lsearch -glob $somelist "{bbb *}"

Si vous ceux sont vraiment des listes de listes, et vous êtes à la recherche pour répondre à la première sous-liste avec un premier élément de bbb vous pouvez aussi faire:

foreach sublist $somelist {   
  foreach {name value} $sublist {
    if {[string eq $name "bbb"]} {
      #do interesting stuff here
    }
  }
}

Les détails de cette dépendra bien sûr les détails de votre liste de listes (si vous n'avez que deux éléments de votre liste imbriquée, ou si elle pourrait être plus profondément imbriqués.