Tirant les Noms de Colonne dans Excel à partir d'une requête SQL

Je suis à l'aide d'Excel d'extraire les données à partir de SQL db. J'ai utilisé le code d'un autre DONC, la question et il fonctionne très bien. Maintenant, j'ai envie de tirer dans les noms de colonnes d'une table en plus de la table. J'ai pensé que je pourrais obtenir les noms à l'aide De la fld boucle. Toutefois, il y a encore la question du peuplement horizontalement sur une ligne dans Excel que le nombre de colonnes peut changer, alors je me dis, j'aurais besoin d'un autre Pour chaque boucle aussi, ou quelque chose de similaire.

Sub GetDataFromADO()

'Declare variables'
    Set objMyConn = New ADODB.Connection
    Set objMyCmd = New ADODB.Command
    Set objMyRecordset = New ADODB.Recordset

'Open Connection'
    objMyConn.ConnectionString = "Provider=SQLOLEDB;Data Source=localhost;User ID=abc;Password=abc;"
    objMyConn.Open

'Set and Excecute SQL Command'
    Set objMyCmd.ActiveConnection = objMyConn
    objMyCmd.CommandText = "select * from myTable"
    objMyCmd.CommandType = adCmdText
    objMyCmd.Execute

'Loop Names'
    ' WHAT TO DO HERE????'

'Open Recordset'
    Set objMyRecordset.ActiveConnection = objMyConn
    objMyRecordset.Open objMyCmd

'Copy Data to Excel'
    ActiveSheet.Range("A1").CopyFromRecordset (objMyRecordset)

End Sub

Ne voulez-vous pas les en-têtes alignées avec les données? Les données commence en A1, mais vous avez l'air d'avoir la tête gamme au format A4.
ouais vous avez raison, mauvais copier et coller de ma part.

OriginalL'auteur firedrawndagger | 2010-11-16

20

Mon habitude de code est très similaire:
```
For intColIndex = 0 To objMyRecordset.Fields.Count - 1 
    Range("A4").Offset(0, intColIndex).Value = objMyRecordset.Fields(intColIndex).Name
Next
```
J'aime bien le "souffle" de votre solution. J'ai juste agrandi un peu pour définir les en-têtes de Gras.
Je suis déçu par l'absence d'une solution qui ne recourt pas à une boucle.

OriginalL'auteur dendarii

Ok, donc j'ai pensé à elle après 4 tentatives, voici le code de la boucle.

 'Loop'
 Dim FieldRange As Range
 Set FieldRange = Range("A4")
 Set TableColumns = Range("A4:H4")
 x = 1

 Range("A4").Select

 For Each fld in objMyRecordset.Fields
      ActiveCell.Value = fld.Name
      ActiveCell.Offset(0, x).Select
      x = x + 1 'tick iterator
 Next

 ActiveSheet.Range("A5").CopyFromRecordset objMyRecordset
 Range("A4").Select

Vous n'avez pas besoin de sélectionner la Cellule d'utiliser quelque chose comme Range("A4").OffSet(0, x).value = fld.Name

OriginalL'auteur firedrawndagger

6

Pour super simple, faire quelque chose comme ceci (à l'aide de la feuille Sheet1 et jeu d'enregistrements r)
```
    For i = 0 To r.Fields.Count - 1
        Sheet1.Cells(1, i + 1) = r.Fields(i).Name
    Next i
```
OriginalL'auteur protoculture
3

Il vous suffit de définir votre "x" à la variable à 0 et puis faire quelque chose comme:
```
x = 0

For Each Field In RS.Fields 'RS being my Recordset variable
    Range("A3").Offset(0, x).Value = Field.Name
    x = x + 1
Next Field
```
Et qui va le rendre un peu plus facile à lire... 🙂

OriginalL'auteur Tony Diaz

Vous devez vous connecter pour publier un commentaire.