Trouver la dernière occurrence de la valeur spécifique dans une rangée

J'ai une table qui garde les scores de fantasy football league. Le plus bas score de la semaine n'est pas inclus dans le total.

Je suis en mesure de trouver le score le plus bas à l'aide de la =min function [=min(B2:R2)]

Je peux trouver de la première instance à l'aide de la =match function. [=MATCH(S2,B2:R2,0)]

Cependant, je voudrais une formule qui retourne la dernière occurrence du plus bas score de la semaine.

Par exemple Portia score le plus bas est de 8 la première occurrence est la semaine de 4, mais je voudrais qu'il revienne plus tard survenue la semaine 11

Trouver la dernière occurrence de la valeur spécifique dans une rangée

  • Définir dernière apparition?
  • Dernières diffusions / dernier événement le plus récent. Si il y a plus d'une occurrence le score le plus bas, je voudrais la formule pour renvoyer le plus récent. Pour Portia est serait la semaine 11, Phoebe semaine 4, Anastasia la semaine 11.
  • =INDEX(1:1,1,MAX(COLUMN(B2:R2)*(B2:R2=MIN(B2:R2)))) entrée comme une formule de matrice (à l'aide de Ctrl-Maj-Entrée)
  • Pas sûr de la façon dont vous entrez les valeurs. Êtes-vous d'insérer les valeurs manuellement? Si vous êtes l'insertion par le biais de certains champs de texte, vous pouvez ajouter un horodatage lorsque vous effectuez les changements. Puis il suffit de retourner sur le terrain avec la dernière heure.
InformationsquelleAutor user2245450 | 2014-12-09
  1. 16

    Vous pouvez également le faire à l'aide de LOOKUP fonction et en évitant les formules de tableau, par exemple, en supposant que S2 a la valeur minimale que vous pouvez obtenir la dernière semaine avec cette valeur avec cette formule dans T2 copié vers le bas

    =LOOKUP(2,1/(B2:R2=S2),B$1:R$1)

    Cela fonctionne parce que (B2:R2=S2) retourne un tableau de TRUE/FALSE valeurs, puis en divisant 1 par ce tableau vous donne un tableau de 1s ou #DIV/0! erreurs. Lorsque vous utilisez 2 comme le valeur de recherche sur ce tableau on ne trouverez pas de 2s donc, va donc correspondre avec le dernier nombre (la dernière 1) dans le tableau. Qui correspond à la dernière semaine avec votre plus petite valeur à l'aide de la ligne du haut, comme le retour "vecteur" signifie que la formule renvoie la semaine correspondante nombre de

    • Presque 4 ans plus tard et c'est exactement ce que je cherchais, en plus j'ai appris le 1/(<plage>=<valeur>) technique comme un bonus. 🙂 Merci beaucoup!
    InformationsquelleAutor barry houdini
  2. 2

    Vous aurez besoin d'utiliser une Formule matricielle pour atteindre cet objectif. Le suivant sera le retour de la "plus haute" valeur la plus faible si vous utilisez les colonnes B:R que les données des colonnes et des colonnes T comme le Faible Semaine colonne. Il vous faut la saisir comme un tableau (CST) de la formule de copier /coller dans la cellule T2 et en appuyant sur Ctrl+Maj+Entrée.

    =IFERROR(INDEX($A$1:$R$1,1,SMALL(IF(B2:R2=MIN(B2:R2),COLUMN(B2:R2),FALSE),COUNTIF(B2:R2,MIN(B2:R2)))),"")

    Explication

    Tout d'abord, le COUNTIF(B2:R2,MIN(B2:R2)) va compter le nombre de fois que la valeur minimale se produit. Ceci est nécessaire car une simpleMIN(B2:R2) ne prenez le première valeur minimale, pas la nième valeur minimale.

    Prochain, le IF(B2:R2=MIN(B2:R2),COLUMN(B2:R2),FALSE) est le tableau réel de la formule une partie de l'équation (la raison pour laquelle vous devez utiliser Ctrl+Maj+Entrée). Il retournera seulement les références pour quand vous avez un minimum et le retour FALSE pour toutes les autres entrées de plus que le minimum. Maintenant, vous avez un tableau de seulement les numéros de colonne la plus petite des valeurs dans le jeu de données.

    Ensuite, le SMALL(IF(B2:R2=MIN(B2:R2),COLUMN(B2:R2),FALSE),COUNTIF(B2:R2,MIN(B2:R2))) prendra les numéros de colonne de la plus petite des valeurs et de trouver la dernière occurrence de ce qui vient de la COUNTIF(B2:R2,MIN(B2:R2)) code.

    Maintenant que le dernier plus petit occurrences' nombre de colonnes est savoir, vous pouvez utiliser le INDEX fonction pour trouver la valeur dans la première ligne INDEX($A$1:$R$1,1.

    Enfin, la IFERROR affichera le Faible Semaine ligne si la SMALL fonction trouve une correspondance, sinon il affichera une cellule vide. Cela pourrait être utilisé pour copier cette formule de tableau en bas de la page pour les lignes que vous n'avez pas encore d'utilisateurs.

    Résultat

    Trouver la dernière occurrence de la valeur spécifique dans une rangée

    • Fantastique, merci Michael. Votre solution fonctionne et vous m'avez donné beaucoup de choses à lire sur. J'apprécie que vous preniez le temps de répondre à ma question.
    InformationsquelleAutor Michael