Trouver une valeur de retour de la cellule du dessous (ou jusqu'à 4 ci-dessous) dans lequel la première valeur commence par un 1

J'ai un fichier word importé dans Excel. Le fichier est dans la colonne A, jusqu'à 400-500 lignes de long. Pour illustrer un exemple:

Type application
0 shortcut
1 Client installation (standalone)
0 Client installation with data on the network (fileshare needed)
0 Client/server (server needed)
0 Webbased without dependancies
0 Webbased with dependancies
Importancy
0 Company critical
1 Important
0 Supportive

Et de nombreux autres domaines d'intérêt. Maintenant, j'ai une formule qui recherches pour une certaine valeur de texte, par exemple "chef de Produit" et retourne la valeur en dessous (le nom). Pour illustrer:

=INDEX(A:A;MATCH("Product manager";A:A;0)+2;1)

Ici, l' +2 renvoie le nom de la chef de produit.

Le problème que j'ai besoin de VOTRE aide!

Le problème est comme suit. Dans le gros bloc de code ci-dessus, vous voyez un peu de valeur, avec le 1 correspondant à la case cliquée dans le fichier word. Maintenant, je veux faire une recherche sur Type d'application et retour seulement la valeur correspondant à la 1, donc dans ce cas 1 installation du Client (autonome).

La solution ci-dessus avec l'INDEX et le MATCH ne fonctionne pas parce qu'il ne renvoie à une certaine ligne ci-dessous la requête de recherche (sorte de ligne +1, ou de la ligne +5). Je veux trouver la valeur Type d'application, moteurs de recherche, dans les 6 lignes ci-dessous et le retourner à la valeur seulement 1 il va trouver.

InformationsquelleAutor JuliusSecret | 2015-07-24

1

Suivant l'exemple de mes illustres collègues, j'ai commencé à essayer d'utiliser les INDEX pour ce genre de question, donc, la réponse serait quelque chose comme ceci:-
```
=INDEX(INDEX(B$1:B$10,MATCH(D2,B$1:B$10,0)):B$10,MATCH(1,INDEX(A$1:A$10,MATCH(D2,B$1:B$10,0)):A$10,0))
```
afin qu'il trouve la chaîne de caractères (par exemple, charlie) dans la colonne B, et les recherches le reste de la gamme dans la colonne A, pour un '1'.

Si toutes les valeurs d'une colonne comme dans la question, la formule devient
```
=INDEX(INDEX(A$1:A$10,MATCH(D2,A$1:A$10,0)):A$10,
MATCH("1*",INDEX(A$1:A$10,MATCH(D2,A$1:A$10,0)):A$10,0))
```
De mettre une limite sur la plage et la gestion d'erreur doit être quelque chose comme ceci:-
```
=IFERROR(
INDEX(INDEX(A:A,MATCH(D2,A:A,0)):
INDEX(A:A,MATCH(D2,A:A,0)+4),
MATCH("1*",INDEX(A:A,MATCH(D2,A:A,0)):
INDEX(A:A,MATCH(D2,A:A,0)+4),0)),
"No entry")
```
Si vous vouliez faire une recherche plus d'une colonne de la même manière, vous pouvez utiliser le même genre de formule, mais il ne serait pas pratique sans l'aide d'un helper colonnes. Donc le copier à travers, disons, deux colonnes, puis d'afficher le premier match.

Configurer le début de la recherche en E2:-
```
=MATCH(D2,A$1:A$20,0)+1
```
Fin de la recherche en F2 pourrait juste être E2+4, mais vous pouvez également effectuer une recherche jusqu'à la prochaine sous-position' a l'aide:-
```
=MATCH(1,INDEX((INDEX(A$1:A$20,E2):A$20>"2")+(INDEX(A$1:A$20,E2):A$20=""),),0)+E2-2
```
La recherche d'une cellule à partir de "1" dans G2:-
```
=IFERROR(MATCH("1*",INDEX(A$1:A$20,$E2):INDEX(A$1:A$20,$F2),0),"")
```
et tirer à travers en H2 et I2.

Obtenir le premier des trois matchs J2:-
```
=MIN(G2:I2)
```
Et de trouver les colonnes qui il s'applique à en K2:-
```
=IF(J2=0,"",MATCH(J2,G2:I2,0))
```
Enfin obtenir le correspondant de la cellule à l'aide de la ligne et la colonne du J2 et K2:-
```
=IF(K2="","No entry",INDEX(INDEX(A$1:A$20,E2):C$20,J2,K2))
```
- Merci beaucoup pour vos commentaires et votre dur travail pour un étranger! J'aime vraiment ce site. Une dernière question et ensuite je suis dehors. Que faire si je veux mettre une plage de recherche, par exemple +4 lignes quand il a trouvé une certaine touche? Mon scénario contient la deuxième image. Certaines touches peuvent ne pas avoir de 1, dans ce cas, je veux le retour d'une certaine valeur (par exemple, "pas d'entrée"). Au moment où il cherche jusqu'à ce qu'il trouve une ligne qui renvoie un 1, alors que je veux seulement qu'elle recherche dans la prochaine 3 de 4 ou 5 lignes.
- Ont ajouté à ma réponse. Ce serait bien si elle pouvait la recherche jusqu'à la prochaine 'key', mais vous ne savez pas comment faire cela 🙂
- Merci beaucoup Tom Sharpe pour votre aide jusqu'à présent. J'ai une autre question je ne peux pas comprendre et j'espère vraiment que vous pouvez jeter un peu de lumière sur ce problème. La chose: je recherche dans une PLAGE de cellules et des colonnes. Par exemple, je fais une recherche sur le terme "Application". Une fois qu'il est trouvé, je recherche à PARTIR de cette cellule (par exemple, A30) jusqu'à 5 lignes et 2 colonnes de droite (donc, de l'A30 à C35) pour la PREMIÈRE valeur que renvoie un. Je veux que la première 1 à renvoyer avec le texte suivant (à l'aide de la 1 comme un caractère générique).... J'espère que vous pourrez m'aider!
- Ce serait vraiment difficile. Parce que le MATCH ne peut traiter que d'une seule colonne, vous auriez probablement besoin d'une approche différente en utilisant une formule de tableau ou de VBA. Va revenir à vous si je pense à quelque chose.
- En fait, il est OK pour le faire, mais aura besoin de quelques helper colonnes car trop de choses à faire avec une formule. Ajouter à ma réponse.
InformationsquelleAutor Tom Sharpe
0

Dire que nous avons données comme:

et nous voulons:
1. trouver Puck
2. de retour de la première valeur à partir de "1" ci-dessous Puck
À l'aide de Match() avec un caractère générique peut retrouver la ligne avec Puck. Ainsi, dans C5, nous entrée:
```
=MATCH("*Puck",A1:A9999,0)
```
ensuite, nous utilisons Match() encore pour trouver la ligne en-dessous que ça commence à "1". Ainsi, dans C6 nous entrons::
```
=INDEX(A1:A9999,MATCH("1*",INDIRECT("A" & C5 & ":A9999"),0)+C5-1)
```
Naturellement, ce 2 cellules approche peut toujours être combinées dans une seule cellule.
- Merci beaucoup de Gary pour vos commentaires, c'est très apprécié! - Je choisir la solution fournie par Tom Sharpe, mais j'ai encore non résolus de la solution. Il est publié sous sa solution, ne vous ont peut-être une idée sur comment faire?
InformationsquelleAutor Gary's Student

Vous devez vous connecter pour publier un commentaire.