Try-Catch-End Try en VBScript ne semble pas fonctionner

Je suis essayer le code suivant:

Try ' DOESN'T WORK
    Throw 2 ' How do I throw an exception?
Catch ex
    'What do I do here?
End Try

mais j'obtiens le message d'erreur Statement expected dans la clause catch.

Personne ne sait comment je peux attraper/lancer des exceptions dans VBScript utilisation de try/catch? (Je suis pas à la recherche de solutions avec On Error Do X.)

Alors vous allez être très déçu. Il n'y a pas de Try-Catch de soutien dans pre-.NET les versions de VB, y compris 6 VB, VBA, VBScript et. On Error Resume Next n'est pas si mauvaise si vous savez comment l'utiliser correctement.
Ouais, je suis déçu. 🙁 On Error Resume Next utilisé pour être mon préféré de commande de retour au collège, quand j'ai appris VB 6... il est rapidement devenu mon plus détesté de commande après que j'ai appris le C#. Je crois que je vais l'utiliser mais je ne veux vraiment pas.
Voir ci-dessous pour quelques conseils sur l'utilisation correctement! 🙂

InformationsquelleAutor Mehrdad | 2011-02-15

try-catch vbscript

19

VBScript n'a pas de Try/Catch. (Référence du langage VBScript. Si elle avait Essayer, il serait inscrit dans les États de section.)

On Error Resume Next est la seule erreur de manipulation dans VBScript. Désolé. Si vous voulez try/catch, JScript est une option. Il est pris en charge partout que VBScript est et a les mêmes capacités.
- Si elle n'a pas Try/Catch, alors comment se fait-il n'a pas d'erreur sur Essayer?
- Je suppose qu'il doit prendre en charge Trraoysfoaiuerlkj trop, parce que si vous modifiez l'Essayer pour que ça ne fait pas d'erreur non plus. 😉 Je suppose qu'il pense Essayer peut-être le nom de la Sous qui vient plus tard dans le script.
- C'est bon, VBScript qu'il considère comme un Sous, sans arguments, donc il ne fait pas d'erreur si vous n'utilisez pas l'Option Explicite ou si vous utilisez l'on Error Resume Next. C'est la raison pour laquelle vous devez utiliser l'Option Explicite régulièrement et on Error Resume Next sparcely. Car si vous faites une faute de frappe, vous pouvez facilement détecter par la mention de non déclarées déclaration ou n'est pas reconnu sous/fonction.
- Oh, je ne savais pas que l'Option Explicite travaille en VBScript... j'ai seulement utilisé dans visual basic 6, merci! (J'ai aussi pensé à Essayer est un mot-clé parce que Notepad++ en surbrillance Try et Catch... :\ )
- En fait je googlé Trraoysfoaiuerlkj. Merci De Génie.
- En vertu de WSH, VBScript du mécanisme de gestion d'événements est un peu plus simple que dans le Javascript. Voir ici.
InformationsquelleAutor Tmdean
67

Les Erreurs De Manipulation

D'une sorte de "vieux style" de la gestion des erreurs est disponible en VBScript, à ne faire usage de On Error Resume Next. Nous avons d'abord permettre que (souvent en haut d'un fichier, mais vous pouvez l'utiliser en place de la première Err.Clear ci-dessous pour leur effet combiné), puis avant l'exécution de nos éventuellement des erreurs de la génération de code, effacer les erreurs qui ont déjà eu lieu, exécutez la peut-être des erreurs de la génération de code, et puis explicitement vérifier les erreurs:
```
On Error Resume Next
' ...
' Other Code Here (that may have raised an Error)
' ...
Err.Clear      ' Clear any possible Error that previous code raised
Set myObj = CreateObject("SomeKindOfClassThatDoesNotExist")
If Err.Number <> 0 Then
    WScript.Echo "Error: " & Err.Number
    WScript.Echo "Error (Hex): " & Hex(Err.Number)
    WScript.Echo "Source: " &  Err.Source
    WScript.Echo "Description: " &  Err.Description
    Err.Clear             ' Clear the Error
End If
On Error Goto 0           ' Don't resume on Error
WScript.Echo "This text will always print."
```
Ci-dessus, nous sommes juste l'impression de l'erreur s'il se produit. Si l'erreur a été fatale pour le script, vous pouvez remplacer la deuxième Err.clear avec WScript.Quit(Err.Number).

Note également de la On Error Goto 0 qui s'éteint de reprendre l'exécution à l'instruction suivante lorsqu'une erreur se produit.

Si vous voulez tester le comportement pour quand le Set réussit, aller de l'avant et de commenter cette ligne, ou créer un objet qui va réussir, comme vbscript.regexp.

La On Error directive n'affecte le fonctionnement actuel de la portée (actuel Sub ou Function) et n'affecte pas les appelant ou de l'appelé étendues.

La Levée Des Erreurs

Si vous voulez vérifier une sorte d'etat et de lever une erreur à être traitées par le code qui appelle votre fonction, vous devez utiliser Err.Raise. Err.Raise prend jusqu'à cinq arguments, Number, Source, Description, HelpFile, et HelpContext. À l'aide de fichiers d'aide et des contextes est au-delà de la portée de ce texte. Number est un numéro d'erreur que vous choisissez, Source est le nom de votre application/classe/objet/propriété qui est la collecte de l'erreur, et Description est une courte description de l'erreur qui s'est produite.
```
If MyValue <> 42 Then
    Err.Raise(42, "HitchhikerMatrix", "There is no spoon!")
End If
```
Vous pouvez ensuite gérer l'erreur levée comme discuté ci-dessus.

_{Journal des modifications}
- _{Edit #1:
  
  Ajout d'une Err.Clear avant la possible erreur causant ligne pour effacer toutes les erreurs précédentes qui ont été ignorés.}
- _{Edit #2:
  
  Précisé.}
- _{Edit #3:
  
  Ajouter des commentaires dans le bloc de code. A précisé qu'il devait être plus de code entre On Error Resume Next et Err.Clear. Correction de quelques de la grammaire à l'être moins maladroit. Ajout d'infos sur Err.Raise. La mise en forme.}
InformationsquelleAutor Mark Ribau

Try Catch existe via la solution de contournement dans VBScript:

http://web.archive.org/web/20140221063207/http://my.opera.com/Lee_Harvey/blog/2007/04/21/try-catch-finally-in-vbscript-sure

Class CFunc1
    Private Sub Class_Initialize
        WScript.Echo "Starting"
        Dim i : i = 65535 ^ 65535 
        MsgBox "Should not see this"
    End Sub

    Private Sub CatchErr
        If Err.Number = 0 Then Exit Sub
        Select Case Err.Number
            Case 6 WScript.Echo "Overflow handled!" 
            Case Else WScript.Echo "Unhandled error " & Err.Number & " occurred."
        End Select
        Err.Clear
    End Sub

    Private Sub Class_Terminate
        CatchErr
        WScript.Echo "Exiting" 
    End Sub 
End Class

Dim Func1 : Set Func1 = New CFunc1 : Set Func1 = Nothing

Alors que c'est plutôt cool, en ce sens qu'il est intelligent, "intelligents" le code est rarement lisible et facilement maintenable/utilisable. Je ne suis pas à l'aise de faire un -1 sur ce point, mais c'est vraiment "mauvais code" à des fins de production. Cool académiquement bien.

InformationsquelleAutor AngelicCare

0

Parfois, en particulier lorsque vous travaillez avec VB, vous pouvez manquer de solutions évidentes. Comme je le faisais depuis 2 jours.

le code qui génère l'erreur doit être déplacé vers une fonction distincte. Et dans le début de la fonction que vous écrivez On Error Resume Next. C'est comment une erreur peut être "avalé", sans avaler toutes les autres erreurs. Diviser le code en petites fonctions distinctes améliore également la lisibilité, refactoring & rend plus facile d'ajouter de nouvelles fonctionnalités.
- Ou vous pourriez mettre On Error Goto 0 après le code qui génère l'erreur, de sorte que vous n'avez pas à supporter la charge d'un appel de fonction (et n'ont pas besoin de minuscules fonctions qui ne font aucun travail réel).
InformationsquelleAutor Vital

Vous devez vous connecter pour publier un commentaire.

Les Erreurs De Manipulation

La Levée Des Erreurs