Un Système Est-Il Défini La Variable D'Environnement Pour Le Répertoire Documents?

Que je sais sur les %USERPROFILE% système défini la variable d'environnement sous Windows XP (et Vista et Windows 7). Un système est-il défini la variable d'environnement pointant vers l'emplacement de le "Mes Documents" répertoire? Sur XP, par défaut, il %USERPROFILE%\My Documents et sur Win 7 c'est %USERPROFILE%\Documents. Je voulais juste éviter d'avoir à tester la version de l'OS dans un script Powershell si je peux l'éviter.

  • Comme une réponse, il n'y a pas de Variable d'Environnement pointant vers Mes Documents, mais il est Environment.GetFolderPath(Environment.SpecialFolder.Mydocuments) (C#) pour .NET. Je suis principalement l'ajout de ce commentaire car cette question revient quand googler pour C#, les variables d'environnement et mes documents et la solution la plus simple dans .NET est à l'aide de la méthode ci-dessus.
  • Vous devez avoir posté en réponse @flindeberg, j'aurais voté il. Bon à savoir.
  • Je l'ai ajouté comme une réponse maintenant 🙂
  • Dans windows il y a un junction que des liens documents à my documents. ` <JONCTION> Mes Documents [C:\Users\Philip\Documents]`
InformationsquelleAutor Onorio Catenacci | 2010-08-16
  1. 30

    Sur mon défaut-installation de XP, il n'y a pas de variable d'environnement pour que. Vous pouvez dresser la liste de toutes les variables avec la commande "set" (pas de paramètres ) dans la ligne de commande. Donc, probablement que vous avez à faire un test.

    Si vous ne voulez pas tester pour la version de l'OS, vous pouvez simplement vérifier si les "Documents" existe et si non, alors essayer de "Mes Documents" ou vice versa. Ce n'est pas parfait cependant, parce que s/o pourrait avoir un dossier "Documents" sur sa machine XP.

    Btw: mon système est allemand, donc le dossier est appelé "Dokumente". Vous pourriez avoir besoin de prendre en compte.

    Le chemin d'accès à ce dossier est stocké dans

    HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders

    sous Personal. Vous avez besoin d'accès au registre, si.

    Source: Microsoft

    • Excellente suggestion à propos de cette clé de registre.
    InformationsquelleAutor msteiger
  2. 29

    Pour powershell, les travaux suivants:

    [environment]::getfolderpath("mydocuments")

    et en évitant les chaînes magiques

    [Environment]::GetFolderPath([Environment+SpecialFolder]::MyDocuments)

    Pour .NET le suivant est vrai (c'est à dire pas applicable dans tous applications windows):

    Comme une réponse, il n'y a pas de Variable d'Environnement pointant vers Mes Documents, mais il est Environment.GetFolderPath(Environment.SpecialFolder.MyDocuments) (C#) pour .NET.

    Je suis l'ajout de cette réponse étant donné que cette question revient quand googler pour C#, les variables d'environnement et mes documents et Justin réponse ne contient pas la ligne de code 🙂

    À l'aide de l'mentionnés ci-dessus de la ligne de code est la voie privilégiée pour accéder à mes documents .NET 🙂

    Copier-coller de cette ligne pour C# usage:

    var directoryNameOfMyDocuments = Environment.GetFolderPath(Environment.SpecialFolder.MyDocuments);

    Remarque que le C# a besoin d'un capital D dans Mesdocuments.

    • Questions demande une Powershell réponse, pas de C#.
    • Wow homme, avez-vous lu ce que j'ai écrit dans cette SIX ans réponse? Pour éviter tout doute: je suis l'ajout de cette réponse étant donné que cette question revient quand googler pour C#, les variables d'environnement et mes documents
    • Oui je l'ai fait. Ce serait toujours mieux qu'un commentaire, ou si vous voulez poser/répondre à votre propre question.
    InformationsquelleAutor flindeberg
  3. 22

    Il n'y a pas intégré de l'environnement variable, mais dans PowerShell, vous pouvez trouver l'emplacement avec:

    [Environment]::GetFolderPath("mydocuments")

    Vous pouvez bien évidemment créer une variable d'environnement avec:

    $env:DOCUMENTS = [Environment]::GetFolderPath("mydocuments")
    • Bonne amplification.
    • J'ai eu du mal à obtenir la syntaxe juste à droite de la conversion de .net de powershell. Pas besoin d'utiliser un enum pour le param si une chaîne ne pourra le faire.
    • D'accord, mais pour ceux qui n'aiment pas la magie des cordes, comme moi, il y a un enum: [Environment]::GetFolderPath([Environment+SpecialFolder]::MyDocuments
    • Grand. Avez-vous de l'utilisation de l' + un lot dans powershell alors? J'ai toujours essayé une . au lieu de cela, comme vous le feriez en C# et a obtenu nulle part.
    • Le + il n'y a pas une fonction de PowerShell, exactement. L'expression [Environment+SpecialFolder] indique le sous-type SpecialFolder, qui est un type enum est imbriqué dans le Environment statique de la classe. À l'aide de l' + précéder le nom de la classe imbriquée est une représentation commune pour une classe imbriquée. Voir docs.microsoft.com/en-us/dotnet/api/... (dans la section des Remarques)
    InformationsquelleAutor Hipponax43
  4. 14

    (Juste pour rappeler les réponses précédentes) Il n'y a pas de variable d'environnement fournis à l'extérieur de la boîte (WinXP) pour le dossier "Mes Documents" répertoire.

    Cependant, vous pouvez définir une variable avec la commande suivante:

    Testé sur Windows 7 /8.1:

    for /f "tokens=3* delims= " %a ^
in ('reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal"') ^
do (set mydocuments=%a %b)

    ou (un liner)

    for /f "tokens=3* delims= " %a in ('reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal"') do (set mydocuments=%a %b)

    Qui serait alors donnez-vous une %mydocuments% variable:

    C:\>echo mydocuments="%mydocuments%"

mydocuments="C:\pathto\My Documents"

    (Peut-on utiliser XP/Vista? Si oui, pouvez tester cela et laissez-nous savoir si cela fonctionne?)

    • Salut! Merci pour votre réponse. Sur mon ordinateur Windows 7 il y a des espaces dans le chemin. Par exemple "\\drive\utilisateurs\nom d'utilisateur\Mes Documents\". L' %UserDocuments% variable renvoie ceci: "\\drive\utilisateurs\nom d'utilisateur\Mes". Est-ce possible de résoudre?
    • Je suis capable de reproduire votre problème au travail. Bascially les "Documents" est analysée comme un deuxième jeton. La solution, serait d'utiliser la %b variable, comme ceci: FOR /F "tokens=3* delims= " %a in ('reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal"') do (set mydocuments=%a %b) <--.
    • Merci beaucoup!
    • Ce sera un échec si il y a plus d'un espace dans le chemin d'accès. Correcte serait tokens=2* et puis set mydocuments=%b.
    InformationsquelleAutor Nick Grealy
  5. 7

    Si vous tapez:

    set

    Dans une invite de commande, vous obtiendrez une liste de toutes les variables d'environnement définies sur votre système.

    À la recherche à celles définies sur la mienne (Windows 7 Home Premium) aucun d'entre eux semblent pointer vers Mes Documents.

    FYI:

    La SHGetSpecialFolderPath) fonction peut être utilisée pour obtenir le chemin d'accès au répertoire Mes Documents. Sinon le De l'environnement.GetFolderPath méthode peut être utilisée sous .Net

    InformationsquelleAutor Justin
  6. 5
    C:\Documents and Settings\mrabinovitch>set | grep -i document
ALLUSERSPROFILE=C:\Documents and Settings\All Users
APPDATA=C:\Documents and Settings\myuser\Application Data
HOMEPATH=\Documents and Settings\myuser
USERPROFILE=C:\Documents and Settings\myuser

    comme vous pouvez le voir il n'y a aucune une telle vairable.

    InformationsquelleAutor Moisei
  7. 4

    En plus de réponses sur la base de registre, .NET et PowerShell, vous pouvez également utiliser WshSpecialFolders de WSH. Voici un autonome commande/script batch qui démontre comment:

    @echo off
call :script > "%temp%\%~n0.js" && cscript //nologo "%temp%\%~n0.js" %*
goto :EOF

:script
echo var specialFolders = WScript.CreateObject('WScript.Shell').SpecialFolders;
echo if (WScript.Arguments.length === 0) {
echo     for (var e = new Enumerator(specialFolders); !e.atEnd(); e.moveNext()) {
echo         WScript.Echo(e.item());
echo     }
echo } else {
echo     for (var e = new Enumerator(WScript.Arguments); !e.atEnd(); e.moveNext()) {
echo         WScript.Echo(specialFolders(e.item()));
echo     }
echo }
goto :EOF

    Il émet un script WSH en JScript et l'utilise pour obtenir un ou plusieurs chemins d'accès pour le dossier spécial jetons fournis en arguments. En supposant que vous enregistrez le script ci-dessus dans un fichier appelé specialf.cmd, l'utilisation pour l'obtention de chemin d'accès aux documents de l'utilisateur courant répertoire serait:

    specialf MyDocuments

    Voici une autre utilisation de tester tous les dossier spécial jetons:

    specialf ^
  AllUsersDesktop ^
  AllUsersStartMenu ^
  AllUsersPrograms ^
  AllUsersStartup ^
  Desktop ^
  Favorites ^
  Fonts ^
  MyDocuments ^
  NetHood ^
  PrintHood ^
  Programs ^
  Recent ^
  SendTo ^
  StartMenu ^
  Startup ^
  Templates

    Vous pouvez l'utiliser pour la capture dans un environnement variable comme ceci:

    for /f "delims=/" %p in ('specialf MyDocuments') do @set MYDOCS=%p
    InformationsquelleAutor Atif Aziz
  8. 3

    Une certaine confusion peut-être en raison de la disponibilité de CSIDL/KNOWNFOLDERID valeurs de vs de commande shell variables d'environnement.

    • CSIDLs peut être utilisé en PowerShell avec SheGetSpecialFolderPath. Voir Justin réponse pour plus de détails.
    InformationsquelleAutor John Chacho
  9. 2

    Pour un fichier de commandes dans Windows 7 (au moins), Nick G de la solution a besoin d'un léger réglage pour définir la variable définie par l'utilisateur UserDocuments :

    FOR /F "tokens=3* delims= " %%a in ('reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal"') do (set UserDocuments=%%a)

    Note les seules différences sont,

    1. Utilisez uniquement un caractère d'espace pour delims
    2. %%a la place de %un

    Pour éviter de voir la ligne, mais à voir les résultats, utilisez :

    @FOR /F "tokens=3* delims= " %%a in ('reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal"') do @(Set UserDocuments=%%a)
@Echo ~~~~~~~~ UserDocuments=%UserDocuments%

    Merci Nick G. Votre réponse m'a beaucoup appris. J'espère que cela aide quelqu'un d'autre.

    • Salut! Merci pour votre réponse. Sur mon ordinateur Windows 7 il y a des espaces dans le chemin. Par exemple "\\drive\utilisateurs\nom d'utilisateur\Mes Documents\". L' %UserDocuments% variable renvoie ceci: "\\drive\utilisateurs\nom d'utilisateur\Mes". Est-ce possible de résoudre?
    InformationsquelleAutor Rocky Scott
  10. 2

    Amélioré @NickGrealy réponse:

    1. reg query sorties
    empty_line 
reg_key_path 
nom type valeur
    1. il peut y avoir une quantité arbitraire de " l'espace de la station entre les mots d'une valeur de registre, et le %a %b chaîne n'est pas correct dans ce cas

    Donc, en utilisant le skip=2 option pour ignorer les premières lignes et le tokens=2* option pour passer à une valeur de registre à la %b var:

    for /f "skip=2 tokens=2*" %A in ('reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal"') do @set "UserDocs=%B"

    ou pour les fichiers de script:

    for /f "skip=2 tokens=2*" %%A in ('reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal"') do set "UserDocs=%%B"

    Mais en tenant compte de la valeur de registre [HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders\!Do not use this registry key]

    Basé sur @AtifAziz réponse:

    for /f "tokens=*" %A in ('echo WScript.Echo^(^(new ActiveXObject^("WScript.Shell"^)^).SpecialFolders^("MyDocuments"^)^)^>%TEMP%\getdoc.js ^& cscript /nologo %TEMP%\getdoc.js ^& del /q %TEMP%\getdoc.js') do @set "UserDocs=%A"
    InformationsquelleAutor Dmitry Sokolov
  11. 1

    Il n'existe pas, par conception, un des documents de la variable d'environnement windows. Vous devez créer une personnalisée. Pour ce faire, aller ici. Définir une variable d'environnement appelée DOCUMENTS de référence, selon l'endroit que vous devez référencés. Par la suite, elle doit être une variable d'environnement de référence en %MYDOCUMENTS%.

    • En règle générale, le point de lecture d'une variable d'environnement est d'obtenir des informations sur d'autres machines que la vôtre où vous connaissez déjà la valeur. Afin de définir une variable personnalisée, vous auriez encore besoin de l'obtenir par programmation de la première!
    InformationsquelleAutor Neal Bangia
  12. 1

    Testé et worrking dans win XP, vista, 8, 8.1 et 10!! 

    @echo off
    for /f "skip=2 tokens=2*" %%c in ('reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal"') do @set "docs=%%d" && echo WIN XP - 10
    xcopy "C:\test.txt" "%docs%" /f /y
echo %docs%
pause
EXIT
    InformationsquelleAutor George H. Compton IV
  13. 0

    Windows Fichier De Commandes (.chauve-souris) ou Script de Commande Windows (.cmd)

    @echo off
ver | find "XP" > nul
    if %ERRORLEVEL% == 0 set Docs=%UserProfile%\My Documents & echo WIN XP
    if %ERRORLEVEL% == 1 set Docs=%UserProfile%\Documents & echo WIN vista - 10

    xcopy  "C:\test.txt"  "%Docs%" /f /y 
pause
EXIT
    InformationsquelleAutor George H. Compton IV
  14. 0

    mise à jour de Windows Fichier de commandes (.chauve-souris) ou Script de Commande Windows (.cmd)

    @echo off
ver | find "XP" > nul
    if %ERRORLEVEL% == 0 SET DOCS=%USERPROFILE%\My Documents & echo WIN XP
    if %ERRORLEVEL% == 1 FOR /f "tokens=3" %%x IN ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal"') do (set docs=%%x) & echo WIN vista - 10

    xcopy "C:\test.txt" "%docs%" /f /y
echo %docs%
pause
EXIT
    • cela ne fait pas de sens dans toutes les langues, mais l'anglais, par exemple, en allemand %USERPROFILE%\My Documents est %USERPROFILE%\Dokumente, en polonais %USERPROFILE%\Moje Dokumenty, cependant Win XP en cours d'exécution est plutôt rare, alors j'aimerais l'enlever à tous
    InformationsquelleAutor George H. Compton IV
  15. 0

    Voici la liste complète des variables utilisateur pour tous les utilisateurs de Windows.

    Le reg query partie du code constaterez que la valeur et le configurer de sorte qu'il peut être utilisé immédiatement et permet à l'autre de codes pour définir de façon permanente pour tous les utilisateurs.
    L'annonce de registre partie du code de l'activer pour tous les utilisateurs. Le setx fait de sorte que vous n'avez pas à vous déconnecter et vous reconnecter pour être en mesure d'utiliser les codes.

    L'utilisateur actuel variables ne s'applique qu'à la personne qui a installé ce code.

    @ECHO OFF
ECHO REG ALL USER variables

ECHO all user desktop
for /f "skip=2 tokens=3*" %%c in ('reg query "HKLM\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Common Desktop"') do @set "ALLDT=%%d"
 REG ADD "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment"  /v "ALLDT" /t  "REG_SZ"  /d "%ALLDT%" /f
 setx ALLDT "%ALLDT%"

 Echo all user's documents
  for /f "skip=2 tokens=3*" %%c in ('reg query "HKLM\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Common Documents"') do @set "ALLDOC=%%d"
   REG ADD "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment"  /v "ALLDOC" /t  "REG_SZ"  /d "%ALLDOC%" /f
   setx ALLDOC "%ALLDOC%"

 echo all user start menu
 for /f "skip=2 tokens=3*" %%c in ('reg query "HKLM\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Common Programs"') do    @set "ALLSM=%%d"
 REG ADD "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment"  /v "ALLSM" /t  "REG_SZ"  /d "%ALLSM%" /f 
 setx ALLSM "%ALLSM%"

  Echo all users startup
  for /f "skip=2 tokens=3*" %%c in ('reg query "HKLM\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Common Startup"') do @set "ALLSMSTU=%%d"
   REG ADD "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment"  /v "ALLSMSTU" /t  "REG_SZ"  /d "%ALLSMSTU%" /f 
   setx ALLSMSTU "%ALLSMSTU%"

  Echo all users music
  for /f "skip=2 tokens=2*" %%c in ('reg query "HKLM\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "CommonMusic"') do @set "ALLMU=%%d"
   REG ADD "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment"  /v "ALLMU" /t  "REG_SZ"  /d "%ALLMU%" /f 
   setx ALLMU "%ALLMU%"

  echo all users pictures
  for /f "skip=2 tokens=2*" %%c in ('reg query "HKLM\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "CommonPictures"') do @set "ALLPIC=%%d"
 REG ADD "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment"  /v "ALLPIC" /t  "REG_SZ"  /d "%ALLPIC%" /f 
 setx ALLPIC "%ALLPIC%"

 Echo all users videos
 for /f "skip=2 tokens=2*" %%c in ('reg query "HKLM\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "CommonVideo"') do @set "ALLVID=%%d"
 REG ADD "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment"  /v "ALLVID" /t  "REG_SZ"  /d "%ALLVID%" /f
 setx ALLVID "%ALLVID%"

 Echo set cerrent user variables 

 Echo current users desktop
 for /f "skip=2 tokens=2*" %%c in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Desktop"') do @set "myDesktop=%%d"
   REG ADD "HKEY_CURRENT_USER\Environment"  /v "myDesktop" /t  "REG_SZ"  /d "%myDesktop%" /f 
setx myDesktop "%myDesktop%"

 Echo current users documents
 for /f "skip=2 tokens=2*" %%c in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal"') do @set "mydoc=%%d"
 REG ADD "HKEY_CURRENT_USER\Environment"  /v "mydoc" /t  "REG_SZ"  /d "%mydoc%" /f 
   setx mydoc "%mydoc%"

 Echo current user start menu
 for /f "skip=2 tokens=3*" %%c in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Start Menu"') do @set "myStart=%%d"
   REG ADD "HKEY_CURRENT_USER\Environment"  /v "myStart" /t  "REG_SZ"  /d "%myStart%" /f 
   setx myStart "%myStart%"

  Echo current user startup
  for /f "skip=2 tokens=2*" %%c in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Startup"') do @set "myStartup=%%d"
   REG ADD "HKEY_CURRENT_USER\Environment"  /v "myStartup" /t  "REG_SZ"  /d "%myStartup%" /f 
   setx myStartup "%myStartup%"

  Echo current users music
  for /f "skip=2 tokens=3*" %%c in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Music"') do @set "myMU=%%d"
   REG ADD "HKEY_CURRENT_USER\Environment"  /v "myMU" /t  "REG_SZ"  /d "%myMU%" /f 
   setx myMU "%myMU%"

 Echo current users pictures
 for /f "skip=2 tokens=3*" %%c in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Pictures"') do @set "myPIC=%%d"
  REG ADD "HKEY_CURRENT_USER\Environment"  /v "myPIC" /t  "REG_SZ"  /d "%myPIC%" /f 
  setx myPIC "%myPIC%"

 Echo current users video
 for /f "skip=2 tokens=3*" %%c in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Video"') do @set "myVID=%%d"
 REG ADD "HKEY_CURRENT_USER\Environment"  /v "myVID" /t  "REG_SZ"  /d    "%myVID%" /f
   setx myVID "%myVID%"

 exit
    InformationsquelleAutor
  16. -2

    En fait, la %USERPROFILE%\My Documents devrait fonctionner dans Windows 7. C'est ce que j'utilise.

    • Trois ans après, la question a été posée, vous laissez une ligne de réponse et ne plus jamais la peine de lire la meilleure réponse (qui aurait montré vous de votre faute).
    • L'erreur est de ne pas prendre de paramètres régionaux en compte? La Cause, au moins sur les systèmes anglais, %userprofile%\Mes Documents est un lien symbolique vers %userprofile%\Documents dans Windows Vista et au-dessus. C'est pour la compatibilité avec Windows XP.
    InformationsquelleAutor user3080328