Utilisation des Types de Données Personnalisés en VBA

Je suis en train de créer un type de données personnalisé en VBA pour Excel. Nous appellerons ce type de données "camion". Chaque camion a les attributs suivants:

NumberOfAxles (this is an integer)
AxleWeights (this is an array of doubles)
AxleSpacings (this is an array of doubles)

Puis-je créer plusieurs instances du type de données "truck" (camion(1), camion(2)... etc), et de lire/écrire les attributs que j'ai énumérés ci-dessus à cette instance?

Exemple:

Truck(1).NumberOfAxles = 2
Truck(1).AxleWeights(1) = 15.0
Truck(1).AxleWeights(2) = 30.0
Truck(1).AxleSpacings(1) = 8.0

Truck(2).NumberOfAxles = 3
Truck(2).AxleWeights(1) = 8.0
Truck(2).AxleWeights(2) = 10.0
Truck(2).AxleWeights(3) = 12.0
Truck(2).AxleSpacings(1) = 20.0
Truck(2).AxleSpacings(2) = 4.0

et ainsi de suite. La syntaxe ci-dessus est le plus probablement de mal, je voulais juste démontrer la structure j'ai besoin de venir avec.

Tout ce que je suis en train d'écrire des données dans une structure de données et l'appeler comme nécessaire, comme par exemple

Truck(i).NumberOfAxles
Truck(i).AxleWeights(j)
Truck(i).AxleSpacings(j)

Merci beaucoup!

InformationsquelleAutor marillion | 2012-09-13
  1. 63

    Bien sûr, vous pouvez:

    Option Explicit
'***** User defined type
Public Type MyType
MyInt As Integer
MyString As String
MyDoubleArr(2) As Double
End Type
'***** Testing MyType as single variable
Public Sub MyFirstSub()
Dim MyVar As MyType
MyVar.MyInt = 2
MyVar.MyString = "cool"
MyVar.MyDoubleArr(0) = 1
MyVar.MyDoubleArr(1) = 2
MyVar.MyDoubleArr(2) = 3
Debug.Print "MyVar: " & MyVar.MyInt & " " & MyVar.MyString & " " & MyVar.MyDoubleArr(0) & " " & MyVar.MyDoubleArr(1) & " " & MyVar.MyDoubleArr(2)
End Sub
'***** Testing MyType as an array
Public Sub MySecondSub()
Dim MyArr(2) As MyType
Dim i As Integer
MyArr(0).MyInt = 31
MyArr(0).MyString = "VBA"
MyArr(0).MyDoubleArr(0) = 1
MyArr(0).MyDoubleArr(1) = 2
MyArr(0).MyDoubleArr(2) = 3
MyArr(1).MyInt = 32
MyArr(1).MyString = "is"
MyArr(1).MyDoubleArr(0) = 11
MyArr(1).MyDoubleArr(1) = 22
MyArr(1).MyDoubleArr(2) = 33
MyArr(2).MyInt = 33
MyArr(2).MyString = "cool"
MyArr(2).MyDoubleArr(0) = 111
MyArr(2).MyDoubleArr(1) = 222
MyArr(2).MyDoubleArr(2) = 333
For i = LBound(MyArr) To UBound(MyArr)
Debug.Print "MyArr: " & MyArr(i).MyString & " " & MyArr(i).MyInt & " " & MyArr(i).MyDoubleArr(0) & " " & MyArr(i).MyDoubleArr(1) & " " & MyArr(i).MyDoubleArr(2)
Next
End Sub
    • Vous êtes les bienvenus! La réponse de @ooo sur les classes aussi le travail pour vous.
    • J'ai vérifié ooo réponse, et je vois les avantages de l'utilisation de classes au lieu de types. Je suis d'accord que l'utilisation de classes permettent de rendre le code plus d'avenir, mais votre réponse résout mon problème spécifique (la structure de données est très simple et limité) de manière rapide.
    • Vous devez vous assurer que le type est défini avant tout des sous-marins ou des fonctions, de définir plus tard, il va causer des problèmes (ou pas).
    • Est le MyType définition dans le même module de code? Ce genre de module de code est le code?
    InformationsquelleAutor Olle Sjögren
  2. 28

    Il semble que vous souhaitez définir Camion Class avec des propriétés NumberOfAxles, AxleWeights & AxleSpacings.

    Il peut être défini dans un MODULE de CLASSE (ici nommé clsTrucks)

    Option Explicit
Private tID As String
Private tNumberOfAxles As Double
Private tAxleSpacings As Double
Public Property Get truckID() As String
truckID = tID
End Property
Public Property Let truckID(value As String)
tID = value
End Property
Public Property Get truckNumberOfAxles() As Double
truckNumberOfAxles = tNumberOfAxles
End Property
Public Property Let truckNumberOfAxles(value As Double)
tNumberOfAxles = value
End Property
Public Property Get truckAxleSpacings() As Double
truckAxleSpacings = tAxleSpacings
End Property
Public Property Let truckAxleSpacings(value As Double)
tAxleSpacings = value
End Property

    puis dans un MODULE celui-ci définit un nouveau camion et de ses propriétés, et l'ajoute à une collection de camions, puis récupère la collection.

    Option Explicit
Public TruckCollection As New Collection
Sub DefineNewTruck()
Dim tempTruck As clsTrucks
Dim i As Long
'Add 5 trucks
For i = 1 To 5
Set tempTruck = New clsTrucks
'Random data
tempTruck.truckID = "Truck" & i
tempTruck.truckAxleSpacings = 13.5 + i
tempTruck.truckNumberOfAxles = 20.5 + i
'tempTruck.truckID is the collection key
TruckCollection.Add tempTruck, tempTruck.truckID
Next i
'retrieve 5 trucks
For i = 1 To 5
'retrieve by collection index
Debug.Print TruckCollection(i).truckAxleSpacings
'retrieve by key
Debug.Print TruckCollection("Truck" & i).truckAxleSpacings
Next i
End Sub

    Il y a plusieurs façons de faire cela, donc cela dépend vraiment de comment vous avez l'intention d'utiliser les données afin de déterminer si une classe/collection est le meilleur de l'installation ou des tableaux/dictionnaires etc.

    • merci pour l'explication de la démarche à l'aide de classes. Je l'ai fait aujourd'hui, à peine à se familiariser avec, et il fonctionne comme un charme. Pour mon but, la "coutume" type d'approche fonctionne, car il n'y aura pas d'extension de ce projet dans l'avenir. Cependant, je vais essayer d'utiliser les classes plus souvent dans les projets à venir. Merci!
    InformationsquelleAutor user3357963