Utilisation esttab pour générer des statistiques sommaires par groupe avec des colonnes pour la moyenne de la différence et de l'importance

Je voudrais utiliser esttab (ssc install estout) pour générer des statistiques sommaires par groupe avec des colonnes pour la moyenne de la différence et de la signification. Il est assez facile de générer ces deux tableaux séparés avec estpost, summarize, et ttest, et de les combiner à la main, mais je voudrais automatiser l'ensemble du processus.

Le code suivant génère les deux composants de la table désirée.

sysuse auto, clear

* summary statistics by group
eststo clear
by foreign: eststo: quietly estpost summarize ///
    price mpg weight headroom trunk
esttab, cells("mean sd") label nodepvar   

* difference in means
eststo: estpost ttest price mpg weight headroom trunk, ///
    by(foreign) unequal 
esttab ., wide label

Et je peux imprimer les deux tables et couper-une-coller dans un tableau.

* can generate similar tables and append horizontally
esttab, cells("mean sd") label
esttab, wide label


* manual, cut-and-paste solution
-------------------------------------------------------------------------------------------------------
                              (1)                       (2)                         (3)                

                             mean           sd         mean           sd         
-------------------------------------------------------------------------------------------------------
Price                    6072.423     3097.104     6384.682     2621.915         -312.3         (-0.44)
Mileage (mpg)            19.82692     4.743297     24.77273     6.611187         -4.946**       (-3.18)
Weight (lbs.)            3317.115     695.3637     2315.909     433.0035         1001.2***       (7.50)
Headroom (in.)           3.153846     .9157578     2.613636     .4862837          0.540**        (3.30)
Trunk space (.. ft.)        14.75     4.306288     11.40909     3.216906          3.341***       (3.67)
-------------------------------------------------------------------------------------------------------
Observations                   52                        22                          74                
-------------------------------------------------------------------------------------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001

Il semble que je devrais être en mesure d'obtenir la table désirée avec un esttab appel et sans couper-coller, mais je ne peux pas le comprendre. Est-il un moyen pour générer la table désirée sans manuellement couper-coller?

Je préfère à la sortie d'un LaTeX de la table, mais rien de ce qui élimine le couper-coller est un grand pas, même en passant par l'intermédiaire d'un fichier texte délimité.

OriginalL'auteur Richard Herron | 2013-03-21

stata

Si vous voulez toujours utiliser esttab, vous pouvez jouer à l'aide de cellules et de motif. La table dans le post original peuvent être reproduits avec le code suivant:

sysuse auto, clear

eststo domestic: quietly estpost summarize ///
    price mpg weight headroom trunk if foreign == 0
eststo foreign: quietly estpost summarize ///
    price mpg weight headroom trunk if foreign == 1
eststo diff: quietly estpost ttest ///
    price mpg weight headroom trunk, by(foreign) unequal

esttab domestic foreign diff, ///
cells("mean(pattern(1 1 0) fmt(2)) sd(pattern(1 1 0)) b(star pattern(0 0 1) fmt(2)) t(pattern(0 0 1) par fmt(2))") ///
label

qui donne

-----------------------------------------------------------------------------------------------------
                              (1)                       (2)                       (3)                

                             mean           sd         mean           sd            b               t
-----------------------------------------------------------------------------------------------------
Price                     6072.42      3097.10      6384.68      2621.92      -312.26         (-0.44)
Mileage (mpg)               19.83         4.74        24.77         6.61        -4.95**       (-3.18)
Weight (lbs.)             3317.12       695.36      2315.91       433.00      1001.21***       (7.50)
Headroom (in.)               3.15         0.92         2.61         0.49         0.54**        (3.30)
Trunk space (.. ft.)        14.75         4.31        11.41         3.22         3.34***       (3.67)
-----------------------------------------------------------------------------------------------------
Observations                   52                        22                        74                
-----------------------------------------------------------------------------------------------------

Merci! Je n'ai pas regardé de près à la cells options. Ce sera utile partout où je utiliser esttab. Qui est partout. Ben Jann devrait obtenir un prix Nobel pour esttab.

OriginalL'auteur Mattias Öhman

Je ne pense pas qu'il y a un moyen de le faire avec esttab (estout paquet de ssc), mais j'ai une solution avec listtab (également ssc) et postfile. Le tableau est un peu différent de celui que j'ai proposé ci-dessus, mais l'approche est assez générale que vous pouvez modifier en fonction de vos besoins.

Cette solution présente en outre l'utilisation de LaTeX booktabs paquet.

/* data and variables */
sysuse auto, clear
local vars price mpg weight headroom trunk

/* means */
tempname postMeans
tempfile means
postfile `postMeans' ///
    str100 varname domesticMeans foreignMeans pMeans using "`means'", replace
foreach v of local vars {
    local name: variable label `v'
    ttest `v', by(foreign)
    post `postMeans' ("`name'") (r(mu_1)) (r(mu_2)) (r(p))
}
postclose `postMeans'

/* medians */
tempname postMedians
tempfile medians
postfile `postMedians' ///
    domesticMedians foreignMedians pMedians using `medians', replace
foreach v of local vars {
    summarize `v' if !foreign, detail
    local med1 = r(p50)
    summarize `v' if foreign, detail
    local med2 = r(p50)
    ranksum `v', by(foreign)
    local pval = 2 * (1 - normal(abs(r(z))))
    post `postMedians' (`med1') (`med2') (`pval')
}
postclose `postMedians'

/* combine */
use `means'
merge 1:1 _n using `medians', nogenerate
format *Means *Medians %9.3gc
list

/* make latex table */
/* requires LaTeX package `booktabs` */
listtab * using "Table.tex", ///
    rstyle(tabular) replace ///
    head("\begin{tabular}{lcccccc}" ///
    "\toprule" ///
    "& \multicolumn{3}{c}{Means} & \multicolumn{3}{c}{Medians} \\" ///
    "\cmidrule(lr){2-4} \cmidrule(lr){5-7}" ///
    "& Domestic & Foreign & \emph{p} & Domestic & Foreign & \emph{p}\\" ///
    "\midrule") ///
    foot("\bottomrule" "\end{tabular}")

Cela donne ce qui suit.

Utilisation esttab pour générer des statistiques sommaires par groupe avec des colonnes pour la moyenne de la différence et de l'importance

OriginalL'auteur Richard Herron

1

La réponse choisie est sympa mais un peu devenus inutiles. Vous pouvez obtenir le même résultat avec seulement estpost test-t bilatéral.
```
sysuse auto, clear
estpost ttest price mpg weight headroom trunk, by(foreign)
esttab, cells("mu_1 mu_2 b(star)"
```
La sortie ressemble à ceci:
```
             mu_1          mu_2         b   

c_score     43.33858    42.034       1.30458***
nc_a4_17    4.007524    3.924623    .0829008*  
```
Nice! Un avantage de la réponse choisie, vous pouvez inclure des moments non signalés par estpost ttest.

OriginalL'auteur Yan Song

Vous devez vous connecter pour publier un commentaire.