VB6-faire pour créer le fichier journal en VB6 lors du lancement de l'application

Je veux ouvrir une session à l'exception survenue pendant l'exécution de mon application. Avant cela, je traitées avec boîte de message. Je suis nouveau sur VB 6.

Veuillez fournir un exemple de code pour créer le fichier journal et d'enregistrer des messages d'exception.

Merci..

articles.techrepublic.com.com/5100-10878_11-5798663.html Qui semble être à peu près ce que vous voulez.
Grâce MarkJ. 🙂

OriginalL'auteur Royson | 2010-01-13

  1. 7

    Vous avez besoin de gestionnaires d'erreurs, à l'aide de On Error Goto, de sorte que vous pouvez exécuter votre propre code lorsqu'une erreur se produit. (BTW en VB6 ils sont appelés erreurs pas exceptions.) L'outil gratuit MZTools est excellente, il peut insérer automatiquement les On Error Goto et un gestionnaire d'erreur, qui comprend le nom de la routine actuelle.

    Vous avez également besoin d'un général de routine qui enregistre les détails de l'erreur dans un fichier, un peu comme ce ci-dessous. Avertissement de santé - j'ai juste tapé directement dans sans le tester (air code). 

    Sub MySub()
  On Error Goto ErrHandler
  '... Do something ...'
  On Error Goto 0
  Exit Sub

ErrHandler:
  Call LogError("MySub", Err, Error$) ' passes name of current routine '
End Sub 

' General routine for logging errors '
Sub LogError(ProcName$, ErrNum&, ErrorMsg$)
  On Error Goto ErrHandler
  Dim nUnit As Integer
  nUnit = FreeFile
  ' This assumes write access to the directory containing the program '
  ' You will need to choose another directory if this is not possible '
  Open App.Path & App.ExeName & ".log" For Append As nUnit
  Print #nUnit, "Error in " & ProcName
  Print #nUnit, "  " & ErrNum & ", " & ErrorMsg
  Print #nUnit, "  " & Format$(Now)
  Print #nUnit
  Close nUnit
  Exit Sub

ErrHandler:
  'Failed to write log for some reason.'
  'Show MsgBox so error does not go unreported '
  MsgBox "Error in " & ProcName & vbNewLine & _
    ErrNum & ", " & ErrorMsg
End Sub

    Bonus suggestion: rouler votre propre trace de la pile.

    Bonus suggestion 2: éteindre les gestionnaires d'erreur dans l'IDE avec quelque chose comme ça If Not IsInIDE() Then On Error Goto Handler, à l'aide de la IsInIDE fonction de ici

    OriginalL'auteur MarkJ