VBA - Access - Obtenir le dernier jour du mois

J'ai besoin de votre aide. Je veux obtenir le dernier jour du mois. Eh bien c'est mon code, mais si je veux le débogage et de compilation à la base de données qu'il dit qu'il a une erreur dans la syntaxe.
S'il vous plaît aider =)

Public Function GetNowLast() As Date
Dim asdfh As Date
asdfh = DateValue("1." _
& IIf(Month(Date) + 1) > 12, Month(Date) + 1 - 12, Month(Date) + 1) _
&"."&IIf(Month(Date)+1)>12 , Year(Date)+1,Year(Date))
asdf = DateAdd("d", -1, asdf)
GetNowLast = asdf
End Function

Regardez ici. Il donne des fonctions pour faire ce que vous voulez.
j'ai eu la syntaxe, mais dans la deuxième ligne, on me dit que mon argument n'est pas facultatif
en gros pour ce que vous voulez, vous avez seulement besoin d'une seule ligne dans votre fonction: GetNowLast = Format(DateSerial(Year(Date), Month(Date) + 1, 0), "d") Cela vous donnera une réponse de 31 de ce mois, puis, quand nous entrons novembre, il donnera à 30 et ainsi de suite.
ouais mais l'année 1900 😀
Si vous souhaitez que la date complète ensuite supprimer le formatage GetNowLast = DateSerial(Year(Date), Month(Date) + 1, 0). Je pensais que vous vouliez le dernier jour seulement. Désolé.
merci bro 🙂
Content d'avoir pu aider
asdf <> asdfh

InformationsquelleAutor linuxman | 2015-10-13

vba

10

GD Linuxman,

Nous allons concentrer sur l'obtention du résultat...:-)

Voir aussi: ici

Le commentaire de @Scott Craner est sur place ! Bien que strictement parlant, il n'est pas nécessaire d'utiliser la mise en forme. (En supposant que vous voulez travailler avec le 'Date' objet)

À réaliser ce que vous voulez, le programme d'installation de la fonction comme ci-dessous:
```
Function GetNowLast() as Date

    dYear = Year(Now)
    dMonth = Month(Now)

    getDate = DateSerial(dYear, dMonth + 1, 0)

    GetNowLast = getDate

End Function
```
Vous pouvez appeler la fonction dans votre code comme:
```
Sub findLastDayOfMonth()

    lastDay = GetNowLast()

End Sub
```
Alternativement, et plus propre est possible de:
```
Function GetNowLast(inputDate as Date) as Date

    dYear = Year(inputDate)
    dMonth = Month(inputDate)

    getDate = DateSerial(dYear, dMonth + 1, 0)

    GetNowLast = getDate

End Function
```
Vous pouvez appeler cette fonction et lui passer un paramètre d'entrée.
```
Sub findLastDayOfMonth()

lastDay = GetNowLast(Now()) 'Or any other date you would like to know the last day of the month of.

End Sub
```
Voir aussi cette solution élégante par @KekuSemau
- Veuillez déclarer vos variables... à l'aide de Option Explicit en haut de chaque module va vous aider à vous rappeler de le faire! (Mais il est intéressant de noter que dMonth + 1 fonctionne même si dMonth+1=13.)
- Downvoting pour quelque chose qui est arbitraire semble être plutôt pédant, vous ne pensez pas? Malgré le fait que vous personnellement peut penser que c'est la meilleure méthode ou même qu'il puisse mieux la pratique, il est et reste arbitraire et au développeur de choisir si ou de ne pas utiliser les Option Explicit' déclaration. La question était de fournir une solution, non pas pour décrire l'ensemble de l'environnement dans lequel la solution doit être déployée.
InformationsquelleAutor mtholen
2

Je réalise que c'est un peu tard dans la conversation, mais il est déjà disponible en fonction de feuille de calcul qui donne à la fin de mois, date, EoMonth().

Le coller dans la Fenêtre d'exécution:
```
    ?Format(CDate(WorksheetFunction.EoMonth(Date, 0)), "dd")
```
Sera de retour le dernier jour du mois en se basant sur la date du jour.

Comme un UDF, il est logique de lui donner un Argument par défaut:
```
    Function LastDay(Optional DateUsed As Date) As String
        If DateUsed = Null Then DateUsed = Date
        LastDay = Format(CDate(WorksheetFunction.EoMonth(DateUsed, 0)), "dd")
        Debug.Print LastDay
    End Function
```
Si vous lui donnez des Arguments, assurez-vous qu'ils sont Date de Littéraux (c'est à dire Fermé avec #s)
```
LastDay(#3/10#)
Result: 31

LastDay #2/11/2012#
Result: 29 '(A leap Year)
```
Noter la sortie Type de Données est Chaîne (pas Date) et que le format de la date peut être modifiée en fonction des besoins (Ex: "mm/dd/yyyy" au lieu de "dd").

Si le Date Type de Données est nécessaire, utiliser:
```
Function LastDay(Optional DateUsed As Date) As Date
    If DateUsed = 0 Then DateUsed = Date
    LastDay = WorksheetFunction.EoMonth(DateUsed, 0)
    Debug.Print CDate(LastDay)
End Function
```
J'espère que ça aide quelqu'un.
- le titre de la question dit que c'est pour MS-Access, VBA, Excel pas.
InformationsquelleAutor OTA-SAN

Sub Worksheet_SelectionChange(ByVal Target As Range)

   Dim d1 As String

   Set Rng = Range("A2")
   d1 = Range("a2").Value2 'put a date in A2 Formatted as date(cell format)

   Dim years
   Dim months
   Dim end_month
   years = year(d1)
   months = month(d1)

   end_month = Day(DateSerial(years, months + 1, 1 - 1)) 'add one month and subtract one day from the first day of that month

   MsgBox CStr(end_month), vbOKOnly, "Last day of the month"


End Sub

Vous devez ajouter une explication de la façon dont votre code résout le problème mentionné dans la question.

InformationsquelleAutor Bill

0

Dans Access VBA, vous pouvez appeler Excel EOMonth fonction de feuille de calcul (ou presque tout de Excel feuille de calcul les méthodes de) est par la liaison à une application Excel objet et un WorksheetFunction de l'objet, ce qui peut être accompli de plusieurs façons.

Appelant les fonctions d'Excel avec un Retard Lié objet

Le plus court de la méthode à partir d'Access VBA est avec une seule ligne de code à l'aide d'un objet tardive. Cet exemple renvoie la date du dernier jour du mois en cours:
```
MsgBox CreateObject("Excel.Application").WorksheetFunction.EOMonth(Now(), 0)
```
Une méthode plus détaillée, en fonction:
```
Function eoMonth_LateBound(dt As Date) As Date
  Dim xl As Object
  Set xl = CreateObject("Excel.Application")
  eoMonth_LateBound = xl.WorksheetFunction.eomonth(dt, 0)
  Set xl = Nothing
End Function
```
Un problème avec la fin des références liées est que VBA prend une seconde pour lier l'objet à chaque fois que la fonction est appelée. Ceci peut être évité en utilisant une liaison anticipée.

Appelant les fonctions d'Excel avec un objet Lié au plus Tôt

Si la fonction est d'être utilisé à plusieurs reprises, il est plus efficace pour aller avec la Liaison Anticipée et de conserver l'objet entre les appels, par exemple:
- Aller Outils > Références et ajouter une référence à "Microsoft Excel x.xx Object Library" (utiliser quel que soit le nouveau numéro de version, c'est que vous avez installé).
- Ajouter ce code dans un nouveau module:
```
Option Compare Database
Option Explicit

Dim xl As Excel.Application

Function eoMonth_EarlyBound(dt As Date) As Date
  If xl Is Nothing Then Set xl = New Excel.Application
  eoMonth_EarlyBound = xl.WorksheetFunction.eomonth(dt, 0)
End Function

Sub demo()
  MsgBox eoMonth_EarlyBound(Now())
  MsgBox eoMonth_EarlyBound("4/20/2001")
End Sub
```
La création d'un WorksheetFunction objet

Si Excel fonctions de feuille de calcul doivent être utilisés beaucoup tout au long de votre code, vous pouvez même créer un WorksheetFunction objet de simplifier les appels. Par exemple, ce pourrait être un moyen simple de joindre plusieurs chaînes avec TEXTJOIN, ou d'obtenir une réponse à partir d'une API avec WEBSERVICE:
```
Sub Examples()
'requires reference: "Microsoft Excel x.xx Object Library"
  Dim xl As Excel.Application, wsf As Excel.WorksheetFunction
  Set xl = New Excel.Application
  Set wsf = xl.WorksheetFunction

  'use EOMONTH to return last date of current month
  Debug.Print CDate(wsf.eomonth(Now(), 0))

  'use WEBSERVICE return your current IP address from a free JSON API
  Debug.Print wsf.WebService("https://api.ipify.org")

  'use TEXTJOIN to implode a bunch of values
  Debug.Print wsf.TextJoin(" & ", True, "join", "this", , "and", , "that", "too")

  'always tidy up your mess when finished playing with objects!
  Set wsf = Nothing
  Set xl = Nothing
End Sub
```
_{Notez que ces fonctions peuvent nécessiter des Excel 2016+ ou Excel 365 (aka: la Bibliothèque d'Objets 16.0+.)}

InformationsquelleAutor ashleedawg

Vous devez vous connecter pour publier un commentaire.

Appelant les fonctions d'Excel avec un Retard Lié objet

Appelant les fonctions d'Excel avec un objet Lié au plus Tôt

La création d'un WorksheetFunction objet

La création d'un `WorksheetFunction` objet