VBA, ADO.De connexion et les paramètres de requête

J'ai excel VBA script:

Set cоnn = CreateObject("ADODB.Connection")
conn.Open "report"
Set rs = conn.Execute("select * from table" )

Script fonctionne très bien, mais je veux ajouter un paramètre. Par exemple, " où (parentid = myparam)", où myparam placé à l'extérieur de la chaîne de requête. Comment puis-je le faire?

Bien sûr, je peux modifier la chaîne de requête, mais je ne pense pas très sage.

InformationsquelleAutor Alexey | 2012-04-27

ado vba

40

Vous devez utiliser un ADODB.Objet de commande que vous pouvez ajouter des paramètres à. Voici en gros ce qui ressemble à
```
Sub adotest()

    Dim Cn As ADODB.Connection
    Dim Cm As ADODB.Command
    Dim Pm As ADODB.Parameter
    Dim Rs as ADODB.Recordset

    Set Cn = New ADODB.Connection
    Cn.Open "mystring"
    Set Cm = New ADODB.Command
    With Cm
        .ActiveConnection = Cn
        .CommandText = "SELECT * FROM table WHERE parentid=?;"
        .CommandType = adCmdText

        Set Pm = .CreateParameter("parentid", adNumeric, adParamInput)
        Pm.Value = 1

        .Parameters.Append Pm

        Set Rs = .Execute
    End With

End Sub
```
Le point d'interrogation dans le CommandText est l'espace réservé pour le paramètre. Je crois, mais je ne suis pas positif, que l'ordre de vous Ajouter les paramètres doivent correspondre à l'ordre des questions de marques (quand vous avez plus d'un). Ne soyez pas dupe que le paramètre est appelé "parentid" parce que je ne pense pas que l'ADO se soucie de l'autre nom que pour l'identification.
- Merci, vous code workfs fine 🙂
- Je crois que vous avez raison sur l'ordre des paramètres. Cette trébuché moi quand je suis venu à partir de C# .Net puis codés VBScript.
- Ou vous pouvez simplement.. .CommandText = "SELECT * from table where parentid=" & myparam & ";"
- cela va à l'encontre de l'objectif de l'utilisation de requêtes paramétrées. Utiliser la concaténation de variables contenant des userinput de données pour construire des chaînes de requête SQL est une mauvaise pratique. (Parce que si myparam = "parentid;SELECT * from userpasswords", ou si la connexion de l'utilisateur a des privilèges d'écriture: myparam ="parentid;insert into userpasswords..." ou tout de même à être trolly, myparam="parentid;delete from table")
- Des Injections SQL oui. Dans ma pratique, j'ai utilisé PHP pour filtrer les.
- Pourtant, vous n'avez pas mentionné que avec votre commentaire, laissant ainsi le danger que quelqu'un pourrait utiliser votre méthode sans le savoir sur les Injections SQL. C'est pas une bonne pratique pour faire de la chaîne concat pour les requêtes, même si vous en quelque sorte filtré le code dangereux (ce dont je doute fortement).
InformationsquelleAutor Dick Kusleika
6

Autre exemple de retour d'une commande à partir d'une fonction:
```
Function BuildCommand(conn As ADODB.Connection) As ADODB.Command
    Dim cmd As ADODB.Command
    Set cmd = New ADODB.Command
    cmd.ActiveConnection = conn
    cmd.CommandType = adCmdText
    cmd.Parameters.Append cmd.CreateParameter("@name", adVarChar, adParamInput, 255, "Dave")
    cmd.CommandText = "SELECT * FROM users WHERE name = @name;"
    Set BuildCommand = cmd
End Function
```
Un couple de choses à noter:
1. Lors de l'utilisation de adVarChar type de données, la taille de l'argument de cmd.CreateParameter (p. 255) est nécessaire. Ne pas les fournir, il en résulte une erreur d'exécution 3708: définie par l'Application ou par l'objet défini d'erreur, comme indiqué dans le la documentation:
  
  Si vous spécifiez une longueur variable de type de données dans l'argument de Type, vous devez passer un argument Size ou de définir la Taille de la propriété de l'objet Parameter avant d'ajouter à la collection de Paramètres; sinon, une erreur se produit.
2. Si le cmd.ActiveConnection propriété est définie lors de la cmd.CommandText est défini, et cmd.CommandText contient des paramètres nommés, cmd.Parameters sera remplie en conséquence. L'appel de cmd.Parameters.Append par la suite pourrait entraîner des doublons. Par exemple:
```
cmd.ActiveConnection = conn
cmd.CommandType = adCmdText
Debug.Print cmd.Parameters.Count ' 0

cmd.CommandText = "SELECT * FROM users WHERE name = @name;"
Debug.Print cmd.Parameters.Count ' 1

cmd.Parameters.Append cmd.CreateParameter("@name", adVarChar, adParamInput, 255, "Dave")
Debug.Print cmd.Parameters.Count ' 2
```
  Je crois que c'est ce que l'on entend dans le la documentation, ce qui est légèrement inexact:
  
  Si le Prêt de la propriété de l'objet de Commande est défini sur True et que la Commande objet est lié à une connexion ouverte lorsque vous définissez la propriété CommandText, ADO prépare la requête (c'est une forme compilée de la requête qui est stockée par le fournisseur) lorsque vous appelez l'Exécuter ou Ouvrir méthodes.
  
  Comme une solution de contournement, vous pouvez soit définir cmd.CommandText ou cmd.ActiveConnection après ajout de paramètres.
- chaque fois que j'essaie de faire cela, j'ai toujours erreur d'exécution Must Declare the scalar variable "@name"
InformationsquelleAutor David Kennedy

Vous devez vous connecter pour publier un commentaire.