VBA boucle dans toutes les séries dans tous les tableaux

Je vais avoir un problème avec la boucle par le biais de plusieurs cartes dans mon code VBA. Je suis à 99,7% sûr que c'est vraiment facile et rapide à fixer, mais mon cerveau ne fonctionne pas aujourd'hui.

Je veux le code d'une boucle sur chaque graphique sur le ActiveSheet, et pour chaque série de données que le tableau contient je le veux pour ajouter la dernière valeur de la série. Dans mon exemple, j'ai 9 cartes, chacune avec 3 séries en eux (liée au changement, certains ont 2 mais je m'égare).

J'ai le code suivant

Sub AddLastValue()
Dim myChartObject As ChartObject
Dim myChart As Chart
Dim mySrs As Series
Dim myPts As Points

With ActiveSheet
For Each myChartObject In .ChartObjects
    For Each myChart In .Chart
        For Each mySrs In .SeriesCollection
            Set myPts = .Points
            myPts(myPts.Count).ApplyDataLabels Type:=xlShowValue
        Next
    Next
Next
End With

End Sub

Si je supprime le code de boucle et il suffit de faire une 

Set myPts = ActiveSheet.ChartObjects(1).Chart. _
    SeriesCollection(1).Points
myPts(myPts.Count).ApplyDataLabels type:=xlShowValue

Puis il travaille pour le graphique et la série, donc je suis positif, il est la boucle que je suis bien.

Quelqu'un pourrait-il me dire où je galère le code de boucle?

InformationsquelleAutor MagneTism | 2014-01-16
  1. 14

    Essayer de code suivant:

    Sub AddLastValue()
    Dim myChartObject As ChartObject
    Dim mySrs As Series
    Dim myPts As Points

    With ActiveSheet
        For Each myChartObject In .ChartObjects
            For Each mySrs In myChartObject.Chart.SeriesCollection
                Set myPts = mySrs.Points
                myPts(myPts.Count).ApplyDataLabels Type:=xlShowValue
            Next
        Next
    End With

End Sub
    • Et il fonctionne comme un charme 🙂 j'ai essayé une solution similaire pour cela que le Tableau de variable, mais je crois que je vois maintenant que c'est le deuxième, le mySrs Dans .SeriesCollection, qui a tout fait foiré car l'ajout de la myChartObject.Le graphique.SeriesCollection, a fait le tour. Merci!!!!
    • Vous êtes les bienvenus) fondamentalement, le problème était que des lignes comme For Each mySrs In .SeriesCollection. Dans With déclaration signifie ActiveSheet.SeriesCollection, (mais pas ActiveSheet.ChartObjects.Chart.SeriesCollection)
    • Aaah, ça fait du sens. Je ne suis pas encore au travers de toutes les Lynda cours encore et j'ai donc beaucoup à apprendre ^^
    InformationsquelleAutor Dmitry Pavliv
  2. 1

    Pas travailler pour des valeurs vides.

    Ce code trouver dernier n'est pas vide de la valeur et ajoute ensuite de l'étiquette.

    For Each mySrs In myChartObject.Chart.SeriesCollection
      Set myPts = mySrs.Points
      Dim i As Integer
      i = myPts.Count
      Do Until i < 2 Or mySrs.Values(i) <> ""
        i = i - 1
      Loop
      myPts(i).ApplyDataLabels Type:=xlShowValue
Next
    InformationsquelleAutor Andrzej Jackiewicz