VBA Excel: Comment Étendre une Gamme Donnée une Sélection Actuelle

Je veux faire quelque chose comme:

E18-(1,1) &":" &E18+(1,1)

Mon intention est de garder la sélection de la gamme E18 (valeur = B) et étendre la sélection à D16:F20.

Si j'ai une plage de la cellule de E18 et je veux étendre la gamme de D16:F20, comment puis-je faire cela?

Qu'entendez-vous par étendre. Si vous connaissez déjà votre gamme ex D16:F20 alors pourquoi ne pas l'utiliser directement pour le sélectionner?
C'est un exemple, supposons que si je connais une plage de cellules peut être n'importe où dans la feuille. Et je veux faire une sélection qui comprennent les environs de cette cellule. Je tiens donc à exprimer/s'étendre.
ok il n'y en aura qu'une seule cellule pour commencer?
Oui, un seul. Qui est l'adresse d'une cellule A1, B3, etc
J'ai essayé de redimensionner mais il ne semble pas fonctionner

OriginalL'auteur NCC | 2012-05-21

Range(Cells(WorksheetFunction.Max(1, Selection.Row - 1), _
      WorksheetFunction.Max(1, Selection.Column - 1)), _
      Cells(WorksheetFunction.Min(Selection.Worksheet.Rows.Count, _
      Selection.Row + 1), _
      WorksheetFunction.Min(Selection.Worksheet.Columns.Count, _
      Selection.Column + 1))).Select

upd: merci Siddharth Déroute pour le formatage de mon msg

OriginalL'auteur NDavid RU

Tu veux dire?

SYNTAXE

ExpandRange [Gamme], [Nombre de Col sur la gauche], [Nombre de Lignes sur le Dessus], [Nombre de Col sur la droite], [Nombre de Lignes vers le bas]

Sub Sample()
    Debug.Print ExpandRange(Range("B5"), 1, 1, 1, 1)            '<~~ $A$4:$C$6
    Debug.Print ExpandRange(Range("A1"), 1, 1, 1, 1)            '<~~ Error
    Debug.Print ExpandRange(Range("XFD4"), 1, 1, 1, 1)          '<~~ Error
    Debug.Print ExpandRange(Range("XFD1048576"), 1, 1, 1, 1)    '<~~ Error
    Debug.Print ExpandRange(Range("E5"), 1, 1, 1, 1)            '<~~ $D$4:$F$6
End Sub

Function ExpandRange(rng As Range, lft As Long, tp As Long, _
rt As Long, dwn As Long) As String
    If rng.Column - lft < 1 Or _
       rng.Row - tp < 1 Or _
       rng.Column + rt > ActiveSheet.Columns.Count Or _
       rng.Row + dwn > ActiveSheet.Rows.Count Then
        ExpandRange = "Error"
        Exit Function
    End If

    ExpandRange = Range(rng.Offset(-1 * tp, -1 * lft).Address & ":" & _
                        rng.Offset(dwn, rt).Address).Address
End Function

Merci pour la réponse et oui, c'est ce que je cherchais.
+1 Bien Fait 🙂

OriginalL'auteur Siddharth Rout

7

Voici le simple code que j'utilise pour redimensionner une sélection existante.
```
Selection.Resize(Selection.Rows.Count + 5, Selection.Columns.Count + 50).Select
```
Cela va ajouter 5 pour le nombre de lignes et de 50 pour le nombre de colonnes. S'adapter à vos besoins.

OriginalL'auteur g3t_
3

Vous pouvez utiliser Application.WorksheetFunction.Offset() qui est plus riche que VBA Offset et fait tout le requis par la question.

Je pense que c'est ce que Siddharth Déroute ExpandRange, sans la nécessité d'une UDF.

Juste petite question - je pense que je pourrais juste poster ici - comment puis-je ajouter cette gamme à un contrôle listbox (les valeurs). J'ai essayé <code>Listbox1.Liste = ExpandRange("A1",0,0,1,1)</code> j'ai aussi essayé de définir une variante, mais elle renvoie l'erreur: impossible de définir la Propriété List.
Que voulez-vous faire? Affecter les valeurs de la plage à une listbox?
Oui, Siddharth Déroute. Il semble que je n'ai pas connu ce concept bien parce que j'ai parfois cela fonctionne, parfois, je ne suis pas.
J'ai essayé mais j'ai toujours eu n'a pas Pu définir la Liste des Biens lorsque j'ai utilisé <code>.Liste</code>

OriginalL'auteur Patrick Honorez

Au lieu de retourner une adresse absolue, je la modification de la syntaxe ci-dessus pour retourner une plage. Le crédit va à Siddharth Déroute = )

Function ExpandRG(rng As Variant, lft As Long, tp As Long, rt As Long, dwn As Long) _
 As Range
 Set ws = rng.Parent
If rng.Column - lft < 1 Or _
   rng.Row - tp < 1 Or _
   rng.Column + rt > ActiveSheet.Columns.Count Or _
   rng.Row + dwn > ActiveSheet.Rows.Count Then
        MsgBox "Out of range"
        Exit Function
End If

 Set rng = ws.Range(rng.Offset(-1 * tp, -1 * lft).Address & ":" & _
                    rng.Offset(dwn, rt).Address)                        
End Function

Sub aa()
Dim ori_add, O_add, New_add As Range
Set ori_add = Range("B2")
Set O_add = ori_add

Call ExpandRG(ori_add, 1, 1, 1, 1)
Set New_add = ori_add

MsgBox "Original address " & O_add.Address & ", new address is" & New_add.Address
End Sub

OriginalL'auteur EC_DD

Vous devez vous connecter pour publier un commentaire.