VBA Excel filtrage par la valeur de la cellule d'une autre feuille et en utilisant la formule

Donc j'ai compris la première partie de ma question - comment filtrer par des valeurs sur d'autres feuilles de calcul, le code que j'ai utilisé est indiqué ci-dessous. Cependant, je ne peux pas comprendre ce que je fais de mal avec la "moyenne" de la formule de partie

Sub Filtering_Average()
'
' Filtering Macro


'Turn off filtering that has already been applied
Worksheets("Sold Homes").Cells.AutoFilter


Worksheets("Sold Homes").Range("A1").Select

Dim zipcode As Range, bedroom As Range, soldprice As Range
  Set zipcode = Worksheets("Enter Info").Range("B2")
  Set bedroom = Worksheets("Enter Info").Range("K2")
'defining "soldprice" as range that starts in R2 and continues until a blank cell, on sheet "Sold Homes"
    Set soldprice = Worksheets("Sold Homes").Range("R2",     Range("R1").End(xlDown))

'Filtering data in Sold Homes sheet based on zip code and Bedroom count
    ActiveSheet.Range("$A$1:$T$15001").AutoFilter Field:=1, Criteria1:=zipcode
    ActiveSheet.Range("$A$1:$T$15001").AutoFilter Field:=10, Criteria1:=bedroom

'go to the sheet "Enter Info"
Worksheets("Enter Info").Select
'Select cell "AM16"
Range("am16").Select
'Calculate the average of the cells defined by "soldprice"
ActiveCell.Formula = "=Average(soldprice)"


'
End Sub

Question 1 = répondit
J'ai un classeur avec plusieurs feuilles, mais les deux feuilles, je suis principalement concernés sont la Feuille("Entrez l'Info") et la Feuille("Vendu des Maisons")

Comme vous l'avez deviné la "vendu des maisons", une feuille qui contient des données sur les maisons qui ont été vendues dans ma région. J'ai des données sur 15 000 foyers, chacune dans sa propre ligne. J'ai besoin de filtrer les données par 2 conditions:

1er j'ai besoin de filtrer les 15 000 lignes par le code postal. Le code postal est tenue sur "enter info" de la feuille dans la cellule B2. Le code postal se trouve dans la Champ = 1 sur la "Vendu des Maisons" de la feuille.

2e je besoin de préciser la maintenant de données filtrées par le nombre de chambres dont les maisons ont. Le nombre de chambres à coucher qu'une maison est tenue sur le Saisissez les informations de la feuille dans la cellule K2. Le nombre de chambres à coucher se trouve dans la champ = 10 sur la "Vendu des Maisons" de la Feuille.

Je sais comment écrire la macro VBA pour faire un simple filtre par code postal, puis filtrer par un certain nombre de chambres à coucher mais j'ai besoin de la macro de s'adapter et de filtre en fonction de ce que je place dans la cellule B2 et K2 sur mon "enter info" de la feuille.

Question 2

Après le filtrage des données sur le "vendu des maisons" feuille j'ai besoin de trouver le prix de vente moyen pour les maisons qui sont maintenant à l'affiche. Les données pour le prix de Vente de la maison est trouvé dans la colonne "R" de "vendu des maisons" de la feuille. La plus grande complication, c'est que le nombre de maisons retourné après que les deux conditions de filtrage ont été appliquées varie.

Ex: code postal 11111, nombre de chambres = 3, les rendements de 50 maisons. Donc, je voudrais que la moyenne de ceux de 50 maisons

MAIS

Zipvode 22222, nombre de chambres = 4, renvoie 36 maisons.

J'aurais besoin d'un moyen de sélectionner uniquement les cellules qui sont dans la colonne de R qui ont une valeur en eux (Non Vide) pour ma fonction moyenne. Si je sélectionne toute la colonne R-je obtenir la moyenne pour toutes les maisons de 15,000 maison, car le filtrage fait la même chose à cacher les cellules qui ne sont pas dans les paramètres sélectionnés.

Merci beaucoup à l'avance. Désolé, je n'ai pas poster mon code la 1ère fois.

Alors, quelle est votre question? Vous avez obtenu coincé avec votre programme? Merci de poster votre code, et être plus précis sur la question.
Mon Problème est que je ne sais pas comment écrire la macro pour faire référence à une cellule d'une autre feuille que la cellule qui contient la valeur pour le code postal doit être filtré. Le même problème s'applique à la cellule qui contient la valeur pour le nombre de chambres à coucher. Je vais poster mon code une fois que je suis de retour sur mon ordinateur de travail. Désolé à ce sujet.

InformationsquelleAutor Snook55 | 2017-01-16

0

cela devrait le faire:
```
Option Explicit

Sub Filtering_Average()
    '
    ' Filtering Macro
    '
    Dim zipcode As Range, bedroom As Range, soldprice As Range

    With Worksheets("Enter Info")
        Set zipcode = .Range("B2")
        Set bedroom = .Range("K2")
        Set soldprice = .Range("AM16")
    End With

    With Worksheets("Sold Homes")
        With .Range("A1:T" & .Cells(.Rows.count, "R").End(xlUp).Row)
            .AutoFilter 'Turn off any previous filtering
            .AutoFilter Field:=1, Criteria1:=zipcode
            .AutoFilter Field:=10, Criteria1:=bedroom
            If Application.WorksheetFunction.Subtotal(103, .Resize(, 1)) > 1 Then soldprice.Value = WorksheetFunction.Average(.Resize(.Rows.count - 1, 1).Offset(1, 17).SpecialCells(xlCellTypeVisible))
        End With
        .AutoFilterMode = False
    End With
End Sub
```
- Hey merci beaucoup pour votre aide. Je n'ai pas eu la chance de l'essayer encore. Je vais vous laisser savoir si il fonctionne dès que, je reviens à mon ordinateur de travail. Pourquoi avez-vous utilisé le/End avec à l'étoile de chaque étape? Je n'ai jamais eu à l'utiliser et ne comprends pas la logique.
- La "Avec la Fin Avec" bloc permet de supposer une référence d'objet (dans les deux cas, un objet de feuille de calcul) et l'accès de ses membres (propriétés et méthodes) par le biais d'un simple point (.). Ceci à la fois pour réduire les accès à la mémoire et en tapant charge
- Je vous remercie encore. Cela prend tout son sens. Pourriez-vous également expliquer la logique de l'instruction if?
- Si une cellule est filtré autres que dans la ligne d'en-tête puis d'écrire dans soldprice plage de la moyenne de toutes les filtrée de cellules de la 18e colonne (17 colonne de décalage à partir de la 1re) référencé de gamme. Cela fonctionne?
- cela a parfaitement fonctionné. Je souhaite juste que j'ai compris comment. Je vous remercie pour toute l'aide que. Est-il possible de vous contacter afin de comprendre comment le code fonctionne? Je ne voit pas d'un contact ou par message privé bouton mais je suis nouveau ici et pourrait être absente.
- Vous êtes les bienvenus. Il n'y a pas de message privé ici. La meilleure façon de comprendre un code à l'étape par le biais de: 1) placez votre curseur dans n'importe quelle déclaration de la "main" macro 2) appuyez sur la touche F8 pour la macro de démarrage 3) la première instructions exécutables obtient en surbrillance et en appuyant sur la touche F8, vous reçoit à la suivante 4) tandis que "dans" un état, vous pouvez interroger les variables pertinentes valeurs par le biais de la "Fenêtre" (CTRL + G pour la faire sortir) en tapant des choses telles que ?zipcode et en appuyant sur retour. Vous pouvez également utiliser les "Habitants" de la fenêtre (cliquez sur Affichage -> Habitants) à la requête de toutes les variables d'état. apprendre VBA de débogage!
InformationsquelleAutor user3598756

Vous devez vous connecter pour publier un commentaire.