VBA Fonction Définie par l'Utilisateur pour “Concaténer Si” par les lignes

J'ai des données de savoir si ou non un "service" (par exemple, Enquête sur les Oiseaux) a été réalisée pour un site en particulier avec un "oui" ou "non" pour chaque service.

E. G.

  • La colonne A contient les noms de site, disons A, B, C, D et E avec le titre "Nom du Site" en A1 puis "A" dans la cellule A2, etc.
  • La colonne B contient "Enquête sur les Oiseaux" dans la cellule B1, puis soit un "oui" ou "non" pour B2-B6.
  • Idem pour d'autres services dans les colonnes C, D et E, permet de dire "chauve-souris de l'Enquête", "LVI" et "Registre Foncier", respectivement.
  • En F je veux concaténer les noms de service pour chaque ligne contenant un "oui". E. G. permet de dire que les valeurs de B2,C2,D2 et E2 sont "oui", "oui", "non" et "oui", je veux F2 à contenir de l'Enquête sur les Oiseaux, chauve-souris de l'Enquête.

Ce que je comprends il n'y a pas des fonctions natives dans excel qui peuvent le faire, et j'ai donc essayé de créer une fonction définie par l'utilisateur dans VBA. J'ai essayé deux approches

  • l'une basée sur l'alimentation de deux gammes (les noms de colonne et de la ligne du "oui/non") dans l'UDF, puis en combinant ces éléments dans un tableau à appliquer une certaine forme de critères de recherche
  • et un autre retour de lettre de colonne d'un oui/non seulement, puis en sélectionnant dans la colonne des noms de colonne en fonction de la lettre.

Je n'ai pas été en mesure d'obtenir pour le travail bien. Notez qu'à la fin, j'ai besoin de créer une fonction qui fonctionne pour un nombre variable de services, ils ne seront pas pré-défini comme dans cet exemple.

Des suggestions?

Merci beaucoup à l'avance.

Serait utile d'ajouter votre tentative de code à votre question - même si elle n'a pas assez de travail.
Quelques questions... (1) compte tenu de votre exemple " E. G. permet de dire que les valeurs de B2,C2,D2 et E2 sont "oui", "oui", "non" et "oui", je veux F2 à contenir de l'Enquête sur les Oiseaux, chauve-souris de l'Enquête." - Faut-que dire "Enquête sur les Oiseaux, chauve-souris de l'Enquête, le Registre Foncier"? (2) Êtes-vous limité à "oui" / "non" ou peut-il être (1 / 0) ou (Vrai / Faux)?
Oups, désolé, oui vous avez raison, il convient en effet de dire "Enquête sur les Oiseaux, chauve-souris de l'Enquête, le Registre Foncier". Il pourrait également être modifié pour un autre binaire condition, (1/0) ou (Vrai/Faux) comme vous le suggérez.
L'affichage d'une solution maintenant....
TEXTJOIN pour xl2013 avec les critères

OriginalL'auteur vbastrangledpython | 2014-03-25

  1. 7

    Basé sur ce que vous cherchez, j'ai trouvé cette fonction il y a longtemps et ça a un charme:

    Function ConcatenateIf(CriteriaRange As Range, Condition As Variant, _
        ConcatenateRange As Range, Optional Separator As String = ",") As Variant
    Dim i As Long
    Dim strResult As String
    On Error GoTo ErrHandler
    If CriteriaRange.Count <> ConcatenateRange.Count Then
        ConcatenateIf = CVErr(xlErrRef)
        Exit Function
    End If
    For i = 1 To CriteriaRange.Count
        If CriteriaRange.Cells(i).Value = Condition Then
            strResult = strResult & Separator & ConcatenateRange.Cells(i).Value
        End If
    Next i
    If strResult <> "" Then
        strResult = Mid(strResult, Len(Separator) + 1)
    End If
    ConcatenateIf = strResult
    Exit Function
ErrHandler:
    ConcatenateIf = CVErr(xlErrValue)
End Function

    Donnée à votre question, il serait utilisé comme suit:

    =ConcatenateIf(B2:E2,"yes",$B$1:$E$1,", ")

    Initiale de crédit va à ce lien.

    Espère que cela fait l'affaire!!

    Cela a fonctionné parfaitement, merci beaucoup!
    belle réponse et félicitations pour 5k:)

    OriginalL'auteur John Bustos