VBA impossible de supprimer les espaces

Trim supprime les espaces supplémentaires au début et à la fin, pas au milieu d'une chaîne de caractères.

Function CleanSpace(ByVal strIn As String) As String
    strIn = Trim(strIn)

  ' //Replace all double space pairings with single spaces
    Do While InStr(strIn, "  ")
        strIn = Replace(strIn, "  ", " ")
    Loop

    CleanSpace = strIn
End Function

De ici.

PS. Ce n'est pas le moyen le plus efficace pour supprimer les espaces. Je ne voudrais pas l'utiliser sur de nombreux, de très longues chaînes ou dans une boucle serrée. Il pourrait être adapté à votre situation.

OriginalL'auteur Mitch Wheat

Sont tous vos autres fonctions de laisser des espaces derrière?

Obtenir CleanUltra!

CleanUltra supprime tous les espaces et les caractères non-imprimables, y compris les espaces laissés par d'autres fonctions!

J'espère que vous trouverez ce utile. Toutes les améliorations sont les bienvenus!

Function CleanUltra( _
       ByVal stringToClean As String, _
       Optional ByVal removeSpacesBetweenWords As Boolean = False) _
        As String
' Removes non-printable characters and whitespace from a string


' Remove the 1 character vbNullChar. This must be done first
'  if the string contains vbNullChar
    stringToClean = Replace(stringToClean, vbNullChar, vbNullString)

    ' Remove non-printable characters.
    stringToClean = Application.Clean(stringToClean)

    ' Remove all spaces except single spaces between words
    stringToClean = Application.Trim(stringToClean)

    If removeSpacesBetweenWords = True Then _
       stringToClean = Replace(stringToClean, " ", vbNullString)

    CleanUltra = stringToClean
End Function

Voici un exemple de son utilisation:

Sub Example()
    Dim myVar As String
    myVar = " abc d e  "

    MsgBox CleanUltra(myVar)
End Sub

Voici un test que j'ai couru pour vérifier que la fonction réellement supprimé tous les espaces. vbNullChar a été particulièrement retors. J'ai dû mettre de la fonction de l'enlever en premier, avant la CLEAN et TRIM fonctions ont été utilisées pour arrêter de supprimer tous les caractères après le vbNullChar.

Sub Example()
    Dim whitespaceSample As String
    Dim myVar As String

' Examples of various types of whitespace
'  (vbNullChar is particularly devious!)
    whitespaceSample = vbNewLine & _
                       vbCrLf & _
                       vbVerticalTab & _
                       vbFormFeed & _
                       vbCr & _
                       vbLf & _
                       vbNullChar

    myVar = "     1234" & _
            whitespaceSample & _
            "     56      " & _
            "789     "

    Debug.Print "ORIGINAL"
    Debug.Print myVar
    Debug.Print "Character Count: " & Len(myVar)


    Debug.Print
    Debug.Print "CLEANED, Option FALSE"


    Debug.Print CleanUltra(myVar)
    Debug.Print CleanUltra(myVar, False)
    '   Both of these perform the same action.  If the optional parameter to
    '   remove spaces between words is left blank it defaults to FALSE.
    '   Whitespace is removed but spaces between words are preserved.
    Debug.Print "Character Count: " & Len(CleanUltra(myVar))


    Debug.Print
    Debug.Print "CLEANED, Option TRUE"

    Debug.Print CleanUltra(myVar, True)
    '   Optional parameter to remove spaces between words is set to TRUE.
    '   Whitespace and all spaces between words are removed.
    Debug.Print "Character Count: " & Len(CleanUltra(myVar, True))

End Sub

OriginalL'auteur ChrisB

Lorsque vous appelez Trim() VBA est en fait l'appel des Chaînes de caractères.Trim(). Cette fonction ne supprime attaque et de fuite des espaces. Pour supprimer les espaces à l'intérieur d'une chaîne, utilisez

Application.Trim()

OriginalL'auteur Excel Developers

Parfois, ce qui semble être un espace n'est pas un espace, mais un personnage qui ne peut pas être affichée.
Utiliser la fonction ASC pour obtenir la valeur de l'entier du personnage. Ensuite, utilisez le code suivant:

Function CleanSpace(ByVal StrIn As String) As String
    StrIn = Trim(StrIn)

  ' Searches string from end and trims off excess ascii characters

  Dim StrLength As Integer
  Dim SingleChar As Integer
  Dim StrPosition As Integer

  SingleChar = 1

  StrLength = Len(StrIn)
  StrPosition = StrLength - 1

    Do Until Asc(Mid(StrIn, StrPosition, SingleChar)) <> 0
        StrPosition = StrPosition - 1
    Loop
  StrIn = Mid(StrIn, 1, StrPosition)

End Function

OriginalL'auteur Brian Stevenson

Je sais que cette question est vieux, mais je veux juste partager ma solution sur la façon de traiter et de corriger ce problème.

Peut-être vous pourriez vous demander pourquoi parfois TRIM function ne fonctionne pas, rappelez-vous qu'il sera seulement supprimer les espaces et les espaces sont équivalentes à ASCII 32. Donc, si ces ASCII 13 ou ASCII 10 existe dans le Début ou fin de votre chaîne de valeur TRIM function ne fonctionnera pas sur elle.

Function checkASCIItoBeRemoved(myVal) As String

Dim temp As String
temp = Replace(Trim(myVal), Chr(10), Empty)
temp = Replace(temp, Chr(13), Empty)
checkASCIItoBeRemoved = temp

End Function

Avec ce code, il fonctionne pour moi, d'ailleurs si cela pourrait ne pas fonctionner sur votre côté puis essayez de vérifier l' ASCII de vous de la chaîne de valeur, car il pourrait avoir une autre invisible char spécial qui pourrait ne pas couverte sur mon code pour remplacer sur elle, de bien vouloir nous ajouter pour le travail.

Veuillez voir référence pour certains invisible char spécial.

OriginalL'auteur davinceleecode