VBA méthode de l'aire de répartition de l'objet' _Worksheet échec de variables utilisées dans la gamme de la déclaration de

J'obtiens le message d'erreur suivant: Method range of object _worksheet failed lorsque vous essayez de sélectionner une plage dans excel à l'aide de variables, comme la longueur de la gamme.

Ci-dessous est un extrait de mon code:

Private Function copyAmount(startRange As Integer, endRange As Integer)
    Dim startRng As String
    Dim endRng As String

    startRng = "A" & Str(startRange)
    endRng = "A" & Str(endRange)

    activateBook ("book2.xlsm")
    Set rng = Range(startRng, endRng)
    Workbooks("book2.xlsm").Sheets(1).Range(rng).Select
    Selection.Copy
    activateBook ("Book1.xlsm")
    Range("D3").Select
    Selection.PasteSpecial Paste:=xlPasteValues, _
    Operation:=xlNone, SkipBlanks:=False, Transpose:=False
End Function

Toute aide serait grandement appréciée.

L'erreur que vous avez n'arrivera pas si vous remplacez Range(rng).Select avec rng.Select (c'est-à - déjà un Range) en supposant que rng a été défini comme un Range variable dans MS Excel 2010.

OriginalL'auteur user1155383 | 2012-07-03

  1. 7

    Vous obtenez l'erreur parce que vous n'êtes pas entièrement de qualification de vos gammes. Aussi il n'est pas nécessaire d'activer un classeur à faire un copier coller 🙂 Aussi, vous n'avez pas besoin d'un Function pour cela. Utiliser un Sub

    Est-ce que vous essayez (non testé)?

    Private Sub copyAmount(startRange As Integer, endRange As Integer)
    Dim wbT As Workbook, wbO As Workbook
    Dim rng As Range

    Set wbT = ThisWorkbook
    Set wbO = Workbooks("book2.xlsm")

    Set rng = wbO.Sheets(1).Range("A" & startRange & ":" & "A" & endRange)
    rng.Copy

    '~~> Change Sheets(1) below to the relevant sheet
    wbT.Sheets(1).Range("D3").PasteSpecial Paste:=xlPasteValues, _
    Operation:=xlNone, SkipBlanks:=False, Transpose:=False
End Sub

    MODIFIER

    Sub, comme un Function de la procédure, est une procédure distincte qui peut prendre des arguments, effectuer une série d'instructions, et changer la valeur de ses arguments. Toutefois, un Sub procédure ne retourne pas une valeur comme une Function n'.

    Merci beaucoup, très utile !

    OriginalL'auteur Siddharth Rout

  2. 0

    Au lieu de Str, utilisez Cstr. Cela rendra votre travail de code, je suppose...

    OriginalL'auteur Trace

  3. 0

    Vous obtiendrez ce message d'erreur lorsque votre code est dans une feuille de calcul et non pas un module.

    OriginalL'auteur IndyThinker