VBA MSFORMS vs Contrôles - quel est la différence

Ajouter UserForm première. Puis dans VBA IDE appuyez sur la touche F2, le objet navigateur s'affiche. Dans le coin supérieur gauche est la zone de liste déroulante, sélectionnez MSForms. Dans la liste de classes, vous pouvez voir les classes qui appartient à MSForms bibliothèque d'objets.

Vous pouvez voir bouton de commande et Contrôle dans cette liste:

Pour déclarer une variable de type bouton de commande dans votre code:

Dim button1 As MSForms.CommandButton
Dim button2 As CommandButton

La variable button1 est de type bouton de commande de MSForms pour vous. Le bouton2 pourrait être votre propre classe définie dans votre Projet VBA ... mais si votre projet VBA ne contiennent pas de classe avec un tel nom, il sera considéré à partir de MSForms. Cependant si vous faites référence à un autre objet de la bibliothèque dire "MSFoo" qui contiendra la classe bouton de commande ainsi vous devrez les déclarer pleinement qualifié comme ceci:

Dim button1 As MSForms.CommandButton
Dim button2 As MSFoo.CommandButton

Pour déclarer une variable de type Contrôle dans votre code:

Dim controlObject As MSForms.Control

Utiliser une variable de type Contrôle, comme une sorte de classe de base pour les contrôles. E. g. pour enumarate collection de Contrôles:

For Each controlObject In Me.Controls
    Debug.Print VBA.TypeName(controlObject)
Next controlObject

Ou en tant que paramètre dans la fonction qui attend et pas seulement un seul type de contrôle:

Private Sub PrinControlName(ByRef c As MSForms.Control)
    Debug.Print c.Name
End Sub

Donc, en utilisant des noms pleinement qualifiés comme MSForms.Bouton de commande est en général approprite je pense. L'Utilisation De La Commande.Bouton de commande est erronée et ne compile pas jusqu'à ce que vous faites référence à un objet de la bibliothèque nommée "Contrôle" avec la classe bouton de commande.

EDIT:

Ici un exemple de créés localement classe avec le même nom comme MSForm.Bouton de commande:

Et comment TypeName et TypeOf de travail dans ce cas:

Option Explicit

Private m_buttonMsForms As MSForms.CommandButton
Private m_buttonLocal As CommandButton

Private Sub UserForm_Initialize()
    Set m_buttonMsForms = Me.Controls.Add( _
        "Forms.CommandButton.1", "testMsButton", True)
    Set m_buttonLocal = New CommandButton

    m_buttonLocal.Name = "testLocalButton"

    Debug.Print "We have two instances of two different button types: " & _
        m_buttonLocal.Name & " and " & m_buttonMsForms.Name

    ' Check instances with TypeName function
    ' TypeName function returns same results
    If VBA.TypeName(m_buttonMsForms) = VBA.TypeName(m_buttonLocal) Then
        Debug.Print "TypeName of both buton types returns same result"
    End If

    ' Check instances with TypeOf operator
    ' TypeOf doen't work with not initialised objects
    If m_buttonLocal Is Nothing Or m_buttonMsForms Is Nothing Then _
        Exit Sub

    ' TypeOf operator can distinguish between
    ' localy declared CommandButton type and MSForms CommandButton
    If TypeOf m_buttonLocal Is MSForms.CommandButton Then _
        Debug.Print "m_buttonLocal Is MSForms.CommandButton"

    If TypeOf m_buttonMsForms Is CommandButton Then _
        Debug.Print "m_buttonMsForms Is CommandButton"

    If TypeOf m_buttonLocal Is CommandButton Then _
        Debug.Print "m_buttonLocal Is CommandButton"

    If TypeOf m_buttonMsForms Is MSForms.CommandButton Then _
        Debug.Print "m_buttonMsForms Is MSForms.CommandButton"

End Sub

De sortie:

We have two instances of two different button types: testLocalButton and testMsButton
TypeName of both buton types returns same result
m_buttonLocal Is CommandButton
m_buttonMsForms Is MSForms.CommandButton

OriginalL'auteur dee