VBScript — à l'Aide d'erreur de manipulation

Je veux utiliser VBScript pour détecter les erreurs et la session (c'est à dire sur l'erreur "journal de quelque chose") puis reprendre la ligne suivante du script.

Par exemple,

On Error Resume Next 
"Faire L'Étape 1 
"Faire L'Étape 2 
"Faire L'Étape 3

Lorsqu'une erreur se produit lors de l'étape 1, je veux que ce journal d'erreur (ou d'effectuer d'autres fonctions personnalisées avec elle), puis le reprendre à l'étape 2. Est-ce possible? et comment puis-je mettre en œuvre?

EDIT: je Peux faire quelque chose comme cela?

On Error Resume myErrCatch 
"Faire l'étape 1 
"Faire l'étape 2 
"Faire l'étape 3 

myErrCatch: 
"journal d'erreur 
Resume Next

Dylan réponse est à peu près aussi bon que VB est dans la gestion des Erreurs département. C'est pourquoi j'ai toujours utilisé du Javascript quand je pourrais sortir avec elle.

InformationsquelleAutor apandit | 2008-10-01

error-handling vbscript

148

VBScript n'a aucune notion de lancer ou attraper des exceptions, mais le runtime fournit un objet Err global qui contient les résultats de la dernière opération effectuée. Vous devez explicitement vérifier si le Tre.Numéro de la propriété est non-zéro après chaque opération.
```
On Error Resume Next

DoStep1

If Err.Number <> 0 Then
  WScript.Echo "Error in DoStep1: " & Err.Description
  Err.Clear
End If

DoStep2

If Err.Number <> 0 Then
  WScript.Echo "Error in DoStop2:" & Err.Description
  Err.Clear
End If

'If you no longer want to continue following an error after that block's completed,
'call this.
On Error Goto 0
```
Le "on Error Goto [label]" la syntaxe est pris en charge par Visual Basic et Visual Basic pour Applications (VBA), mais VBScript ne prend pas en charge cette fonctionnalité du langage, donc vous devez utiliser on Error Resume Next comme décrit ci-dessus.
- 🙁 ... Trop mal je pense...
- Vous pouvez changer WScript.Écho dans l'instruction if pour appeler une Fonction ou un Sous, qui pourrait quitter l'application, connectez-vous à l'erreur, etc.
- "contient les reuslts de la dernière opération effectuée". Est-ce vrai? Semble comme il obtient la dernière erreur qui est une grande différence.
- En dépit de MS de la documentation suggère que err.clear doit être utilisée après chaque case de l'objet, pour éviter des erreurs de déclenchement de l'enregistrement suivant (par exemple, technet.microsoft.com/en-us/library/ee692852.aspx), dans mon expérience, err est effacée "par lui-même" comme le script progresse. Sans les tests plus loin, je devine que c'est en utilisant des objets efface err comme un produit de leur fonctionnement interne.
- D'accord, mais encore plus sûr d'appeler explicitement Err.Clear.
InformationsquelleAutor Dylan Beattie
9

Noter que On Error Resume Next n'est pas défini à l'échelle mondiale. Vous pouvez mettre vos dangereuse partie de code par exemple dans une fonction, qui sera immédiatement interrompu si une erreur se produit, et d'appeler cette fonction à partir de sous-contenant précédent OERN déclaration.
```
ErrCatch()

Sub ErrCatch()
    Dim Res, CurrentStep

    On Error Resume Next

    Res = UnSafeCode(20, CurrentStep)
    MsgBox "ErrStep " & CurrentStep & vbCrLf & Err.Description

End Sub

Function UnSafeCode(Arg, ErrStep)

    ErrStep = 1
    UnSafeCode = 1 / (Arg - 10)

    ErrStep = 2
    UnSafeCode = 1 / (Arg - 20)

    ErrStep = 3
    UnSafeCode = 1 / (Arg - 30)

    ErrStep = 0
End Function
```
- Pas le meilleur exemple que j'ai jamais vu, mais je reçois le concept.
- auriez-vous l'esprit de relier une meilleure exemple que vous avez vu, ou plutôt suggérer comment omegastripes peut améliorer cet exemple?
- Pendant une seconde, j'ai l'impression que j'ai raté un nouveau logiciel d'ingénierie paradigme appelé "omegastripes" lol
InformationsquelleAutor omegastripes

Je suis exceptionnellement nouvelle pour VBScript, si cela peut ne pas être considéré comme une bonne pratique ou il y a peut être une raison, il ne devrait pas être fait de cette façon que je ne suis pas encore au courant, mais c'est la solution je suis venu avec de couper vers le bas le montant de la journalisation des erreurs de code dans mon bloc de code principal.

Dim oConn, connStr
Set oConn = Server.CreateObject("ADODB.Connection")
connStr = "Provider=SQLOLEDB;Server=XX;UID=XX;PWD=XX;Databse=XX"

ON ERROR RESUME NEXT

oConn.Open connStr
If err.Number <> 0 Then : showError() : End If


Sub ShowError()

    'You could write the error details to the console...
    errDetail = "<script>" & _
    "console.log('Description: " & err.Description & "');" & _
    "console.log('Error number: " & err.Number & "');" & _
    "console.log('Error source: " & err.Source & "');" & _
    "</script>"

    Response.Write(errDetail)       

    '...you could display the error info directly in the page...
    Response.Write("Error Description: " & err.Description)
    Response.Write("Error Source: " & err.Source)
    Response.Write("Error Number: " & err.Number)

    '...or you could execute additional code when an error is thrown...
    'Insert error handling code here

    err.clear
End Sub

C'est ASP Classic, pas un bon vieux VBScript

InformationsquelleAutor MistyDawn

0

Vous pouvez regrouper vos étapes des appels de fonctions dans une façade de la fonction :
```
sub facade()
    call step1()
    call step2()
    call step3()
    call step4()
    call step5()
end sub
```
Ensuite, laissez votre gestion des erreurs dans un coin supérieur de la fonction qui appelle la façade :
```
sub main()
    On error resume next

    call facade()

    If Err.Number <> 0 Then
        ' MsgBox or whatever. You may want to display or log your error there
        msgbox Err.Description
        Err.Clear
    End If

    On Error Goto 0
end sub
```
Maintenant, supposons que step3() génère une erreur. Depuis facade() ne gère pas les erreurs (il n'y a pas On error resume next dans facade()), l'erreur sera retourné à main() et step4() et step5() ne sera pas exécutée.

Votre gestionnaire d'erreur est maintenant refait dans 1 bloc de code

InformationsquelleAutor Cid

Vous devez vous connecter pour publier un commentaire.