VBscript chemin relatif

Je suis en train d'utiliser le script suivant (Il est appelé par un fichier Batch, par la voie) pour décompresser les fichiers dans Windows XP:

strZipFile ="C:\test.zip"                        'name of zip file
outFolder = "C:\"                                'destination folder of unzipped files

Set objShell = CreateObject( "Shell.Application" )
Set objSource = objShell.NameSpace(strZipFile).Items()
Set objTarget = objShell.NameSpace(outFolder)
intOptions = 256
objTarget.CopyHere objSource, intOptions

Problème est, où j'ai l'intention de l'utiliser je ne sais pas le chemin d'accès complet du fichier zip, tout ce que je vais savoir, c'est qu'il va être dans le même dossier que le script VBScript, donc, avec cela à l'esprit, serait-il possible de l'appeler avec un chemin relatif? Exemple:

strZipFile ="test.zip"

Cet exemple ne fonctionne pas (Il donne un message d'erreur "Objet requis:" objShell.Espace de noms(...)' "), alors, évidemment, je veux dire quelque chose le long de ces lignes, qui serait à l'œuvre.

OriginalL'auteur ShizukaSM | 2013-03-25

  1. 10

    WScript.ScriptFullName et de l'OFS.GetParentFolder devrait résoudre votre problème:

    >> p = CreateObject("Scripting.FileSystemObject").GetParentFolderName(WScript.ScriptFullName)
>>
>> WScript.Echo p
>>
M:\bin

    Mise à jour wrt Kiril commentaire:

    Preuves pour la réponse "Oui":

    Option Explicit

Class cX
  Private Sub Class_Initialize()
    WScript.Echo "Class_Initialize"
  End Sub
  Private Sub Class_Terminate()
    WScript.Echo "Class_Terminate"
  End Sub
  Public Function f()
    f = "qed"
  End Function
End Class

WScript.Echo 1
Dim f : f = (New cX).f()
WScript.Echo 2
WScript.Echo f

    de sortie:

    cscript 15621395.vbs
1
Class_Initialize
Class_Terminate
2
qed
    Est l'OFS Objet immédiatement éliminés, car il est hors de portée?
    oui, voir la mise à jour.

    OriginalL'auteur Ekkehard.Horner

  2. 3

    Cela devrait vous obtenez la zip du fichier chemin d'accès complet:

    strZipFile ="test.zip" 
dim fso, fullPathToZip
set fso = CreateObject("Scripting.FileSystemObject")
fullPathToZip = fso.GetAbsolutePathName(strZipFile)
    +1 Car votre réponse est aussi valable et différente de la précédente, merci!
    Il n'y a plus d'une façon d'écrire un script de chat! 😀
    Notez que GetAbsolutePathName interprète un chemin relatif par rapport au répertoire courant, alors que @Ekkehard.De Horner solution suppose par rapport au script. Ils peuvent être, mais ne sont pas toujours les mêmes.

    OriginalL'auteur Keen