VBScript Pour Lancer Internet Explorer Avec UNE URL Générée

Actuellement, je suis un apprentissage de programmation ETS. J'ai une exigence comme suit.

Il y a deux zones de saisie dans le formulaire (les deux sont obligatoires). Lorsque j'entre les valeurs et cliquez sur le bouton rechercher, une url serait créé sur la base des contributions. Le devrait lancer l'application Internet Explorer avec l'url générée.

Mon problème est que je suis en mesure de lancer le navigateur IE, mais je ne suis pas en mesure de passer l'url à elle.
J'ai essayé plusieurs méthodes mais je ne suis pas en mesure de le faire.

J'ai donné mon code ci-dessous. J'ai enlevé mon erronée de la syntaxe du passage de l'url du navigateur. Le code ci-dessous permettrait de créer l'url et le lancement d'un vide IE explorer.

S'il vous plaît aider moi. Merci à l'avance.

<html> 
<head> 
<script language="VBScript"> 

    Sub RunProgram
        callb = document.getElementById("callb").value
        call = document.getElementById("call").value
        url = "www.google.com"&callb&"and"&call
        msgbox(url)
        Set objShell = CreateObject("Wscript.Shell")
        objShell.Run "iexplore.exe"
    End Sub

</script> 
</head> 
<body>

<form style="width:254px; height:44px;">
CallB: <input type="text" id="callb" value=""><br>
Call  : <input type="text" id="call" value=""><br><br>
<button onclick="RunProgram">search</button>
</form>

</body>
</html>
InformationsquelleAutor arunpandiyarajhen | 2014-02-15
  1. 3

    Vous pouvez charger une URL dans le navigateur par défaut à l'aide de la méthode Run() de WShell:

    CreateObject("WScript.Shell").Run "www.google.com"

    Si vous voulez charger explicitement l'URL dans Internet Explorer, vous aurez besoin de déterminer le chemin d'accès complet IEXPLORE.EXE tout d'abord, puis la passer à Run():

    CreateObject("WScript.Shell").Run """" & strExePath & """ www.google.com"

    Ou

    CreateObject("WScript.Shell").Run """" & strExePath & """ " & strURL

    Notez les guillemets. Vous aurez envie de mettre des guillemets autour du chemin-à-dire dans le cas où le chemin d'accès contient un espace. Pour spécifier une citation à l'intérieur d'une chaîne, il faut le doubler. Si les citations sont source de confusion, vous pouvez utiliser Chr(34) pour spécifier un caractère de devis:

    CreateObject("WScript.Shell").Run Chr(34) & strExePath & Chr(34) & " " & strURL
    • Vous êtes vraiment super. Son travail pour moi. J'ai un petit souci. Pourriez-vous expliquer un peu clair sur les guillemets dans la syntaxe?
    • Assurez-vous. Lorsque vous tapez un chemin d'accès à la ligne de commande, vous devez utiliser des guillemets si le chemin contient des espaces. Par exemple, "C:\Program les Fichiers". La même règle s'applique à la fonction Run (). Pour spécifier une citation à l'intérieur d'une chaîne, il doit être doublé. C'est pourquoi nous utilisons 4 citations. Pour commencer la chaîne, un guillemet double, puis une autre citation à la fin de la chaîne. Alternativement, vous pouvez utiliser Chr(34) pour spécifier un devis. J'ai édité ma réponse à démontrer cette méthode.
    • Je l'ai eu. Merci beaucoup. 🙂
    InformationsquelleAutor Bond
  2. 0

    Pour rendre la vie plus facile, j'ai l'habitude d'utiliser cette fonction pour ajouter des guillemets dans une variable.

    Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function

    Un exemple pour vous montrer comment il est facile à utiliser.

    Option Explicit
Dim fso,ws,DossierProgramfiles,Winrar,FileZilla,FireFox
Set fso = CreateObject("Scripting.FileSystemObject")
Set ws = CreateObject("WScript.Shell")
DossierProgramfiles = ws.ExpandEnvironmentStrings("%PROGRAMFILES%")
Winrar = DblQuote(DossierProgramfiles & "\Winrar\Winrar.exe")
If fso.FileExists(DossierProgramfiles & "\Winrar\Winrar.exe") Then
    MsgBox Winrar,Vbinformation,Winrar
    ws.run Winrar
Else
    MsgBox "Le fichier " & Winrar & " n'existe pas",VbCritical,"Le fichier " & Winrar & " n'existe pas"
End If
FileZilla = DblQuote(DossierProgramfiles & "\FileZilla FTP Client\filezilla.exe")
If fso.FileExists(DossierProgramfiles & "\FileZilla FTP Client\filezilla.exe") Then
    MsgBox FileZilla,Vbinformation,FileZilla
    Ws.run FileZilla
Else
    MsgBox "Le fichier " & FileZilla & " n'existe pas",VbCritical,"Le fichier " & FileZilla & " n'existe pas"
End If
FireFox = DblQuote(DossierProgramfiles & "\Mozilla Firefox\FireFox.exe")
If fso.FileExists(DossierProgramfiles & "\Mozilla Firefox\FireFox.exe") Then
    MsgBox FireFox,Vbinformation,FireFox
    ws.run FireFox
Else
    MsgBox "Le fichier " & FireFox & " n'existe pas",VbCritical,"Le fichier " & FireFox & " n'existe pas"
End If
'****************************************************************************************************
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'****************************************************************************************************
    InformationsquelleAutor Hackoo
  3. 0

    Essayez avec cette HTA :

    <html>
<head>
<HTA:APPLICATION
APPLICATIONNAME="Search on Google with Internet Explorer"
BORDER="THIN"
BORDERSTYLE="NORMAL"
ICON="magnify.exe"
INNERBORDER="NO"
MAXIMIZEBUTTON="NO"
MINIMIZEBUTTON="NO"
SCROLL="NO"
SELECTION="NO"
SYSMENU="YES"
SINGLEINSTANCE="YES"/>
<META HTTP-EQUIV="MSThemeCompatible" CONTENT="YES">
<script language="VBScript">
Option Explicit
Dim Titre
Titre = "Search on Google with Internet Explorer"
Self.document.title = Titre
Sub window_onload()
CALL CenterWindow(300,180)
Self.document.bgColor = "Orange"
End Sub
Sub RunProgram()
Dim X,Y,URL,objShell,Param,MaCmd
X = text1.value
Y = text2.value
Param = "#q="& X & "+" & Y &""
URL = "www.google.com"& Param
Set objShell = CreateObject("Wscript.Shell")
msgbox("iexplore.exe " & DblQuote(URL)),VbInformation,Titre
MaCmd = "iexplore.exe "& DblQuote(URL) &""
objShell.Run(MaCmd)
End Sub
'***************************************************
Function DblQuote(Str)
DblQuote = Chr(34) & Str & Chr(34)
End Function
'***************************************************
'Position Windows
Sub CenterWindow(x,y)
Dim iLeft,itop
window.resizeTo x,y
iLeft = window.screen.availWidth/2 - x/2
itop = window.screen.availHeight/2 - y/2
window.moveTo ileft, itop
End Sub
</script>
</head>
<body><center>
Text1 : <input type="text" id="text1" Name="text1" value="Hackoo"><br>
Text2 : <input type="text" id="text2" Name="text2" value="Vbscript+HTA"><br><br>
<input type="submit" Value="Search on Google" onclick="RunProgram()"></center>
</body>
</html>
    InformationsquelleAutor Hackoo
  4. 0

    Le code ci-dessous extrait de lancer cette url dans le navigateur par défaut.

    CreateObject("WScript.Shell").Run url

    InformationsquelleAutor arunpandiyarajhen