Vérifier si une valeur est membre d'une liste

Contrairement à .NET langages VBA ne pas exposer Enum en tant que texte. Il est strictement un certain nombre et il n'est pas .ToString() méthode qui exposerait le nom de l'Enum. Il est possible de créer votre propre ToString() méthode et de retourner une représentation sous forme de Chaîne d'un enum. Il est également possible de énumérer un type Enum. Bien que tous est possible, je ne recommanderais pas en le faisant de cette manière que les choses sont trop compliqué pour une telle tâche.

Que diriez-vous de créer un Dictionnaire de la collecte des éléments et de l'utiliser simplement Exist méthode et une sorte d'erreur de manipulation (ou simple if/else) pour vérifier si ce que les entrées d'utilisateur dans la zone de saisie en existe un dans votre liste.

Par exemple:

Sub Main()

    Dim myList As Object
    Set myList = CreateObject("Scripting.Dictionary")

    myList.Add "item1", 1
    myList.Add "item2", 2
    myList.Add "item3", 3

    Dim userInput As String
    userInput = InputBox("Type something:")

    If myList.Exists(userInput) Then
        MsgBox userInput & " exists in the list"
    Else
        MsgBox userInput & " does not exist in the list"
    End If

End Sub

Remarque: Si vous ajoutez des références à Microsoft Scripting Runtime bibliothèque vous serez alors en mesure d'utiliser le logiciel intelli-sense avec le myList objet tel qu'il aurait été lié au plus tôt en remplacement de

 Dim myList As Object
 Set myList = CreateObject("Scripting.Dictionary")

avec

Dim myList as Dictionary
Set myList = new Dictionary

C'est à vous de la façon dont vous voulez aller à ce sujet et ce qui est plus pratique. Notez que vous n'avez pas besoin d'ajouter des références si vous allez avec la Liaison Tardive alors que les références sont nécessaires si vous voulez au Début de Liaison avec l'intelli-sense.

---

Juste pour le plaisir des lecteurs d'être en mesure de visualiser la version en utilisant le protocole Enum laissez-moi vous montrer comment ce mécanisme pourrait éventuellement travailler

Enum EList
    item1
    item2
    item3
    [_Min] = item1
    [_Max] = item3
End Enum

Function ToString(eItem As EList) As String
    Select Case eItem
        Case EList.item1
            ToString = "item1"
        Case EList.item2
            ToString = "item2"
        Case EList.item3
            ToString = "item3"
    End Select
End Function

Function Exists(userInput As String) As Boolean
    Dim i As EList
    For i = EList.[_Min] To EList.[_Max]
        If userInput = ToString(i) Then
            Exists = True
            Exit Function
        End If
    Next
    Exists = False
End Function

Sub Main()

    Dim userInput As String
    userInput = InputBox("type something:")

    MsgBox Exists(userInput)

End Sub

Tout d'abord vous déclarer votre Liste comme Enum. J'ai ajouté seulement 3 éléments pour l'exemple pour être aussi simple que possible. [_Min] et [_Max] indiquer la valeur minimale et la valeur maximale de l'enum (il est possible d'ajuster cette mais encore une fois, nous allons garder les choses simples pour l'instant). Vous déclarez à la fois à être en mesure d'effectuer une itération sur votre EList.

ToString() méthode renvoie une représentation sous forme de Chaîne de l'Enum. Tout développeur VBA se rend compte à un moment que c'est dommage de VBA est manquant cela comme une caractéristique intégrée. De toute façon, vous avez votre propre mise en œuvre maintenant.

Exists prend tout ce qui userInput magasins et lors de l'itération sur les Enum EList des matchs contre d'une représentation de Chaîne de votre Enum. C'est inutile parce que vous avez besoin à appeler un grand nombre de méthodes et de la boucle sur les enum pour être en mesure de réaliser ce une simple Dictionary's Exists méthode ne permet en une seule fois. C'est principalement pourquoi je ne recommande pas d'utiliser les Énumérations pour votre problème spécifique.

Puis à la fin vous avez le Main sous qui rassemble simplement l'entrée de l'utilisateur et appelle la Exists méthode. Il affiche une Boîte de Message avec soit true ou false qui indique si la Chaîne n'existe qu'un type Enum.

Suffit d'utiliser la Select Case avec une liste:

Select Case entry
   Case item1,item2, ite3,item4 ' add up to limit for Case, add more Case if limit exceeded
      do stuff for being in the list
   Case Else
      do stuff for not being in list
End Select