Windows fichiers Batch: qu'est-ce que l'expansion des variables, et ce n'est EnableDelayedExpansion veux dire?

Ce que l'on entend par "extension variable"? Signifie simplement "définition de la variable", ou quelque chose d'autre?

Ce qui se passe quand je dis setLocal EnableDelayedExpansion? Google n'était pas claire.

ss64.com/nt/delayedexpansion.html ; robvanderwoude.com/variableexpansion.php
J'ai lu ces pages. Je ne comprends toujours pas ce que signifie "l'expansion des variables' - t-il simplement dire "mettre une valeu dans une variable"?
Ok.Vérifiez aussi la de jeb réponse ici stackoverflow.com/questions/17265882/... ici stackoverflow.com/questions/4094699/...
help setlocal à l'invite de commande fournit de la documentation, comme le fait setlocal /?. Est-ce que c'est? (Il se lit assez clairement pour moi.)

OriginalL'auteur Aviv Cohn | 2014-08-15

batch-file variables

15
- Variable expansion moyens de remplacer une variable enfermé dans % ou ! par sa valeur.
- La %normal% l'expansion se trouvent juste une fois, avant une ligne est exécutée. Cela signifie qu'un %variable% extension la même valeur pas de questions si la ligne est exécutée plusieurs fois (comme dans un for de commande).
- La !delayed! expansion est effectuée chaque fois que la ligne est exécutée.
Voir cet exemple:
```
@echo off
setlocal EnableDelayedExpansion
set "var=Original"
set "var=New" & echo Normal: "%var%", Delayed: "!var!"
```
De sortie:
```
Normal: "Original", Delayed: "New"
```
Un autre:
```
@echo off
setlocal EnableDelayedExpansion
set "var1=Normal"
set "var2=Delayed"
for /L %%i in (1,1,10) do (
   set "var1=%var1% %%i"
   set "var2=!var2! %%i"
)
echo Normal:  "%var1%"
echo Delayed: "%var2%"
```
De sortie:
```
Normal:  "Normal 10"
Delayed: "Delayed 1 2 3 4 5 6 7 8 9 10"
```
Normal extension n'est pas nécessairement un inconvénient, mais dépend de la situation spécifique, il est utilisé. Par exemple, dans tous les autres langages de programmation, pour l'échange de la valeur de deux variables que vous avez besoin de l'aide d'un troisième, mais dans le Lot il peut être fait en une seule ligne:
```
set "var1=%var2%" & set "var2=%var1%"
```
Je vois. Permettez-moi de voir si j'ai bien compris: normal expansion, en tout lieu %var% est, il est remplacé, mais c'est la valeur de lors de l'analyse. Depuis très la ligne est parcourue qu'une seule fois, %var% sera le même dans chaque itération de la boucle. Avec l'expansion retardée, en substituant %var% avec une valeur qui se produit au moment de l'exécution", alors que le fait de l'exécution de la ligne, ainsi %var% est remplacé par l'actuelle valeur correcte. - Il Correct?
Aussi, dois-je toujours utiliser !var!, sauf dans des circonstances inhabituelles?

OriginalL'auteur Aacini
4

Dans le lot des variables sont évaluées en les enfermant dans des signes de pourcentage.
```
set myVariable=Hello world
echo %myVariable%
```
Cela signifie que l'expansion des variables.

Par rapport à d'autres langages de programmation, de lot, de ne pas vraiment travailler avec des variables.

Normalement, il ne fonctionne qu'avec l'expansion de l'.

Il fonctionne comme la macro extension de C/C++.

Donc, il n'existe pas une fonction de la longueur de la chaîne pour obtenir la longueur d'une variable,

mais vous pouvez écrire une fonction qui compte le nombre de caractères de texte.

Explication de setLocal EnableDelayedExpansion

La normale pour cent de l'expansion a deux inconvénients.

L'expansion qui se passe dans le moment de l'analyse d'une ligne ou un bloc fermé avec la parenthèse, pas lorsque le bloc est exécuté.

Permet de voir cet échantillon
```
set var=one

set var=two & echo %var%
echo %var%
```
La sortie sera

un

deux

Comme le echo %var% d'en accroître la avant la set var=two sera exécuté.
Cela peut devenir problématique dans les boucles FOR.

Et le deuxième inconvénient est que le lot analyseur de parser le résultat développé de la variable.
```
set var=cat^&dog
echo %var%
```
var

Commande inconnue "chien"

Mais le pourcentage d'expansion existe depuis le début de MS-Dos (1920).

La DelayedExpansion ajoute une nouvelle expansion de caractère, le point d'exclamation !.

Mais vous avez à l'activité première de l'utiliser avec setlocal EnableDelayedExpansion, c'est pour des raisons de compatibilité pour les anciens programmes.
```
setlocal EnableDelayedExpansion
set var=one
set var=two & echo !var!
set var=cat^&dog
echo !var!
```
deux

cat&chien

Si cela résout les deux problèmes de la pour cent de l'expansion.

OriginalL'auteur jeb

Vous devez vous connecter pour publier un commentaire.