XCOPY remplacer l'action?

dans le fichier bat, j'ai eu une commande de ce type :

xcopy "C:\Users\me\Documents\ApplyPatchBat" "C:\Users\me\Desktop\Test\" /S/E/K

Ce fait le travail où il permet de copier tous les fichiers y compris les fichiers à l'intérieur des sous-dossiers. Je sais que vous pouvez ajouter /y pour le rendre auto écraser.

Comment jamais, je veux créer une déclaration si ce fichier que nous sommes copie existe pas dans le dossier de destination, copiez-le dans un dossier de destination pour un dossier de sauvegarde.

Je me demande il n'y a aucune instruction SI je peux ajouter après la commande pour détecter si le fichier existe? Ou peut-être une erreur de contrôle du niveau lors de sa demande ce que je veux remplacer?
P. S. C'est pour appliquer les patchs à un programme, où il y a beaucoup de couches de dossiers, c'est pourquoi j'utilise le /S/E/K dans xcopy.

  • Qui ne peut pas être fait dans xcopy - vous pouvez utiliser un script pour vérifier et déplacer les fichiers avant de xcopy en cours d'exécution.
  • il est mieux d'utiliser un CV, si vous voulez suivre les révisions
InformationsquelleAutor Luis Liu | 2014-10-09
  1. 3

    xcopy ne peut à elle seule sauvegarde à l'avance, mais avec la sortie de xcopy et un peu pour la boucle de magie que vous pouvez faire ceci se produire

    @echo off
setlocal ENABLEDELAYEDEXPANSION
set source="C:\Users\me\Documents\ApplyPatchBat"
set target="C:\Users\me\Desktop\Test\"

rem /l = list only, /u = already existing, /y = yes to replace
rem /f = display full source and destination file names, /c = continue on errors
rem /s = subdirectories, /k = keep attributes
rem split the strings at ->, we're only interested in the part after ->
for /f "usebackq tokens=1,* delims=>" %%a in (`xcopy %source% %target% /l /u /y /f /c /s /k`) do (
    set file=%%b
    rem ignore lines without a destination, e.g. 15 file(s) copied
    if x!file! neq x (
        rem remove the leading space, original string is source -> destination
        set file=!file:~1!
        for %%f in ("!file!") do (
            if not exist %%~dpf\backup\* md %%~dpf\backup
            rem only backup if not already backed up
            if not exist %%~dpf\backup\%%~nxf move %%f %%~dpf\backup
        )
    )
)
xcopy %source% %target% /y /c /q /s /k
    • C'est étonnant, bien optimisé que ce que je suis en train de faire. juste quelques questions afin de bien le comprendre. Dans la première, le xcopy l'intérieur de la parenthèse fait copier les fichiers ? donc, %%a sera les fichiers? Ce sera %%b ? Et la dernière question, qu'est-x!fichier! neq x signifie ? Je vous remercie beaucoup pour l'aide tho !
    • La première xcopy a l' /l drapeau qui vient de listes de fichiers sans avoir à les copier. Les tokens=1,* feront %%a la source (avec un trailing " -" espace tiret) et %%b la destination (avec un espace). Le enabledelayedexpansion vous permet de l'utiliser ! à la place de % pour les variables, mais à l'aide ! signifie que les valeurs d'actualisation. Donc x!fichier! equ x est de demander - est !fichier! vide?
    • Merci c'est plus clair maintenant 🙂 je sais que temp var ! signe, mais ce qui ne l'2 x autour de la déclaration de dire ?
    • Cela pourrait aider à expliquer cette partie pour vous: robvanderwoude.com/variableexpansion.php
    InformationsquelleAutor Scott C