XSLT 2.0, fonction de remplacement: Comment remplacer un groupe apparié avec des majuscules?

Si vous avez un élément suivant dans mon fichier XSL:

<xsl:value-of select="replace(lower-case(@name), '_([a-z0-9])', '$1')" />

Par exemple de "get_polygene_lubricants' elle fait getpolygenelubricants'.

Ce que je veux faire est de remplacer la première lettre après '_' avec
les majuscules variante de la lettre. J'ai googlé, de lire la documentation,
mais je n'ai pas pu trouvé de solution dans XSLT pour cette simple
le remplacement.

Peut-être que quelqu'un sait si il est possible de XSLT 2.0?

Merci pour clarifier les exigences du problème. J'ai corrigé ma réponse et maintenant, il produit exactement le résultat que vous attendez. S'il vous plaît, jetez un oeil 🙂
Désolé, Il y a un bug dans la. Je ne pouvais pas lire votre dernier commentaire à moi. IE s'est écrasé, et maintenant je n'ai pas bouillonnent commentaire. Pourriez-vous, s'il vous plaît, répéter?
Il est édité et produit de votre résultat, juste avec une seule expression XPath 🙂 avez-vous lu vos réponses?

InformationsquelleAutor Jagger | 2009-01-28

6

Édité: Par la clarification de l'affiche originale, la première chaîne délimitée par les traits de soulignement ne devrait pas avoir de départ la lettre en majuscule.

Cette solution ne permet pas l'utilisation de la récursivité et devrait être bien plus efficace.

Ici est la nouvelle solution:
```
string-join(
            (for  $i in 1 to count(tokenize(.,'_')),
                  $s in tokenize(.,'_')[$i],
                  $fl in substring($s,1,1),
                  $tail in substring($s,2)
               return
                  if($i eq 1)
                   then $s
                   else concat(upper-case($fl), $tail)
             ),
                        ''
           )
```
Le résultat est exactement comme l'exige:
```
underLinedString
```
Ci-dessous est la vieille solution.

La fonction de remplacement() suppose que vous avez un remplacement fixe -- il n'est donc pas le meilleur outil pour résoudre ce problème.

Ici est un one-liner XPath 2.0 solution (et il peut certainement être utilisé dans le cadre d'une transformation XSLT 2.0 🙂 ):
```
string-join(
            (for $s in tokenize(.,'_'),
                 $fl in substring($s,1,1),
                 $tail in substring($s,2)
               return
                 concat(upper-case($fl), $tail)
             ),
            ''
           )
```
Lorsque nous utilisons l'expression ci-dessus dans une transformation XSLT 2.0 comme ce:
```
<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:template match="/">
     <xsl:sequence select=
      "string-join(
                   (for $s in tokenize(.,'_'),
                    $fl in substring($s,1,1),
                    $tail in substring($s,2)
                  return
                concat(upper-case($fl), $tail)
                   ),
                   ''
                  )

      "/>
    </xsl:template>
</xsl:stylesheet>
```
et de l'appliquer sur le document XML suivant:
```
<t>under_lined_String</t>
```
le résultat voulu est produit:
```
UnderLinedString
```
- Merci pour l'exemple. Je ne sais pas XPath 2.0, mais à partir de maintenant c'est sûr que je vais apprendre quelque chose. Toutefois, votre solution n'est pas exactement ce que je veux que la première lettre de la chaîne de résultat doit être en minuscules.
- Il est édité et produit de votre résultat, juste avec une seule expression XPath 🙂
- Oui, il a l'air très soigné. Je suis passé à votre solution. Je vous remercie beaucoup.
InformationsquelleAutor Dimitre Novatchev
1

Vous pouvez le faire à l'aide d'un modèle, de manière récursive appelant lui-même pour parcourir les caractères dans la chaîne. Ce modèle doit prendre un paramètre de position, en commençant à 1
et en augmentation pour chaque appel au modèle. Lorsque '_' est trouvé, transformer char à côté de majuscules à l'aide de traduire(1.0) ou en majuscule(2.0)
- J'ai créé un tel monstre de 21 lignes de xml au lieu de 1. Mais surtout, il fonctionne. 🙂 Merci pour l'astuce.
- Oui c'est pas très délicat, je suis d'accord sur ce point. J'ai tendance à inclure ces hacks de certaines communes fichier XSLT, donc je n'ai pas à les voir.
- Avec XPath 2.0 / XSLT 2.0, il est plus simple solution et il ne nécessite pas la récursivité. Donc, il est probablement plus efficace, aussi. Voir ma solution.
InformationsquelleAutor baretta

Bien que déjà répondu, voici ma solution:

<xsl:template name="camel-case">
  <xsl:param name='value'/>
  <xsl:analyze-string regex="^(.)" select="$value">
    <xsl:matching-substring><xsl:value-of select="upper-case(regex-group(1))"/></xsl:matching-substring>
    <xsl:non-matching-substring>
      <xsl:analyze-string regex="[_-](.)" select=".">
        <xsl:matching-substring><xsl:value-of select="upper-case(regex-group(1))"/></xsl:matching-substring>
        <xsl:non-matching-substring><xsl:value-of select="."/></xsl:non-matching-substring>
      </xsl:analyze-string>
    </xsl:non-matching-substring>          
  </xsl:analyze-string>
</xsl:template>

Utilisation:

<xsl:call-template name="camel-case">
  <xsl:with-param name='value' select="."/>
</xsl:call-template>

InformationsquelleAutor nicerobot

Vous devez vous connecter pour publier un commentaire.