XSLT chaîne de remplacer

Je ne sais pas vraiment XSL mais j'ai besoin de corriger ce code, j'ai réduit-il à la rendre plus simple.

J'obtiens cette erreur

Invalide XSLT/XPath fonction

sur cette ligne

<xsl:variable name="text" select="replace($text,'a','b')"/>

C'est le XSL

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:inm="http://www.inmagic.com/webpublisher/query" version="1.0">
    <xsl:output method="text" encoding="UTF-8" />

    <xsl:preserve-space elements="*" />
    <xsl:template match="text()" />

    <xsl:template match="mos">
        <xsl:apply-templates />

        <xsl:for-each select="mosObj">
          'Notes or subject' 
           <xsl:call-template
                name="rem-html">
                <xsl:with-param name="text" select="SBS_ABSTRACT" />
            </xsl:call-template>
        </xsl:for-each>
    </xsl:template>

    <xsl:template name="rem-html">
        <xsl:param name="text" />
        <xsl:variable name="text" select="replace($text, 'a', 'b')" />
    </xsl:template>
</xsl:stylesheet>

Quelqu'un peut me dire quel est le problème avec elle?

Veuillez noter que le replace() fonction est disponible à partir de XPath 2.0 (et donc de XSLT 2.0) en avant et prend en charge les expressions régulières de remplacement.

InformationsquelleAutor Aximili | 2010-06-18

131

replace n'est pas disponible pour XSLT 1.0.

Codesling a un modèle de chaîne à remplacer vous pouvez l'utiliser comme un substitut de la fonction:
```
<xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
        <xsl:when test="$text = '' or $replace = ''or not($replace)" >
            
            <xsl:value-of select="$text" />
        </xsl:when>
        <xsl:when test="contains($text, $replace)">
            <xsl:value-of select="substring-before($text,$replace)" />
            <xsl:value-of select="$by" />
            <xsl:call-template name="string-replace-all">
                <xsl:with-param name="text" select="substring-after($text,$replace)" />
                <xsl:with-param name="replace" select="$replace" />
                <xsl:with-param name="by" select="$by" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>
```
invoquée comme:
```
<xsl:variable name="newtext">
    <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="$text" />
        <xsl:with-param name="replace" select="a" />
        <xsl:with-param name="by" select="b" />
    </xsl:call-template>
</xsl:variable>
```
D'autre part, si vous avez littéralement seulement besoin de remplacer un caractère par un autre, vous pouvez appeler translate qui a la même signature. Quelque chose comme ceci devrait fonctionner:
```
<xsl:variable name="newtext" select="translate($text,'a','b')"/>
```
Aussi, remarque, dans cet exemple, j'ai changé le nom de la variable à "newtext", dans XSLT variables sont immuables, de sorte que vous ne pouvez pas faire l'équivalent de $foo = $foo comme vous l'avez fait dans votre code original.
- Merci Mark, mais maintenant j'obtiens cette erreur: Un inconnu extension XPath fonction a été appelée
- désolé, mais j'ai XSLT 1.0 et 2.0 confus, édité...devrait être bon d'aller maintenant.
- Je vois merci Marc!
- Cette réponse est fausse! La fonction replace dans XSLT remplace correspondant de SIMPLES CARACTÈRES, non pas à l'ensemble des chaînes! Voir par exemple ici: w3schools.com/xpath/xpath_functions.asp
- Vous êtes en train de penser de translate, pas replace. Le replace fonction XPath 2.0 traite son deuxième argument comme un expression régulière et remplace toutes les correspondances de cette expression avec la chaîne de remplacement spécifiée (ce qui peut inclure $n références à la capture des groupes dans la regex). Le translate fonction (1.0 et 2.0) est le caractère unique de unique de caractères de remplacement.
- ne pas le 4e de ligne, dans l'exemple de l'utilisation <xsl:with-param name="replace" select="'a'" /> avec des guillemets autour de l'un?
- Cette solution ne sera pas en mesure de gérer les signaux d'entrée avec XML/HTML, depuis un disable-output-escaping-l'attribut est manquant. Je suppose qu'il doit être ajouté manuellement et si les deux variantes sont nécessaires, il y a deux modèles?
InformationsquelleAutor Mark Elliot

Ici est la fonction XSLT qui fera le même travail à la Chaîne.Fonction de remplacement() de C#.

Ce modèle a les 3 Paramètres comme ci-dessous

texte :- votre chaîne principale

remplacer :- la chaîne que vous souhaitez remplacer

par :- la chaîne qui va répondre par une nouvelle chaîne de

Ci-dessous sont le Modèle

<xsl:template name="string-replace-all">
  <xsl:param name="text" />
  <xsl:param name="replace" />
  <xsl:param name="by" />
  <xsl:choose>
    <xsl:when test="contains($text, $replace)">
      <xsl:value-of select="substring-before($text,$replace)" />
      <xsl:value-of select="$by" />
      <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="substring-after($text,$replace)" />
        <xsl:with-param name="replace" select="$replace" />
        <xsl:with-param name="by" select="$by" />
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$text" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Exemple ci-dessous montre comment l'appeler

<xsl:variable name="myVariable ">
  <xsl:call-template name="string-replace-all">
    <xsl:with-param name="text" select="'This is a {old} text'" />
    <xsl:with-param name="replace" select="'{old}'" />
    <xsl:with-param name="by" select="'New'" />
  </xsl:call-template>
</xsl:variable>

Vous pouvez également consulter le l'URL ci-dessous pour plus de détails.

À l'aide de xslt 1.0 Ce post/modèle a fonctionné pour moi alors que Mark Elliot n'a pas.

InformationsquelleAutor Optimus

12

Remarque: Dans le cas où vous souhaitez utiliser le déjà mentionné algo pour les cas où vous avez besoin de remplacer le grand nombre d'occurrences dans la chaîne source (par exemple, de nouvelles lignes dans le texte long) il y a haute probabilité, vous vous retrouverez avec StackOverflowException en raison de l'appel récursif.

J'ai résolu ce problème grâce à Xalan's (n'a pas à chercher comment le faire dans Saxon) built-in Java de type intégration:
```
<xsl:stylesheet version="1.0" exclude-result-prefixes="xalan str"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xalan="http://xml.apache.org/xalan"
                xmlns:str="xalan://java.lang.String"
        >
...
<xsl:value-of select="str:replaceAll(
    str:new(text()),
    $search_string,
    $replace_string)"/>
...
</xsl:stylesheet>
```
- Désolé si je suis stupide, mais je reçois: Cannot find a script or an extension object associated with namespace 'xalan://java.lang.String'.
- Qu'est-ce que votre moteur XSLT?
- L'Microsoft.NET l'un, je le crains...
- Mon commentaire était pour les plus populaires Java XSLT 1.0 moteur de Xalan (xml.apache.org/xalan-j), qui prend en charge directe de la cartographie de types disponibles à l'intérieur de Java disponible classpath; vous ne pouvez pas appliquer ma solution pour .Net de la pile
- vous pouvez l'utiliser avec .NET par l'ajout d'une <msxsl:script> bloc, qui peut appeler à tout .Méthode NETTE, bibliothèques, etc. Cependant .NET prend également en charge la EXSLT fonctions d'extension, de sorte que vous n'avez pas besoin de.
- exslt est également pris en charge dans libxslt et, par conséquent, dans tous les descendants xsltproc etc...
InformationsquelleAutor Milan Aleksić
6

Vous pouvez utiliser le code suivant lors de votre processeur fonctionne sur .NET ou utilise MSXML (contrairement à Java ou autre natif de processeurs). Il utilise msxsl:script.

Assurez-vous d'ajouter l'espace de noms xmlns:msxsl="urn:schemas-microsoft-com:xslt" à la racine de votre xsl:stylesheet ou xsl:transform élément.

En outre, lier outlet à aucun espace de noms que vous voulez, par exemple xmlns:outlet = "http://my.functions".
```
<msxsl:script implements-prefix="outlet" language="javascript">
function replace_str(str_text,str_replace,str_by)
{
     return str_text.replace(str_replace,str_by);
}
</msxsl:script>


<xsl:variable name="newtext" select="outlet:replace_str(string(@oldstring),'me','you')" />
```
- Désolé si je suis stupide, mais je reçois prefix outlet is not defined ou 'xsl:script' cannot be a child of the 'xsl:stylesheet' element. si je change msxsl pour mon préfixe. Je devine que c'est une partie spécifique de Microsoft XSLT magie?
- il n'est pas xsl:script, mais msxsl:script, et il dispose d'un espace de noms différent (j'ai mis à jour Jean-réponse).
InformationsquelleAutor John Jin
0

La rouine il est très bien, cependant, il provoque mon application à accrocher, j'ai donc besoin d'ajouter le cas:
```
  <xsl:when test="$text = '' or $replace = ''or not($replace)" >
    <xsl:value-of select="$text" />
    
  </xsl:when>
```
avant que la fonction est appelée récursivement.

J'ai eu la réponse à partir d'ici:
Lors de l'essai de la pendaison dans une boucle infinie

Merci!

InformationsquelleAutor Chesare

Vous devez vous connecter pour publier un commentaire.