XSLT - Comment garder seulement voulu éléments de XML

J'ai un certain nombre de fichiers XML qui contiennent beaucoup de frais généraux. Je tiens à les garder seulement environ 20 éléments spécifiques et filtrer rien d'autre. Je connais tous les noms des éléments que je veux garder, je sais aussi qu'ils soient ou non des éléments d'enfant et qui sont leurs parents. Ces éléments que je veux garder après la transformation doivent toujours avoir leur origine hiérarchique de placement.

E. g. Je veux garder SEULEMENT

<ns:currency>

dans;

<ns:stuff>
 <ns:things>
  <ns:currency>somecurrency</ns:currency>
  <ns:currency_code/>
  <ns:currency_code2/>
  <ns:currency_code3/>
  <ns:currency_code4/>
 </ns:things>
</ns:stuff>

Et la faire ressembler à ceci;

<ns:stuff>
 <ns:things>
  <ns:currency>somecurrency</ns:currency>
 </ns:things>
</ns:stuff>

Quelle serait la meilleure manière de construire une transformation XSLT pour accomplir cette?

Double Possible de Comment faire pour supprimer des éléments de xml en utilisant la feuille de style xslt avec et xsltproc?
Dans cet exemple, vous spécifiez les éléments à sortir, j'ai besoin de spécifier les éléments à quitter le filtre et rien d'autre.
Je suis d'accord avec MarcoS. C'est un doublon. L'on a accepté la réponse est à peu près ce que vous avez besoin
Pour l'exemple que j'ai donné, vous pouvez utiliser cette solution, j'en conviens. Mais pour la question générale que j'ai donné, il ne fonctionne pas. Comme je l'ai expliqué, j'ai besoin de la solution inverse de cela, j'ai besoin de spécifier ce que je veux garder, pas ce que je veux supprimer; Il y a beaucoup plus d'éléments que j'ai besoin de l'enlever que j'ai besoin de garder, ainsi, il ne serait pas logique de spécifier toutes celles que je veux supprimer.
Peut-être que vous pouvez essayer de revenir le corps de ces deux modèles...
Je ne vois pas comment cela pourrait fonctionner. Peut-être que je ne vous comprends bien, vous avez un exemple?
Bonne question, +1. Voir ma réponse pour une solution générale qui peut être utilisé pour conserver tout élément dont le nom est dans une "liste blanche" et aussi de préserver les relations structurelles de ces éléments dans le document. Vous pouvez toujours utiliser cette transformation pour tout ce genre de tâche.
Également ajouté des explications détaillées. 🙂

InformationsquelleAutor cc0 | 2011-04-26

14

Cette transformation générale:
```
<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ns="some:ns">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <ns:WhiteList>
  <name>ns:currency</name>
  <name>ns:currency_code3</name>
 </ns:WhiteList>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match=
  "*[not(descendant-or-self::*[name()=document('')/*/ns:WhiteList/*])]"/>
</xsl:stylesheet>
```
lorsqu'il est appliqué sur le document XML fourni par le (avec définition d'espace de noms ajoutés à faire, c'est bien-formé):
```
<ns:stuff xmlns:ns="some:ns">
    <ns:things>
        <ns:currency>somecurrency</ns:currency>
        <ns:currency_code/>
        <ns:currency_code2/>
        <ns:currency_code3/>
        <ns:currency_code4/>
    </ns:things>
</ns:stuff>
```
produit le résultat voulu (white-listé les éléments et leurs relations structurelles sont conservés):
```
<ns:stuff xmlns:ns="some:ns">
   <ns:things>
      <ns:currency>somecurrency</ns:currency>
      <ns:currency_code3/>
   </ns:things>
</ns:stuff>
```
Explication:
1. L'identité de la règle/modèle des copies de tous les nœuds "comme est".
2. La feuille de style contient un haut niveau de <ns:WhiteList> élément dont <name> enfants spécifier toutes dans la liste blanche de l'élément de noms -- les éléments qui doivent être conservés avec leurs relations structurelles dans le document.
3. La <ns:WhiteList> élément est le mieux gardé dans un document distinct, de sorte que la feuille de style n'auront pas besoin d'être modifié avec de nouveaux noms. Voici la liste blanche est dans la même feuille de style juste pour des raisons de commodité.
4. Un seul modèle est primordial de l'identité du modèle. Il n'a pas de processus (supprime) tout élément qui n'est pas dans la liste blanche et n'a pas de descendant qui est dans la liste blanche.
- Qu'est-ce que node()|@*' correspond exactement?
- chaque node() (élément de texte, commentaire de l'instruction de traitement) et chaque attribut.
- +1 Mieux sémantique. Bien que l'on devrait aussi tester URI d'espace de noms, et, pour cette question, plus simple *[not(descendant-or-self::ns:currency)] serait suffisant.
- Oui, mais je suis d'une portée plus générale de la solution qui permet de résoudre un ensemble de problèmes.
- C'est une belle réponse!
- Je suis tombé sur un problème intéressant, j'ai un enfant d'éléments avec le nom "nombre" comme un enfant de plusieurs parents, comme "étudiant" et "enseignant". Si je ne veux liste le "nombre" d'éléments existants, comme les enfants de "l'étudiant", et non pas ceux de "professeur". Ce qui est une bonne approche? Peut-être un moyen pour spécifier hiérarque(s) le "nombre" élément peut appartiennent légalement à, mais comment?
- Novatchev: puis-je remplacer "node ()|@* "et"*|@*'??
- En général, non, c'est le plus modèle générique et il doit le rester générique. Toutefois, si vous insistez sur la rupture de la beauté, et à condition qu'il n'y a aucun texte, commentaire et PI nœuds (ou vous ne voulez pas copié), alors oui, vous pouvez utiliser le match modèle que vous proposez. Pourquoi ne pas vous juste essayer et voir si c'est ce que vous voulez? Osez l'expérience vous-même.
- Dans de tels cas les plus complexes de la liste blanche de la table perd ses avantages. La meilleure et la plus flexible de la voie à suivre dans de tels cas est d'avoir des modèles comme <xsl:template match="teacher/number"/>. Ce modèle ne tient pas compte de teacher/number éléments (effextively la "suppression" de leur. Tous ces modèles devraient être mis (pour une meilleure flexibilité et de commodité) dans un autre <xsl:stylesheet> et il doit être importé (<xsl:import>) de la première feuille de style XSLT application.
- Je comprends, merci pour les commentaires. Très apprécié.
- Vous êtes les bienvenus.
InformationsquelleAutor Dimitre Novatchev

Dans XSLT-vous l'habitude de ne pas supprimer les éléments que vous voulez supprimer, mais vous copier les éléments que vous souhaitez conserver:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:ns="http://www.example.com/ns#"
    version="1.0">

    <xsl:output method="xml" indent="yes" omit-xml-declaration="no"/>

     <xsl:template match="/ns:stuff">
        <xsl:copy>
            <xsl:apply-templates select="ns:things"/>
        </xsl:copy>
     </xsl:template>

     <xsl:template match="ns:things">
        <xsl:copy>
            <xsl:apply-templates select="ns:currency"/>
            <xsl:apply-templates select="ns:currency_code3"/>                   
        </xsl:copy>
     </xsl:template>

     <xsl:template match="ns:currency">
        <xsl:copy-of select="."/>
     </xsl:template>

     <xsl:template match="ns:currency_code3">
        <xsl:copy-of select="."/>
     </xsl:template>

</xsl:stylesheet>

L'exemple ci-dessus exemplaires seulement currency et currency_code3. Le résultat est le suivant:

<?xml version="1.0" encoding="UTF-8"?>
<ns:stuff xmlns:ns="http://www.example.com/ns#">
   <ns:things>
      <ns:currency>somecurrency</ns:currency>
      <ns:currency_code3/>
   </ns:things>
</ns:stuff>

Note: j'ai ajouté une déclaration d'espace de noms pour votre préfixe ns.

Si vous voulez une copie tout à l'exception de quelques éléments, vous pouvez voir ce réponse

Parfait, merci!
Vous pouvez être intéressé de voir plus de solution générale, et dans ma réponse.
1 Ce n'est pas de produire le résultat désiré.
comme d'habitude, vos commentaires sont corrects 🙂 j'ai mis à jour mon code, et maintenant, il devrait être OK. Tout commentaire est le bienvenu et utile d'apprendre.
+1 Maintenant, il produit le résultat souhaité. La suppression des commentaires.

InformationsquelleAutor MarcoS

Vous devez vous connecter pour publier un commentaire.