XSLT Comment vérifier si le Nœud XML existe?

J'ai des fichier XML:

<?xml version="1.0" encoding="utf-8"?>
<?xml-stylesheet type="text/xsl" href="test.xsl"?>
<Data>
  <Records>
    <Record>
     <AddInfo>
      <Info>
      </Info>
     </AddInfo>
    </Record>
  </Records>
</Data>

et fichier XSL:

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:template match="Dane">
    <html>
      <link rel="stylesheet" type="text/css" href="report.css"></link>
      <body>
        <h2>Table1</h2>
        <table border="1" cellspacing="0">
          <tr>
            <th>XXX</th>
          </tr>
          <xsl:for-each select="Records/Record">
            <tr>
              <td>
                <xsl:value-of select="XXX"/>
              </td>
            </tr>
          </xsl:for-each>
        </table>
        <h2>SecondTable</h2>
        <table border="1" cellspacing="0">
          <tr>
            <th>YYY</th>
            <th>ZZZ</th>
          </tr>
          <xsl:for-each select="Records/Record/AddInfo/Info">
            <tr>
              <td>
                <xsl:value-of select="YYY"/>
              </td>
              <td>
                <xsl:value-of select="ZZZ"/>
              </td>
            </tr>
          </xsl:for-each>
        </table>
      </body>
    </html>
  </xsl:template>
</xsl:stylesheet>

Et je veux le faire comme ça: si le nœud existe, affichage de la table "Info" nœuds, et si non, afficher le TEXTE.

J'ai essayé

<xsl:if test="following-sibling::AddInfo">
</xsl:if>

<xsl:if test="AddInfo">
</xsl:if>

Mais ça ne fonctionne pas.

Je le veux comme ceci:

Table1
---------------------
|     |      |      |

(condition: si à l'intérieur de XML sera nœud, je veux afficher la deuxième table, sous la table Table1)

SecondTable
-------------
|     |     |

Comment je peux faire cela?

Il n'est pas clair ce que vous demandez. Une chose importante, vous n'avez pas posté votre sortie attendue. Et de, mettre tous les scénarios dans votre XML d'entrée que vous souhaitez traiter.
Votre question n'est pas claire. Exactement où vous voulez insérer ce test? Vous n'avez qu'une, table générale, de sorte que "si le nœud existe, affichage de la table "Info" nœuds, et si non, afficher le TEXTE", fait très peu de sens.
Donc, vous dites qu'un texte doit être indiqué si la addInfo élément n'est pas présent?
Oui, définitivement, je le veux comme Rnet dit.
qu'est-ce que "si à l'intérieur de XML sera nœud" ? êtes-vous en train de dire "si certains nœud existe cela"?

OriginalL'auteur vBB | 2014-12-19

Ce sorties Yep si <AddInfo> existe qu'à un enfant de <Record>, et Nope autrement:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="Data">
    <xsl:for-each select="Records/Record">
      <xsl:choose>
        <xsl:when test="AddInfo">Yep</xsl:when>
        <xsl:otherwise>Nope</xsl:otherwise>
      </xsl:choose>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

Notez que vous n'avez pas besoin for-each, vous devriez laisser un deuxième modèle de correspondre à chaque <Record>:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="Data">
    <xsl:apply-templates/>
  </xsl:template>

  <xsl:template match="Data/Records/Record">
    <xsl:choose>
      <xsl:when test="AddInfo">Yep</xsl:when>
      <xsl:otherwise>Nope</xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

Vous pourriez aussi éviter choose et l'utilisation de deux indépendants if conditions:

  <xsl:template match="Data/Records/Record">
    <xsl:if test="AddInfo">Yep</xsl:if>
    <xsl:if test="not(AddInfo)">Nope</xsl:if>
  </xsl:template>

Si vous ne voulez pas vous limiter à des enfants immédiats, l'utilisation .//AddInfo à la place.

Considérer la feuille de style suivant:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="Data">
    <xsl:apply-templates select="Records/Record"/>
  </xsl:template>

  <xsl:template match="Data/Records/Record">
    <table class="one"></table>
    <xsl:if test="AddInfo">
      <table class="two"></table>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

Il sorties

<table class="one"></table>

si il n'y a pas <AddInfo> nœud dans <Record>, et

<table class="one"></table>
<table class="two"></table>

autrement.

Vous pouvez résoudre ce problème ni avec l'aide de if ni choose. XML:

<?xml version="1.0" encoding="utf-8"?>
<?xml-stylesheet type="text/xsl" href="test.xsl"?>
<Data>
  <AddInfo>
    <Info>This is ignored</Info>
  </AddInfo>
  <Records>
    <Record>
        <AddInfo>
          <Info>One,</Info>
          <Info>Two,</Info>
          <Info>Three</Info>
        </AddInfo>
    </Record>
    <Record>
      <Info>Ignored as well</Info>
    </Record>
    <Record>
      <Nested>
        <AddInfo>
          <Info>So is this</Info>
        </AddInfo>
      </Nested>
    </Record>
  </Records>
</Data>

XSLT:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="Data">
    <root>
      <xsl:apply-templates select="Records/Record"/>
    </root>
  </xsl:template>

  <xsl:template match="Data/Records/Record">
    <xsl:copy>
      <table id="one"></table>
      <xsl:apply-templates select="AddInfo"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="Data/Records/Record/AddInfo">
    <table id="two">
      <xsl:apply-templates select="Info"/>
    </table>
  </xsl:template>

  <xsl:template match="Data/Records/Record/AddInfo/Info">
    <xsl:value-of select="."/>
  </xsl:template>

</xsl:stylesheet>

De sortie:

<root>
  <Record>
    <table id="one" />
    <table id="two">One,Two,Three</table>
  </Record>
  <Record>
    <table id="one" />
  </Record>
  <Record>
    <table id="one" />
  </Record>
</root>

Ressemble, j'ai été testé quelque chose comme cela, et il n'est pas de travail, parce que, si il n'y a pas de "AddInfo" nœud à l'intérieur de mon XML généré, en-tête de la SecondTable (YYY, ZZZ) est toujours affiché, au lieu de cet en-tête, je voudrais afficher un TEXTE.
La condition nœud doit envelopper tous les nœuds qui génèrent le 2ème tableau de cours. Voir ma réponse mis à jour.
Merci!!!! Maintenant ça fonctionne 🙂
+ 1 Bon code. Juste une petite remarque: Si vous savez que votre structure d'entrée bien, il n'est pas nécessaire de taper l'ensemble de la hiérarchie de l'élément dans le modèle correspond à (par exemple Data/Records/Record/AddInfo/Info).
Vrai, mais il assure que pas aussi appelés nœuds sont appariés à partir d'autres chemins. Vous ne savez pas si il y a une différence de performance.

OriginalL'auteur CoDEmanX

Pour vérifier si le nœud existe en xml ce code XSLT œuvres

<xsl:choose>
                <xsl:when test="XMLNodeName">
                  <Cell ss:Index="2" ss:StyleID="s110">
                    <Data ss:Type="String">
                      <xsl:value-of select="NodeOne"/>
                    </Data>
                  </Cell>
                </xsl:when>
                <xsl:otherwise>
                  <Cell`enter code here` ss:Index="2" ss:StyleID="s110">
                    <Data ss:Type="String">
                      <xsl:value-of select="NodeTwo"/>
                    </Data>
                  </Cell>
                </xsl:otherwise>
 </xsl:choose>

OriginalL'auteur Girish kumrawat

Vous devez vous connecter pour publier un commentaire.