XSLT convertir le format de date

Je rencontre un problème lorsque je reçois un fichier XML, et à partir des échantillons que je reçois le format de date que j'obtiens est mm/dd/yyyy et parfois, il est m/d/yyyy. Ma tâche est de convertir à un autre fichier XML où le schéma accepte uniquement yyyy-mm-dd. Je suis limité à l'aide de XSLT 1.0/XPATH 1.0. Comment puis-je faire cela?

Alors, comment voulez-vous interpréter '11/12/2012' ? Vous devez préciser votre question avec les règles de savoir lequel des deux formats s'applique dans les cas qui.
Avec la source schéma 11/12/2012 le schéma cible aurait besoin d'avoir ce que 2012-11-12 (interprété comme 2012 12 novembre).

OriginalL'auteur TimWagaman | 2012-04-30

  1. 8

    Votre question est un peu vague. Il a besoin de quelques échantillons d'entrée et de sortie attendue. Mais de toute façon, ici, c'est une réponse à deviner ce que vous voulez.

    Compte tenu de cette entrée:

    <?xml version="1.0"?>
<dates>
  <date>11/12/2012</date>
  <date>3/4/2011</date>
</dates>

    ... transformé par cette feuille de style ...

    <?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>

      <xsl:template match="dates">
        <xsl:copy>
        <xsl:apply-templates select="*" />
        </xsl:copy>
      </xsl:template>

      <xsl:template match="date">
        <xsl:copy>
        <xsl:value-of select=" 
           concat(
           substring-after(substring-after(.,'/'),'/') , '-',
           format-number( number( substring-before(.,'/')), '00') , '-',
           format-number( substring-before(substring-after(.,'/'),'/'), '00') 
           )
          " />
        </xsl:copy>
      </xsl:template>

</xsl:stylesheet>

    ... va produire cette sortie désirée ...

    <dates>
 <date>2012-11-12</date>
 <date>2011-03-04</date>
</dates>

    Veuillez cocher la réponse si elle est correcte. J'ai vérifié cette solution sur http://www.purplegene.com/static/transform.html

    Dogbane la solution est assez semblable à la mienne, mais il me battre pour le punch. Pourtant, je pense que ma solution est plus courte et se lit mieux. McLaren solution ne fonctionne pas sur les dates comme 1/12/2012 qui a la longueur de la chaîne 9.

    OriginalL'auteur Sean B. Durkin

  2. 1

    Mon XSLT indiqué ci-dessous devrait fonctionner. Il n'utilise pas codé en dur des longueurs ou des indices, mais au lieu de cela divise la date chaîne de caractères '/' à la journée, le mois et l'année sont les composants.

    XSLT:

    <?xml version="1.0" encoding="utf-8"?>

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" />

    <xsl:template match="/">
        <xsl:apply-templates />
    </xsl:template>

        <!-- match the date and invoke formatDate to format it -->
    <xsl:template match="date">
        <xsl:element name="date">
            <xsl:call-template name="formatDate">
                <xsl:with-param name="dateParam" select="." />
            </xsl:call-template>
        </xsl:element>
    </xsl:template>

    <xsl:template name="formatDate">
        <xsl:param name="dateParam" />
        <!-- input format mm/dd/yyyy or m/d/yyyy -->
        <!-- output format yyyy-mm-dd -->


        <!-- parse out the day, month and year -->
        <xsl:variable name="month" select="substring-before($dateParam,'/')" />
        <xsl:variable name="day" select="substring-before(substring-after($dateParam,'/'),'/')" />
        <xsl:variable name="year" select="substring-after(substring-after($dateParam,'/'),'/')" />

        <!-- now print them out. Pad with 0 where necessary. -->
        <xsl:value-of select="$year" />
        <xsl:value-of select="'-'" />
        <xsl:if test="string-length($month) = 1">
            <xsl:value-of select="'0'" />
        </xsl:if>
        <xsl:value-of select="$month" />
        <xsl:value-of select="'-'" />
        <xsl:if test="string-length($day) = 1">
            <xsl:value-of select="'0'" />
        </xsl:if>
        <xsl:value-of select="$day" />
    </xsl:template>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

    D'entrée:

    <input>
    <date>04/30/2012</date>
    <date>4/1/2012</date>
</input>

    De sortie:

    <?xml version="1.0" encoding="UTF-8"?>
<input>
    <date>2012-04-30</date>
    <date>2012-04-01</date>
</input>

    Démo: http://www.xsltcake.com/slices/kBveVQ

    S'il vous plaît ne pas utiliser <xsl:variable><xsl:value-of select="xxx"/></xsl:variable> quand vous pourriez utiliser <xsl:variable select="xxx"/>. C'est verbeux et inefficace!
    merci pour cette remarque. J'ai mis à jour ma réponse.
    Bonjour l'équipe! Voir ci-dessous , de l'exposer au format dateTime: stackoverflow.com/a/16892467/2816548

    OriginalL'auteur dogbane