XSLT de transformation de la chaîne de format datetime

Pour la xs:date partie je pense <xsl:variable name="date" select="xs:date(substring($DateTimeAsString, 1, 10))"/> devrait fonctionner. Pour le xs:time partie je pense que vous avez besoin de plus de travail que d'extraire une sous-chaîne, en tant que votre échantillon a PM de sorte que vous besoin pour convertir un 24 heures d'horloge. Et retourner une valeur d'un certain type en fonction de l'utilisation <xsl:sequence select="..."/>, pas <xsl:value-of select="..."/>.

J'ai lu http://en.wikipedia.org/wiki/12_hour_clock et essayé de la mettre:

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:mf="http://example.com/mf"
    exclude-result-prefixes="xs mf">


<xsl:function name="mf:parseDateTime" as="xs:dateTime">
  <xsl:param name="input" as="xs:string"/>
  <xsl:variable name="date" as="xs:date" select="xs:date(substring($input, 1, 10))"/>
  <xsl:variable name="clock" as="xs:string" select="substring($input, 12, 8)"/>
  <xsl:variable name="hours" as="xs:integer" select="xs:integer(substring($clock, 1, 2))"/>
  <xsl:variable name="suffix" as="xs:string" select="substring($input, 21)"/>
  <xsl:message select="concat('Suffix: |', $suffix , '|')"/>
  <xsl:variable name="time" as="xs:time"
    select="if ($suffix eq 'AM') 
            then (if ($hours eq 12) 
                  then xs:time($clock) - xs:dayTimeDuration('PT12H')
                  else xs:time($clock))
            else (if ($hours eq 12)
                  then xs:time($clock)  
                  else xs:time($clock) + xs:dayTimeDuration('PT12H'))"/>
  <xsl:sequence select="dateTime($date, $time)"/>
</xsl:function>

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* , node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="value">
  <xsl:copy>
    <xsl:value-of select="mf:parseDateTime(.)"/>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Compte tenu de l'entrée

<values>
  <value>2013-08-08 12:00:00 AM</value>
  <value>2013-08-08 12:01:00 AM</value>
  <value>2013-08-08 12:59:00 AM</value>
  <value>2013-08-08 01:00:00 AM</value>
  <value>2013-08-08 11:00:00 AM</value>
  <value>2013-08-08 11:59:00 AM</value>
  <value>2013-08-08 12:00:00 PM</value>
  <value>2013-08-08 12:01:00 PM</value>
  <value>2013-08-08 12:59:00 PM</value>
  <value>2013-08-08 01:00:00 PM</value>
  <value>2013-08-08 11:00:00 PM</value>
  <value>2013-08-08 11:59:00 PM</value>
</values>

Saxon 9.5 transforme en

<values>
  <value>2013-08-08T00:00:00</value>
  <value>2013-08-08T00:01:00</value>
  <value>2013-08-08T00:59:00</value>
  <value>2013-08-08T01:00:00</value>
  <value>2013-08-08T11:00:00</value>
  <value>2013-08-08T11:59:00</value>
  <value>2013-08-08T12:00:00</value>
  <value>2013-08-08T12:01:00</value>
  <value>2013-08-08T12:59:00</value>
  <value>2013-08-08T13:00:00</value>
  <value>2013-08-08T23:00:00</value>
  <value>2013-08-08T23:59:00</value>
</values>

La fonction doit probablement explicitement vérifier la présence de PM au lieu de supposer que l'absence d'égalité avec AM signifie qu'il est un PM temps.