XSLT: Somme des attributs propres à la base de la valeur sur un autre attribut de nom

J'ai le document XML suivant (fournie par une autre partie)

<transactions>
  <transaction TaxAType="11" TaxAValue="111" TaxBType="2" TaxBValue="222" TaxCType="3" TaxCValue="333"/>
  <transaction TaxAType="11" TaxAValue="111" TaxBType="2" TaxBValue="222" TaxCType="3" TaxCValue="333"/>
</transactions>

Je voudrais écrire un document XSLT qui aurait pour effet de transformer ces lignes et la somme de l'Impôt*Valeur si la Taxe correspondante*Type = '11' par exemple.

Est-ce quelque chose de possible sans l'aide d'un modèle?

nom(), substring(), etc. fonctions dans la requête XQuery?
Quelles sont vos pensées sur cette question?

Quel doit être le résultat? Un numéro unique? XML avec les totaux? Vous dites "Fiscales*Type = '11', par exemple". Est-ce à dire que dans votre exemple de XML, le TaxBValue et TaxCValue ne serait pas être additionnés?
Bien l'idée, c'est que je voudrais stocker la Somme de toutes les valeurs pour un type de 10 dans un attribut de mon transformé document. Par exemple <lot gstAmount=5433"> transformée de transactions-éléments </lot>
Qui ne clarifie pas la question beaucoup. D'où vient le type "10" viennent de cette époque? Comment êtes-vous arrivé à la suite 5433? Pourriez-vous décrire ce que vous voulez faire, dans le détail? Compte tenu de l'échantillon XML que vous mettez dans votre question, ce qui devrait être la sortie?
Donc, si la TPS est égal à la taxe de type 11 puis le gstAmount serait 222. Le problème est que l'impôt de 11 type pourraient être stockées dans TaxAType et/ou TaxBType et/ou TaxCType
Je vois maintenant. Merci pour la clarification. J'ai posté une solution générique ci-dessous dans le cas où vous êtes intéressé.

OriginalL'auteur Daniel St-Jean | 2013-03-11

  1. 13

    Ont un look à la suite de XSLT:

    <?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml" indent="yes" />
  <xsl:template match="/">

    Sum of TaxA where type = 11:
    <xsl:value-of select="sum(transactions/transaction[@TaxAType='11']/@TaxAValue)" />

    Sum of all tax where type = 11:
    <xsl:value-of select="sum(transactions/transaction[@TaxAType='11']/@TaxAValue) 
      + sum(transactions/transaction[@TaxBType='11']/@TaxBValue) 
      + sum(transactions/transaction[@TaxCType='11']/@TaxCValue)" />

  </xsl:template>
</xsl:stylesheet>

    Il calcule la somme de TaxAValue pour les nœuds avec TaxAType = 11 et la somme de tous les Impôts?Valeur pour les nœuds avec les Impôts?Type = 11.

    Cela fonctionne! Merci... je pensais de l'aide d'une approche plus générique à l'aide d'une fonction définie par l'Utilisateur, mais que le Schéma est pré-définie, ce serait le travail! Merci!!!!

    OriginalL'auteur kamituel

  2. 1

    Ici est un peu verbeux, mais l'approche générale:

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:param name="taxType" select="11" />
<xsl:template match="transactions">
<result>
<xsl:variable name="allValues" 
select="transaction/@*[substring(local-name(), 5, 5) = 'Type']
[. = $taxType]" />
<xsl:call-template name="SumValues">
<xsl:with-param name="items" select="$allValues" />
</xsl:call-template>
</result>
</xsl:template>
<xsl:template name="SumValues">
<xsl:param name="items" />
<xsl:param name="total" select="0" />
<xsl:choose>
<xsl:when test="not($items)">
<xsl:value-of select="$total" />
</xsl:when>
<xsl:otherwise>
<xsl:variable name="currentItem" select="$items[1]" />
<xsl:variable name="currentValue">
<xsl:apply-templates select="$currentItem" mode="getMatchingValue" />
</xsl:variable>
<xsl:call-template name="SumValues">
<xsl:with-param name="items" select="$items[position() > 1]" />
<xsl:with-param name="total" select="$total +  $currentValue" />
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="@*" mode="getMatchingValue">
<xsl:variable name="typeCodeLetter" select="substring(local-name(), 4, 1)" />
<xsl:variable name="valueAttributeName"
select="concat('Tax', $typeCodeLetter, 'Value')" />
<xsl:variable name="matchingValueAttribute"
select="../@*[local-name() = $valueAttributeName]" />
<!-- Multiply by boolean to handle the case where the 
attribute wasn't found-->
<xsl:value-of select="$matchingValueAttribute * 
boolean($matchingValueAttribute)"/>
</xsl:template>
</xsl:stylesheet>

    Ce doit être capable de gérer n'importe quel nombre de Tax*Types (tant que * est un caractère unique) et le type désiré peut être transmis en tant que paramètre.

    OriginalL'auteur JLRishe

  3. 0

    Ce xml n'est pas dans un format très adapté pour remplir le type de traitement que vous voulez faire.
    votre meilleure option est d'utiliser javascript ou une autre langue avec les fonctionnalités XML (C#, Java,etc etc) pour extraire les détails dont vous avez besoin.

    avec javascript, il est possible de trouver un attribut de l'Impôt*Type=11 et ensuite obtenir la valeur de l'attribut suivant

    Je crois qu'il n'est pas pur XSL, mais j'ai peut-être trouvé une approche raisonnable de la création d'une Fonction Définie par l'Utilisateur qui recevra une nodelist de tous les attributs avec le même nom d'Impôt?Le Type d'une valeur de 11, L'UDF serait et la somme de la "contrepartie" d'Imposition?De la valeur.

    OriginalL'auteur DeadlyDan

  4. 0

    somme(transactions/transaction[@TaxAType='11']/@TaxAValue | @TaxBvalue | @ TaxCvalue)

    OriginalL'auteur titan.hi3