Comment calculer le dernier jour ouvrable du mois en VBScript

Comment dois-je calculer le dernier jour ouvrable du mois en VBScript? C'est pour un rapport Reporting Services.

Grâce

OriginalL'auteur | 2008-11-19

  1. 7

    Comment sur:

    intMonth=11
'Use zero to return last day of previous month '
LastDayOfMonth= dateserial(2008,intMonth+1,0)

'Saturday '
If WeekDay(LastDayOfMonth,1)=7 Then LastDayOfMonth=LastDayOfMonth-1
'Sunday '
If WeekDay(LastDayOfMonth,1)=1 Then LastDayOfMonth=LastDayOfMonth-2

Msgbox LastDayOfMonth & "  " & Weekdayname(Weekday(LastDayOfMonth,1),1)
    +1 pour l'utilisation de "premier jour du mois suivant" algorithme -- les délégués les détails du calendrier de la bibliothèque de routines.

    OriginalL'auteur Fionnuala

  2. 2

    Il y a une bonne CodeProject l'article ici: Travail Avec les Dates d'Affaires (Vacances/week-ends, etc).

    Ce projet vise à soulager la
    les troubles de déterminer valide
    dates. Il comprend quelques
    fonctions que j'ai créé afin de déterminer
    si oui ou non la date est un jour férié
    ou un week-end, et aussi pour récupérer
    soit le lendemain ou le dernier jour ouvrable.
    Il y a aussi une fonction pour trouver le
    dernier jour d'un mois donné.

    Function LastBusinessDay(sDate)

   Dim iDay, iDaysToAdd, iDate

   iDaysToAdd = 0
   iDate = sDate

   x = 1

   Do while iDaysToAdd >= 0

      If Weekday(iDate) = 1 or Weekday(iDate) = 7 or _
                isHoliday(iDate) <> 0 then
         iDay = Weekday(iDate)
         Select Case cint(iDay)
            Case 1  'Sunday

               iDate = DateAdd("d", -1, iDate)

            Case 7  'Saturday

               iDate = DateAdd("d", -1, iDate)

            Case else    'this is a valid day

                if isHoliday(iDate) > 0 then
                    iDate = dateadd("d", -(isHoliday(iDate)), iDate)
                else
                    iDaysToAdd = iDaysToAdd - 1
                end if

         End Select
      end if
   Loop

   LastBusinessDay = iDate
End Function

    P. S.: Vous trouverez les fonctions LastDayOfMonth et isHoliday dans l'article.

    OriginalL'auteur splattne

  3. 1

    Ici est une solution pour toute personne qui cherche à obtenir le Dernier jour ouvrable du mois précédent.

    Dim lastbusinessdayofprevmonth

Sub GetLastDay()

Dim curdate
curdate = Date()    

Dim firstdayofcurmonth 
firstdayofcurmonth = Month(curdate) & "/1/" & Year(curdate)

Dim lastdayofprevmonth
lastdayofprevmonth = DateAdd("d", -1, firstdayofcurmonth)

Dim day
day = weekday(lastdayofprevmonth)


if(day = 1) then
    lastbusinessdayofprevmonth = DateAdd("d", -2, lastdayofprevmonth)
elseif (day = 7) then
    lastbusinessdayofprevmonth = DateAdd("d", -1, lastdayofprevmonth)
else
    lastbusinessdayofprevmonth = lastdayofprevmonth
end if

end sub

    OriginalL'auteur cgolvelker

  4. 0

    Si tu parles de la dernière semaine jour du mois (M-F), puis essayez:

    Dim d

d = DateAdd("m", 1, Now)

d = Month(d) & "/1/" & Year(d)
d = DateAdd("d", -1, d)

If Weekday(d) = 7 Then
    d = DateAdd("d", -1, d)
ElseIf Weekday(d) = 1 Then
    d = DateAdd("d", -2, d)
End If

MsgBox d

    OriginalL'auteur P Daddy