Comment stocker de manière sécurisée une chaîne de connexion dans une application WinForms?

J'ai besoin de savoir quelle est la façon la plus commune de stocker une chaîne de connexion SQL server pour une application WinForms VB.NET.

J'ai cherché sur le net et j'ai trouvé des réponses à chacune des questions suivantes:

  • Comment puis-je lire app.config valeurs
  • Comment le faire dans ASP.NET Référence: cette SORTE de question.
  • Comment dois-je stocker une chaîne de connexion (non crypté donc dangereux)

Je voudrais une réponse complète sur la façon de stocker une chaîne de connexion dans VB.NET dans app.config (ou settings.settings si c'est mieux) en toute sécurité.

Est app.config la bonne place? Je peux chiffrer ces valeurs?

InformationsquelleAutor MarioDS | 2012-05-15
  1. 10

    Simplement , l' .net framework vous permet de le faire , voir

    http://msdn.microsoft.com/en-us/library/89211k9b(v=vs. 80).aspx

    Informations pertinentes:

    Cela va dans le de la machine.config fichier:

    <configProtectedData defaultProvider="RsaProtectedConfigurationProvider">
  <providers>
    <add name="RsaProtectedConfigurationProvider" 
      type="System.Configuration.RsaProtectedConfigurationProvider, ... />
    <add name="DataProtectionConfigurationProvider" 
      type="System.Configuration.DpapiProtectedConfigurationProvider, ... />
  </providers>
</configProtectedData>

    Et c'est le code de l'application:

    Shared Sub ToggleConfigEncryption(ByVal exeConfigName As String)
    ' Takes the executable file name without the
    ' .config extension.
    Try
        ' Open the configuration file and retrieve 
        ' the connectionStrings section.
        Dim config As Configuration = ConfigurationManager. _
            OpenExeConfiguration(exeConfigName)

        Dim section As ConnectionStringsSection = DirectCast( _
            config.GetSection("connectionStrings"), _
            ConnectionStringsSection)

        If section.SectionInformation.IsProtected Then
            ' Remove encryption.
            section.SectionInformation.UnprotectSection()
        Else
            ' Encrypt the section.
            section.SectionInformation.ProtectSection( _
              "DataProtectionConfigurationProvider") 'this is an entry in machine.config
        End If

        ' Save the current configuration.
        config.Save()

        Console.WriteLine("Protected={0}", _
        section.SectionInformation.IsProtected)

    Catch ex As Exception
        Console.WriteLine(ex.Message)
    End Try
End Sub

    Mise à JOUR de 1

    Merci @wpcoder, pour ce lien

    • Je pense que vais le faire, merci.
    • Depuis que cette question est d'obtenir beaucoup de points de vue, j'ai édité votre réponse, assurez-vous que l'information n'est pas perdue si le lien jamais rompre.
    • les réponses à la question, mais ne fournit pas une bonne solution. À partir de MS lien fourni; le note dit: The connection string can only be decrypted on the computer on which it was encrypted. La mise à jour de MS lien pour l'article a pu fournir une solution
    InformationsquelleAutor pylover
  2. 7

    À mon travail, nous stocker les chaînes de connexion dans l'application.config, mais nous les chiffrer avec AES256. Il fonctionne très bien et ajoute une bonne quantité de la sécurité. Nous avons écrit un petit outil qui vous permet de crypter et décrypter des chaînes de connexion afin d'édition de l'application.les fichiers de configuration est assez facile. Nous avons juste le chiffrement de la clé codée en dur dans l'application, donc si quelqu'un qui s'intéresse à décompiler les assemblées, il pouvait le comprendre, mais il soulève la barre assez haute pour nos besoins. Voici la classe que nous avons utiliser pour crypter et décrypter les chaînes de connexion:

    Public Class Aes256Base64Encrypter
Public Function Decrypt(ByVal encryptedText As String, ByVal secretKey As String) As String
Dim plainText As String = Nothing
Using inputStream As MemoryStream = New MemoryStream(System.Convert.FromBase64String(encryptedText))
Dim algorithm As RijndaelManaged = getAlgorithm(secretKey)
Using cryptoStream As CryptoStream = New CryptoStream(inputStream, algorithm.CreateDecryptor(), CryptoStreamMode.Read)
Dim outputBuffer(0 To CType(inputStream.Length - 1, Integer)) As Byte
Dim readBytes As Integer = cryptoStream.Read(outputBuffer, 0, CType(inputStream.Length, Integer))
plainText = Unicode.GetString(outputBuffer, 0, readBytes)
End Using
End Using
Return plainText
End Function
Public Function Encrypt(ByVal plainText As String, ByVal secretKey As String) As String
Dim encryptedPassword As String = Nothing
Using outputStream As MemoryStream = New MemoryStream()
Dim algorithm As RijndaelManaged = getAlgorithm(secretKey)
Using cryptoStream As CryptoStream = New CryptoStream(outputStream, algorithm.CreateEncryptor(), CryptoStreamMode.Write)
Dim inputBuffer() As Byte = Unicode.GetBytes(plainText)
cryptoStream.Write(inputBuffer, 0, inputBuffer.Length)
cryptoStream.FlushFinalBlock()
encryptedPassword = System.Convert.ToBase64String(outputStream.ToArray())
End Using
End Using
Return encryptedPassword
End Function
Private Function getAlgorithm(ByVal secretKey As String) As RijndaelManaged
Const salt As String = "put a salt key here"
Const keySize As Integer = 256
Dim keyBuilder As Rfc2898DeriveBytes = New Rfc2898DeriveBytes(secretKey, Unicode.GetBytes(salt))
Dim algorithm As RijndaelManaged = New RijndaelManaged()
algorithm.KeySize = keySize
algorithm.IV = keyBuilder.GetBytes(CType(algorithm.BlockSize / 8, Integer))
algorithm.Key = keyBuilder.GetBytes(CType(algorithm.KeySize / 8, Integer))
algorithm.Padding = PaddingMode.PKCS7
Return algorithm
End Function
End Class

    En fait, nous avons terminé qu'à l'intérieur d'un ConnectionStringEncrpyter classe qui code en dur de la clé secrète.

    • Cela sonne bien, mais pouvez-vous me dire comment le coder? J'ai un cryptage de classe prêt pour les mots de passe uniquement, pas pour l'ensemble des chaînes de connexion (frais généraux-sage)
    • J'ai ajouté un exemple de code. Je comprends--le cryptage peut être une douleur. Nous l'encoder en base64 donc il stocke bien dans le fichier texte.
    • Merci pour l'aide, mais je pense que pylover m'a fourni la réponse que je cherchais.
    InformationsquelleAutor Steven Doggart