Fonction IsDate renvoie des résultats inattendus

Comment se IsDate("13.50") retourne True mais IsDate("12.25.2010") retourne False?

InformationsquelleAutor mwolfe02 | 2010-12-02
  1. 64

    Je suis fauché par une petite "feature" récemment et je voulais sensibiliser à certaines des questions entourant la IsDate fonction en VB et VBA.

    Le Cas Simple

    Que vous vous attendez, IsDate retourne True lorsqu'il est passé d'un type de données Date et False pour tous les autres types de données à l'exception des Cordes. Pour les Cordes, IsDate retourne True ou False basé sur le contenu de la chaîne:

    IsDate(CDate("1/1/1980"))  --> True
IsDate(#12/31/2000#)       --> True
IsDate(12/24)              --> False  '12/24 evaluates to a Double: 0.5'
IsDate("Foo")              --> False
IsDate("12/24")            --> True

    IsDateTime?

    IsDate devrait être plus justement nommé IsDateTime parce qu'elle renvoie True pour les chaînes formatées que les temps:

    IsDate("10:55 AM")   --> True
IsDate("23:30")      --> True  'CDate("23:30")   --> 11:30:00 PM'
IsDate("1:30:59")    --> True  'CDate("1:30:59") --> 1:30:59 AM'
IsDate("13:55 AM")   --> True  'CDate("13:55 AM")--> 1:55:00 PM'
IsDate("13:55 PM")   --> True  'CDate("13:55 PM")--> 1:55:00 PM'

    Remarque sur les deux derniers exemples ci-dessus que IsDate n'est pas parfait validateur de fois.

    , Gotcha!

    Non seulement IsDate accepter de fois, il accepte à la fois dans de nombreux formats. L'une de qui emploie une période (.) comme séparateur. Cela conduit à une certaine confusion, parce que la période peut être utilisé comme un séparateur de temps, mais pas un séparateur de date:

    IsDate("13.50")     --> True  'CDate("13.50")    --> 1:50:00 PM'
IsDate("12.25")     --> True  'CDate("12.25")    --> 12:25:00 PM'
IsDate("12.25.10")  --> True  'CDate("12.25.10") --> 12:25:10 PM'
IsDate("12.25.2010")--> False '2010 > 59 (number of seconds in a minute - 1)'
IsDate("24.12")     --> False '24 > 23 (number of hours in a day - 1)'
IsDate("0.12")      --> True  'CDate("0.12")     --> 12:12:00 AM

    Cela peut être un problème si vous êtes l'analyse d'une chaîne et d'exploitation sur elle repose sur son type apparent. Par exemple:

    Function Bar(Var As Variant)
    If IsDate(Var) Then
        Bar = "This is a date"
    ElseIf IsNumeric(Var) Then
        Bar = "This is numeric"
    Else
        Bar = "This is something else"
    End If
End Function

?Bar("12.75")   --> This is numeric
?Bar("12.50")   --> This is a date

    Les Solutions De Contournement

    Si vous testez une variante pour les sous-tendent ce type de données, vous devez utiliser TypeName(Var) = "Date" plutôt que IsDate(Var):

    TypeName(#12/25/2010#)  --> Date
TypeName("12/25/2010")  --> String

Function Bar(Var As Variant)
    Select Case TypeName(Var)
    Case "Date"
        Bar = "This is a date type"
    Case "Long", "Double", "Single", "Integer", "Currency", "Decimal", "Byte"
        Bar = "This is a numeric type"
    Case "String"
        Bar = "This is a string type"
    Case "Boolean"
        Bar = "This is a boolean type"
    Case Else
        Bar = "This is some other type"
    End Select
End Function

?Bar("12.25")   --> This is a string type
?Bar(#12/25#)   --> This is a date type
?Bar(12.25)     --> This is a numeric type

    Si, toutefois, vous traitez avec des chaînes qui peuvent être des dates ou des nombres (par exemple, l'analyse d'un fichier texte), vous devriez vérifier si c'est un numéro avant de vérifier pour voir si c'est une date:

    Function Bar(Var As Variant)
    If IsNumeric(Var) Then
        Bar = "This is numeric"
    ElseIf IsDate(Var) Then
        Bar = "This is a date"
    Else
        Bar = "This is something else"
    End If
End Function

?Bar("12.75")   --> This is numeric
?Bar("12.50")   --> This is numeric
?Bar("12:50")   --> This is a date

    Même si tout ce qui vous intéresse est de savoir si c'est une date, vous devriez assurez-vous que ce n'est pas un nombre:

    Function Bar(Var As Variant)
    If IsDate(Var) And Not IsNumeric(Var) Then
        Bar = "This is a date"
    Else
        Bar = "This is something else"
    End If
End Function

?Bar("12:50")   --> This is a date
?Bar("12.50")   --> This is something else

    Particularités de la fonction CDate

    Comme @Deanna souligné dans les commentaires ci-dessous, le comportement de CDate() est pas fiable ainsi. Ses résultats varient selon qu'il s'est passée une chaîne de caractères ou un nombre:

    ?CDate(0.5)     -->  12:00:00 PM
?CDate("0.5")   -->  12:05:00 AM

    De fuite et des zéros sont significatifs si un nombre est passé comme une chaîne de caractères:

    ?CDate(".5")    -->  12:00:00 PM 
?CDate("0.5")   -->  12:05:00 AM 
?CDate("0.50")  -->  12:50:00 AM 
?CDate("0.500") -->  12:00:00 PM

    Le comportement change aussi que la partie décimale d'une chaîne approches les 60 minutes de marque:

    ?CDate("0.59")  -->  12:59:00 AM 
?CDate("0.60")  -->   2:24:00 PM

    La ligne de fond est que si vous avez besoin de convertir des chaînes de date/heure vous devez être au courant de ce format vous vous attendez à être et puis de le re-formater de façon appropriée avant de compter sur CDate() pour les convertir.

    • Qui... a été remarquablement complet.
    • IsDate() fonctionne de cette façon VB.Net trop.
    • Bon à savoir.
    • Si je peux UV plus d'une fois, j'aurais en PLACE de cette 10x 😀
    • Notez également que le "X. YY" de temps peut être ambiguë, surtout avec la partie décimale d'une valeur numérique étant la fraction de la journée. ?cdate("0.59") = 00:59:00 ?cdate("0.60") = 14:24:00
    • Merci pour le commentaire; je n'étais pas au courant de cette question. J'ai étoffé un peu et de l'ajouter à ma réponse.

    InformationsquelleAutor mwolfe02
  2. 7

    Tard pour le jeu ici (mwolfe02 répondu à cette question, il y a un an!) mais le problème est réel, il existe d'autres approches qui mérite d'être examiné, et StackOverflow est l'endroit pour les trouver: voici donc ma propre réponse...

    Je suis fauché par VBA.IsDate() sur cette question il y a quelques années, et codé en place d'une étendue pour couvrir les cas que VBA.IsDate() gère mal. Le pire est que les flotteurs et les nombres entiers return FALSE de IsDate, même si la date de périodiques sont souvent transmis en Double (pour le type DateTime) et les Entiers Longs (pour les dates).

    Un point à noter: votre mise en œuvre ne nécessite pas la possibilité de vérifier le tableau des variantes. Sinon, n'hésitez pas à dépouiller le code dans le bloc indenté qui suit Else ' Comment this out if you don't need to check array variants. Cependant, vous devez être conscient que certains systèmes tiers (y compris en temps réel des données de marché les clients) le retour de leurs données dans des tableaux, même de simples points de données.

    Plus d'informations dans les commentaires de code.

    Voici le Code:

    Public Function IsDateEx(TestDate As Variant, Optional LimitPastDays As Long = 7305, Optional LimitFutureDays As Long = 7305, Optional FirstColumnOnly As Boolean = False) As Boolean
'Attribute IsDateEx.VB_Description = "Returns TRUE if TestDate is a date, and is within ± 20 years of the system date.
'Attribute IsDateEx.VB_ProcData.VB_Invoke_Func = "w\n9"
Application.Volatile False
On Error Resume Next
' Returns TRUE if TestDate is a date, and is within ± 20 years of the system date.
' This extends VBA.IsDate(), which returns FALSE for floating-point numbers and integers
' even though the VBA Serial Date is a Double. IsDateEx() returns TRUE for variants that
' can be parsed into string dates, and numeric values with equivalent date serials.  All
' values must still be ±20 years from SysDate. Note: locale and language settings affect
' the validity of day- and month names; and partial date strings (eg: '01 January') will
' be parsed with the missing components filled-in with system defaults.
' Optional parameters LimitPastDays/LimitFutureDays vary the default ± 20 years boundary
' Note that an array variant is an acceptable input parameter: IsDateEx will return TRUE
' if all the values in the array are valid dates: set  FirstColumnOnly:=TRUE if you only
' need to check the leftmost column of a 2-dimensional array.
' *     THIS CODE IS IN THE PUBLIC DOMAIN
' *
' *     Author: Nigel Heffernan, May 2005
' *     http://excellerando.blogspot.com/
' *
' *
' *     *********************************
Dim i As Long
Dim j As Long
Dim k As Long
Dim jStart As Long
Dim jEnd   As Long
Dim dateFirst As Date
Dim dateLast As Date
Dim varDate As Variant
dateFirst = VBA.Date - LimitPastDays
dateLast = VBA.Date + LimitFutureDays
IsDateEx = False
If TypeOf TestDate Is Excel.Range Then
TestDate = TestDate.Value2
End If
If VarType(TestDate) < vbArray Then
If IsDate(TestDate) Or IsNumeric(TestDate) Then
If (dateLast > TestDate) And (TestDate > dateFirst) Then
IsDateEx = True
End If
End If
Else   ' Comment this out if you don't need to check array variants
k = ArrayDimensions(TestDate)
Select Case k
Case 1
IsDateEx = True
For i = LBound(TestDate) To UBound(TestDate)
If IsDate(TestDate(i)) Or IsNumeric(TestDate(i)) Then
If Not ((dateLast > CVDate(TestDate(i))) And (CVDate(TestDate(i)) > dateFirst)) Then
IsDateEx = False
Exit For
End If
Else
IsDateEx = False
Exit For
End If
Next i
Case 2
IsDateEx = True
jStart = LBound(TestDate, 2)
If FirstColumnOnly Then
jEnd = LBound(TestDate, 2)
Else
jEnd = UBound(TestDate, 2)
End If
For i = LBound(TestDate, 1) To UBound(TestDate, 1)
For j = jStart To jEnd
If IsDate(TestDate(i, j)) Or IsNumeric(TestDate(i, j)) Then
If Not ((dateLast > CVDate(TestDate(i, j))) And (CVDate(TestDate(i, j)) > dateFirst)) Then
IsDateEx = False
Exit For
End If
Else
IsDateEx = False
Exit For
End If
Next j
Next i
Case Is > 2
' Warning: For... Each enumerations are SLOW
For Each varDate In TestDate
If IsDate(varDate) Or IsNumeric(varDate) Then
If Not ((dateLast > CVDate(varDate)) And (CVDate(varDate) > dateFirst)) Then
IsDateEx = False
Exit For
End If
Else
IsDateEx = False
Exit For
End If
Next varDate
End Select
End If
End Function

    Une Astuce pour les gens toujours à l'aide d'Excel 2003:

    Si vous (ou vos utilisateurs) vont appeler IsDateEx() à partir d'une feuille de calcul, mettre ces deux lignes, immédiatement au-dessous de la tête de la fonction, à l'aide d'un éditeur de texte dans un exportés .fichier bas et la réimportation du fichier, car VB Attributs sont utiles, mais ils ne sont pas accessibles à l'éditeur de code dans Excel VBA IDE:

    Attribute IsDateEx.VB_Description = "Returns TRUE if TestDate is a date, and is within ± 20 years of the system date.\r\nChange the defaulte default ± 20 years boundaries by setting values for LimitPastDays and LimitFutureDays\r\nIf you are checking an array of dates, ALL the values will be tested: set FirstColumnOnly TRUE to check the leftmost column only."

    C'est sur une seule ligne: attention aux sauts de lignes insérées par le navigateur! ...Et cette ligne, qui met isDateEX dans l'Assistant fonction dans les "Informations" de la catégorie, aux côtés de ISNUMBER(), ISERR(), ISTEXT() et ainsi de suite:

    Attribute IsDateEx.VB_ProcData.VB_Invoke_Func = "w\n9"

    Utilisez le "w\n2" si vous préférez le voir sous le Jour & fonctions de Temps: bat l'enfer outta perdre dans le bourbier de l' "Utilisé Défini" les fonctions à partir de votre propre code, et tous ceux des tiers add-ins développés par des gens qui ne font pas assez assez pour aider les utilisateurs occasionnels.

    Je n'ai aucune idée si cela fonctionne encore dans Office 2010.

    en outre, vous pourriez avoir besoin de la source pour ArrayDimensions:

    Cette API déclaration est requise dans l'en-tête du module:

    Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
(Destination As Any, _
Source As Any, _
ByVal Length As Long)

    ...Et voici la fonction elle-même: 

    Private Function ArrayDimensions(arr As Variant) As Integer
'-----------------------------------------------------------------
' will return:
' -1 if not an array
' 0  if an un-dimmed array
' 1  or more indicating the number of dimensions of a dimmed array
'-----------------------------------------------------------------
' Retrieved from Chris Rae's VBA Code Archive - http://chrisrae.com/vba
' Code written by Chris Rae, 25/5/00
' Originally published by R. B. Smissaert.
' Additional credits to Bob Phillips, Rick Rothstein, and Thomas Eyde on VB2TheMax
Dim ptr As Long
Dim vType As Integer
Const VT_BYREF = &H4000&
'get the real VarType of the argument
'this is similar to VarType(), but returns also the VT_BYREF bit
CopyMemory vType, arr, 2
'exit if not an array
If (vType And vbArray) = 0 Then
ArrayDimensions = -1
Exit Function
End If
'get the address of the SAFEARRAY descriptor
'this is stored in the second half of the
'Variant parameter that has received the array
CopyMemory ptr, ByVal VarPtr(arr) + 8, 4
'see whether the routine was passed a Variant
'that contains an array, rather than directly an array
'in the former case ptr already points to the SA structure.
'Thanks to Monte Hansen for this fix
If (vType And VT_BYREF) Then
' ptr is a pointer to a pointer
CopyMemory ptr, ByVal ptr, 4
End If
'get the address of the SAFEARRAY structure
'this is stored in the descriptor
'get the first word of the SAFEARRAY structure
'which holds the number of dimensions
'...but first check that saAddr is non-zero, otherwise
'this routine bombs when the array is uninitialized
If ptr Then
CopyMemory ArrayDimensions, ByVal ptr, 2
End If
End Function

    Veuillez garder les remerciements dans votre code source: alors que vous progressez dans votre carrière en tant que développeur, vous allez apprécier vos propres cotisations d'être reconnu.

    Aussi: je vous conseille de garder cette déclaration privé. Si vous devez faire un public Sub dans un autre module, insérez le Option Private Module instruction dans l'en-tête du module. Vous vraiment ne voulez pas que vos utilisateurs d'appeler une fonction avec CopyMemoryoperations et l'arithmétique des pointeurs.

    InformationsquelleAutor Nigel Heffernan